Spalten Zusammenfassen, summieren

[MCT1979]

Hallo Zusammen,

wenn möglich, bräuchte ich nochmal Hilfe.
Die Spalten A,B;C in der angehängten Datei sollten, wenn möglich, so wie die roten Spalten E,G,F zusammengefasst werden. 
D.h, eine Nr sollte einem Arbeitspaket zugeordnet und dann mit der jeweiligen Summe der Stunden im jeweiligen Arbeitspaket ausgewiesen werden.

Ich habe es mit SummeWenn, Index, ... versucht aber die richtige Lösung ist mir nicht geglückt.

Wenn jmd Spaß daran hat würde ich mich wie immer um Hilfe freuen.

Beste Grüße 

Manfred

[RPP63]

Moin!
Ich würde so etwas mittels Pivot Table lösen:
Nr. und Arbeitspaket in Zeilen,
Menge in Werte.
Übrigens ist Deine erste Summe falsch.
   

Gruß Ralf

[johammer]

Hallo MCT1979,

mit SUMMEWENNS geht's,
habe es getestet und es kommen genau die Werte raus;
die du in der Beispiel Tabelle rot gekennzeichnet sind.

Gruss Jo

[RPP63]

Ach ja?
Die Kombi 4/7 gibt es dreimal!
8,5+8+7,5 ergeben bei mir 24 (wie in meiner Pivot) und nicht 16,5 wie in der Beispieldatei …

[MCT1979]

Hallo Zusammen,

danke für die Antworten, ja tatsächlich ist mir der der eine Summand entgangen, habe es in Mappe1_a.xlsx korrigiert.
Mit Pivot wäre es wohl nicht so schwer, da gebe ich Euch recht, aber ich bräuchte eine Formel dafür.
Die Werte in A, B und C können sich in Wert und Anzahl "dynamisch" ändern. Diese Übersicht in der Datei gilt zB für Monat 1. In einem anderen Monat 2 würden dann zB die Nr 5, 8000, 3020 und die Arbeitspakete 1, 2, 3 aktuell sein.
Ich weiß eben nicht, ob SummeWenns, das leisten kann, muss man bei SummeWenns nicht immer den exakten Wert eingeben, den man sucht?

Wie gesagt, mit Pivot würde es wohl gehen, darauf würde ich aber ungern zurückgreifen.
Wenns nicht ohne Pivot geht, danke ich Euch dennoch für Eure Zeit!

Beste Grüße

[shift-del]

Mit Pivot wäre es wohl nicht so schwer, da gebe ich Euch recht, aber ich bräuchte eine Formel dafür.

Nach diesem Schema:

Code:

=SUMME(WENN(UND(A2=F2;B2=G2);C2);WENN(UND(A3=F2;B3=G2);C3);WENN(UND(A4=F2;B4=G2);C4);WENN(UND(A5=F2;B5=G2);C5); usw.)

Da kann überhaupt nichts schief gehen.

[Elex]

Hi

da du 365 angibst.

Code:

=VSTAPELN(A1:C1;LET(TabA;EINDEUTIG(A2:B27);HSTAPELN(TabA;SUMMEWENNS(C2:C27;A2:A27;INDEX(TabA;;1);B2:B27;INDEX(TabA;;2)))))

Gruß Elex

[BoskoBiati]

Hi,

evtl so:


  Mappe1_a.xlsx (Größe: 11,28 KB / Downloads: 10)

[MCT1979]

Danke an die vielen Zuschriften und Eure guten Ideen,

das war die Formel, die ich gesucht hatte.

Beste Grüße Euch und ein schönes Wochenende

[Luschi]

Hallo Excel-Fan's,

ich habe die 365-Formel von Elex so angepaßt, daß die Bereichsangabe 'A2:C27' nur einmal angegeben wird und alle anderen Spaltenangaben davon abgeleitet sind:

Code:

=VSTAPELN(A1:C1;LET(Bereich;A2:C27;TabA;EINDEUTIG(INDEX(Bereich;;1):INDEX(Bereich;;2));HSTAPELN(TabA;SUMMEWENNS(INDEX(Bereich;;3);INDEX(Bereich;;1);INDEX(TabA;;1);INDEX(Bereich;;2);INDEX(TabA;;2)))))

so entspricht 'A2:B27' jetzt  den Formelteil INDEX(Bereich;;1):INDEX(Bereich;;2).

Gruß von Luschi
aus klein-Paris