Sortieren per Formel

[stefan69]

Hallo beisammen,

möchte per Formel die Matrix A5:L5 nach N5:X5 aufsteigend sortieren.
Leere Zellen können in Quell Matrix vorhanden sein.

So wie im Wunschergebnis angezeigt.

Kann mir wer helfen?

LG Stefan

[RPP63]

Mahlzeit!
=SORTIEREN(FILTER(A5:L5;A5:L5<>""))

Gruß Ralf

[stefan69]

Hallo Ralf,

hatte ich auch schon versucht, jedoch stimmt sie Reihenfolge nicht, wnns nur Zahlen wären würde das gehen.

LG stefan

[steve1da]

Hola,

Ralfs Formel ergibt genau dein Wunschergebnis. 
Gruß,
steve1da

[stefan69]

Hallo,

oh sry, jetzt hatte ich das Wunschergebnis falsch hinterleget.

Reihenfolge aufsteigend Sortiert soll natürlivh wie folgt sein.

179610.jpg   179610_1.jpg    179610_2.jpg 179610_3.jpg ... usw.

LG Stefan

[RPP63]

Das kann so nicht funktionieren!
Schließlich hast Du Texte.
Diese werden wie folgt sortiert:
179610.jpg
179610_1.jpg
179610_13.jpg
179610_15.jpg
179610_2.jpg
179610_3.jpg
179610_4.jpg
179610_5.jpg
179610_8.jpg
Heißt, dass Du die "Nummerierung" zwischen _ und . auf das Format 00 umstellen musst.

[RPP63]

Aber da das für mich eine nette Übung war (und Du Excel 365 hast), habe ich das mal umgesetzt:

	A	B
1		179610.jpg
2		179610_1.jpg
3	179610.jpg	179610_2.jpg
4	179610_1.jpg	179610_3.jpg
5	179610_2.jpg	179610_4.jpg
6	179610_4.jpg	179610_5.jpg
7	179610_5.jpg	179610_8.jpg
8	179610_3.jpg	179610_13.jpg
9	179610_13.jpg	179610_15.jpg
10	179610_8.jpg
11	179610_15.jpg
12

Zelle	Formel
B1	=LET(Matrix;FILTER(A1:A12;A1:A12<>""); Start;FINDEN("_";Matrix); Ende;FINDEN(".";Matrix); m_Sort;WENNFEHLER(--TEIL(Matrix;Start+1;Ende-Start-1);0); SORTIERENNACH(Matrix;m_Sort))

[LCohen]

=LET(Matrix;FILTER(A1:A12;A1:A12<>"");
Start;FINDEN("_";WECHSELN(Matrix;".";"_"));
Ende;FINDEN(".";Matrix);
m_Sort;WENNFEHLER(--TEIL(Matrix;Start+1;Ende-Start-1);0);
SORTIERENNACH(Matrix;--LINKS(Matrix;Start-1);;m_Sort;))

... falls der vordere Teil des Dateinamens sich auch ändert

[stefan69]

Sehr spannende, Sache. Funktionier tadellos.
Werde mich mal damit befassen um das im Einzelelnen zu verstehen.

Dane.

LG Stefan