Spalten fixieren aus Tabellen für Formel

[12349]

Schönen guten Tag, 

folgendes Problem:

ich würde in einer Formel gerne eine Spalte referenzieren, wobei wenn ich die Formel nach rechts erweitere/kopiere die Spalte dabei fixiert wird. Habe schon @, [[]:[]],  #This Row ausprobiert scheint aber für die aktuelle Version von Excel (2401 Build 16.0.17231.20236) 64 Bit) nicht mehr zu funktionieren. 

Ich hoffe jemand hat eine Idee. 

Vielen Dank im voraus. 
Beste Grüße

[ralf_b]

schreibe    [[Spaltenname]:[Spaltename]]

[12349]

Das meine ich das habe ich bereits probiert. Hab mich auch schon bei den Autoren erkundigt.

---

schreibe    [[Spaltenname]:[Spaltename]]

Danke für die Antwort.
Funktioniert das den bei dir? Bei mir erkennt er nur die erste []. Wenn ich Liste[[ Spaltenname ]:[ Spaltenname ]] schreibe.

[HKindler]

Hi,

also bei mir funktioniert das.

   

Die Formel aus F2 habe ich nach G2 gezogen.

[12349]

Hi,

also bei mir funktioniert das.



Die Formel aus F2 habe ich nach G2 gezogen.

Hey vielen lieben Dank für die Arbeit. Jetzt erfasst die Formel auch nur noch die richtige Spalte. Trotzdem wird der falsche Wert am Ende meiner Formel ausgegeben.

Meine Formel:

=WENN(UND(
JAHR(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])=2022,
AUFRUNDEN(MONAT(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])/3,0)=C$44,
Projektliste3[[Amount of days from technical discussion to feasibility trial]:[Amount of days from technical discussion to feasibility trial]]>0)
,1,0)

Die Tabelle sieht so aus: 
   

Und die Formel soll das Datum auswerten und dem jeweiligen Jahr, Quartal zuordnen und dafür 1 ausgeben:


   

so und wenn ich jetzt ein datum des 01.10.2022 habe müsste doch eine 1 erzeugt werden.
Wird es aber leider nicht. Mit der Spaltenfixierungformel von normalen Zellen funktioniert es jedoch: =WENN(UND(JAHR($M2)=2022,AUFRUNDEN(MONAT($M2)/3,0)=C$44,$L2>0),1,0)
und es erscheint eine 1 im Quartal 4.

Ich möchte gerne dass sich die Zahlen bei Ergänzung der intelligenten Tabelle auch ergänzen daher der ganze Umstand.

[Klaus-Dieter]

Hallo,

stelle bitte anstelle der Bilder die Datei hier ein, dann kann man auch helfen.

Nachtrag: nach meinem Verständnis beginnt am 1. Oktober das 4. Quartal.

[steve1da]

Hola,
Crossposting
Bitte in jedem Forum nachholen.
Gruß,
steve1da

[12349]

Gerne: 
  Mappe1.xlsx (Größe: 37,17 KB / Downloads: 5)

[HKindler]

Hi,

du solltest deine Formel gründlich überdenken. WENN kommt zwar mit Matrixformeln klar, aber UND nicht. Statt UND(xxx;yyy) musst du bei Matrixformeln (xxx)*(yyy) verwenden.

Somit würde die Formel

=WENN((JAHR(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])=2022)*(AUFRUNDEN(MONAT(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])/3;0)=C$44)*(Projektliste3[[Amount of days from technical discussion to feasibility trial]:[Amount of days from technical discussion to feasibility trial]]);1;0)

heißen. Da dies eine Matrix-Formel ist, die funktioniert, bekommst du dann bei aktuellem Excel einen #ÜBERLAUF!-Fehler, bei altem Excel ziemlich sicher 0 (1 nur wenn die erste Zeile die Bedingungen erfüllt). Wenn du die Anzahl haben willst, dann musst du aus dieser Formel die SUMME ziehen (kannst dafür aber die 0 beim WENN weg lassen):

=SUMME(WENN((JAHR(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])=2022)*(AUFRUNDEN(MONAT(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])/3;0)=C$44)*(Projektliste3[[Amount of days from technical discussion to feasibility trial]:[Amount of days from technical discussion to feasibility trial]]);1))

oder etwas einfacher, da das WENN eigentlich auch überflüssig ist:

=SUMME(--(JAHR(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])=2022)*(AUFRUNDEN(MONAT(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]])/3;0)=C$44)*(Projektliste3[[Amount of days from technical discussion to feasibility trial]:[Amount of days from technical discussion to feasibility trial]]>0))

Aber wieso nicht ZÄHLENWENNS verwenden?

=ZÄHLENWENNS(Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]];">="&DATUM(2022;(C$44-1)*3;1);Projektliste3[[Start of current project status feasibility trials]:[Start of current project status feasibility trials]];"<"&DATUM(2022;C$44*3;1);Projektliste3[[Amount of days from technical discussion to feasibility trial]:[Amount of days from technical discussion to feasibility trial]];">0")

Was mir nicht klar ist: Wieso hast du die Formel in vielen Zeilen stehen? Sie berechnet doch in jeder Zeile den selben Wert unabhängig von der Zeile selbst.

Ich würde das sowieso über eine Pivot-Tabelle lösen...

[steve1da]

…
https://www.herber.de/forum/archiv/1964t...ormel.html