Spalten nach unten kopieren

[grafmanni]

Hallo habe ein Problem!
ich möchte in einer SPALTE eine formel nach unten kopieren und es müsste sich die formel verändern
beispiel:
in A1  Summenprodukt(zählenwenn(AA:AA;2)
in A2  sollte jetzt erscheinen Summenprodukt(zählenwenn(AB:AB;2)
in A3  sollte jetzt erscheinen Summenprodukt(zählenwenn(AC:AC;2)usw.

Ist dies überhaupt möglich?

[schauan]

Hallöchen,

hier mal das Prinzip:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	6	1	2	3
2	5	2	3
3	3	3

Zelle	Formel
A1	=SUMME(INDEX($1:$1;1;ZEILE()+1):INDEX($10:$10;1;ZEILE()+1))
A2	=SUMME(INDEX($1:$1;1;ZEILE()+1):INDEX($10:$10;1;ZEILE()+1))
A3	=SUMME(INDEX($1:$1;1;ZEILE()+1):INDEX($10:$10;1;ZEILE()+1))

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

[schauan]

Hallöchen,

wie jetzt mit Spalten ziehen?

[RPP63]

Moin!
Einzige Formelzelle in A1:

	A	B	C	D	E	F	G
1	1		2	4	3	1	4
2	2		1	2	3	4	2
3	3		1	1	2	4	2
4	0		4	4	2	4	4
5	3		1	3	3	1	1
6			3	3	3	3	2
7			1	3	1	4	1
8			1	2	2	4	4

Zelle	Formel
A1	=MTRANS(NACHSPALTE(C:G;LAMBDA(a;ZÄHLENWENN(a;2))))

Und wer NACHSPALTE() noch nicht hat, hier etwas "ziehbares" in I1:

	C	D	E	F	G	H	I
1	2	4	3	1	4		1
2	1	2	3	4	2		2
3	1	1	2	4	2		3
4	4	4	2	4	4		0
5	1	3	3	1	1		3
6	3	3	3	3	2
7	1	3	1	4	1
8	1	2	2	4	4

Zelle	Formel
I1	=ZÄHLENWENN(INDEX(C:G;;ZEILE(X1));2)

Gruß Ralf

[grafmanni]

Hallo RPP63!
Du hast mir Arbeit für 3 Monate erspart mit der Formel Zählenwenn(usw.
Ich weiss nicht wie ich dir danken soll.
Ein grosses Vergelts Gott und Danke!

grafmanni

[RPP63]

Nettes Feedback!
Auch dafür ein Danke!