Spalten ausblenden, Platzhalter

[MSBG]

Guten Tag,

Folgendes, Ich möchte zum Beispiel Spalten ausblenden, welche in Spalte "E", "SOE" stehen haben.
Das "SOE" steht aber niemals alleine. Aufgrund dessen, wollte Ich mit Platzhaltern arbeiten.
Ich habe jetzt schon alle möglichen Kombinationen mit * oder # ausprobiert aber es hat nie funktioniert.

Der Code funktioniert bei genauen Definitionen, nur bei Platzhaltern nicht.

Wisst Ihr vielleicht woran es liegt ?

Beispiel:TST
  TST.xlsx (Größe: 8,9 KB / Downloads: 4)

Code:

Sub BestimmteZeilenAusblenden()

Dim Zelle As Range

For Each Zelle In Range("E1:E10")

If Zelle.Value = "SOE*" And Rows(Zelle.Row).Hidden = False" _
    Then Rows(Zelle.Row).Hidden = True
   
Next Zelle

End Sub

Vielen Dank für eure Hilfe.

Liebe Grüße

[Klaus-Dieter]

Hallo,

du meinst, du möchtest Zeilen ausblenden, wo in Spalte E SOE enthalten ist?

[Werner.M]

Hallo,

und warum nicht mit dem Autofilter - Textfilter - beginnt nicht mit SOE ?

Und mit = geht das nicht sondern mit like

Code:

Sub Zeilen_weg()
Dim Zelle As Range, raWeg As Range

Application.ScreenUpdating = False

For Each Zelle In Range("E1:E" & Cells(Rows.Count, "E").End(xlUp).Row)
    If Zelle Like "SOE*" Then
        If raWeg Is Nothing Then
            Set raWeg = Zelle
        Else
            Set raWeg = Union(raWeg, Zelle)
        End If
    End If
Next Zelle

If Not raWeg Is Nothing Then
    raWeg.EntireRow.Hidden = True
End If

Set raWeg = Nothing
End Sub

Gruß Werner

[MSBG]

Danke, hat funktioniert :)