SVerweis funktioniert nicht

[12855]

In der beigefügten Excel-Datei tritt ein Fehler auf, den ich einfach nicht verstehen kann. Im Reiter "Invaliditätsberechnung" sucht D2-D28 die Werte aus C2-C28 in der Matrix A31-C130. Anschließend wird der jeweilige Wert der Spalte C ausgegeben, der zum Suchergebnis in Spalte A passt. Das funktioniert auch weitestgehend, außer im Feld D12. Hier wird letztlich von Excel behauptet, dass der Wert "55" nicht in der Matrix A31-C130 zu finden sei, obwohl er im Feld A85 steht. Er kommt auch kein zweites Mal darin vor.

Weiß jemand, warum D12 nicht den Wert aus C85 ausgibt, bzw. warum er den aus A85 nicht findet? Ich bin mittlerweile echt verzweifelt.

[steve1da]

Hola,

Code:

=WENN(B12="individuell";"individuell";RUNDEN(B12*100;0))

Gruß,
steve1da

[BoskoBiati]

Hi,

da kann man aber noch einiges verbessern:

Arbeitsblatt mit dem Namen 'Invaliditätsberechnung'
	A	B	C	D	E
1		Invaliditätsgrad lt. Gliedertaxe	Faktor	Abgleich Franchise	Invaliditätsleistung
2	Arm einschließlich Schulterhaupt­ und Schultereckgelenk	70%	2	2	200.000 €
12	Bein bis unterhalb des Knies	55%	1,25	1,25	125.000 €
13	Bein bis zur Mitte des Unterschenkels	50%	1	1	100.000 €
14	Fuß	50%	1	1	100.000 €
15	große Zehe	15%	0,15	0	15.000 €
16	andere Zehe	5%	0,05	0	5.000 €
26	Magen	individuell	individuell	individuell	individuell
27	Zwölffinger­, Dünn­, Dick­ oder Enddarm	individuell	individuell	individuell	individuell
28	Lungenflügel	individuell	individuell	individuell	individuell
29
30	Leistung bei
31	1%	1%
32	2%	2%
33	3%	3%
34	4%	4%
35	5%	5%
36	6%	6%
37	7%	7%

Zelle	Formel
B2	=SVERWEIS(A2;Tarifdatenbank!$A$26:$CF$52;Hilfsrechnungen!$B$1+1;0)
C2	=WENN(B2="individuell";B2;SVERWEIS(B2;$A$31:$B$130;2;0))
D2	=WENN((Eingabe!$B$8="keine")+(B2>=Eingabe!$B$8);C2;WENN(B2="individuell";B2;0))
E2	=WENN(C2="individuell";C2;Eingabe!$B$5*Invaliditätsberechnung!C2)
B31	=SVERWEIS(RUNDEN(A31*100;0);Tarifdatenbank!$A$55:$CF$154;Hilfsrechnungen!$B$1+1;FALSCH)
A32	=RUNDEN(A31+1%;2)
B32	=SVERWEIS(RUNDEN(A32*100;0);Tarifdatenbank!$A$55:$CF$154;Hilfsrechnungen!$B$1+1;FALSCH)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg