Sortieren nach Größe

[Giani]

Hallo, 


ich importiere eine Excel-File aus unserem System und möchte die Spalte "Size" (Dateigröße) sortierbar machen nach aufsteigend/absteigender Größe. 
Jetzt ist das Problem, dass unser System automatisch die Werte verändert

byte = BYTES
kilobyte: KB
megabyte = MB
gigabyte = GB
...

Die Werte werden generell als Text übermittelt. Wie kann ich nach diesem Schema nun der Größe nach sortieren? 
Danke vorab!

[Martin335]

Ich bin zwar kein Experte, aber wenn ich das Richtig verstanden habe, ist dein Problem nicht das Sortieren an und für sich, sondern die Nichtbeachtung der "Einheiten" / MB, KB etc.

Da würde es vll. helfen die Zahlen von den Werten zu trennen. Sprich aus einer Spalte zwei zu machen. Dann kannst du zwei Filter setzen und es müsste klappen.

[BoskoBiati]

Hallo,

wie wäre es, wenn Du das als Excel-Tabelle vorstellen würdest?
Ist das ein Schweizer System?

[Giani]

Ich bin zwar kein Experte, aber wenn ich das Richtig verstanden habe, ist dein Problem nicht das Sortieren an und für sich, sondern die Nichtbeachtung der "Einheiten" / MB, KB etc.

Da würde es vll. helfen die Zahlen von den Werten zu trennen. Sprich aus einer Spalte zwei zu machen. Dann kannst du zwei Filter setzen und es müsste klappen.

Genau, die Einheiten werden nicht beachtet. Ich kann nur nach jeder Zahl für sich sortieren, außer sie sind identisch. (z.B. 130 KB = 130 KB)
Wenn ich die Einheit weglasse, kann nicht mehr zugeordnet werden, welcher Wert größer ist als der andere. 
Beispielsweise 130 KB und 12 GB. Die 130 KB wären größer als 12 GB, aber dabei sind 12 GB = 12 000 000 KB.

[{Boris}]

Hi,

eine von vielen Lösungen (ich geh davon aus, dass Dein Excel das Komma als Dezimaltrenner hat und es nur KB und Bytes gibt):

=WECHSELN(LINKS(A2;FINDEN(" ";A2)-1);".";",")*(1+999*ISTZAHL(FINDEN("KB";A2)))

runterkopieren und nach dieser Hilfsspalte sortieren.

[EDIT] Jetzt erst gesehen, dass es noch mehrere Einheiten gibt. Könnte man mit einer VERWEIS-Funktion einbauen - aber bis dahin ist sicher ein PQ-Verfechter da gewesen

[Martin335]

Lad doch mal einfach die Datei hoch. Das hilft in vielen Fällen.
Spreche da aus Erfahrung! ;)

[LCohen]

=
TEIL(WECHSELN(A1:A4;" ";WIEDERHOLEN(" ";19));01;19)*10^(SUCHEN(GLÄTTEN(
TEIL(WECHSELN(A1:A4;" ";WIEDERHOLEN(" ";19));20;19));"B__KB_MB_GB")-1)

oder auch (wenn auch unsystematisch) kürzer:

=LINKS(A1:A4;SUCHEN(" ";A1:A4))*10^(SUCHEN(GLÄTTEN(RECHTS(A1:A4;2));"B  KB MB GB")-1)

macht aus

234 MB
2343 KB
3 GB
254456 B

sortierbare Zahlen:

234000000
2343000
3000000000
254456

[schauan]

Hallöchen,

Lad doch mal einfach die Datei hoch. Das hilft in vielen Fällen.
Spreche da aus Erfahrung! ;)

Sollte man bei (so) einfachen Fragestellungen nicht tun ... Da sind in der Regel aussagekräftige und ggf. illustrierte Aufgabenbeschreibungen das A und O. Man kann da z.B. auch die Tabellentools nutzen, siehe die Hinweise in unserer Hilfe:

Ein neues Thema beginnen

[RPP63]

Mal die sehr interessante Formel von LCohen dynamisiert:

	A	B
1	Größe	sortiert
2	58,1 KB	12 B
3	17 B	17 B
4	15,894 MB	12,4 KB
5	12 B	58,1 KB
6	4,45674 GB	15,894 MB
7	12,4 KB	4,45674 GB

Zelle	Formel
B2	=LET(b;A2:INDEX(A:A;ANZAHL2(A:A)); s;LINKS(b;SUCHEN(" ";b))*10^(SUCHEN(GLÄTTEN(RECHTS(b;2));"B  KB MB GB")-1); SORTIERENNACH(b;s))

Gruß Ralf

[LCohen]

Da fällt mir ein: den Exponenten noch durch 3 teilen (oder "BKMGT" nehmen) und aus der 10 richtig 1024 machen. Dann ist es auf Byteebene etwas genauer. Ab 4stelligem TB kommen zwar 0 an die letzte Stelle, aber für die Genauigkeit reicht es.