SVerweis

[steve1da]

Da ja auf jedem Blatt die gleichen Datenarten stehen und die Blätter alle gleich aufgebaut sind, würde man normalerweise auch alles auf einem Blatt untereinander erfassen, in einer zusätzlichen Spalte dann jeweils die Nummer des Hauses. Dann lässt sich das alles wunderbar auswerten.
Ansonsten google mal nach
Zählenwenn über mehrere Blätter
Ob dir das allerdings weiterhilft, kann ich nicht einschätzen. Das sieht dann so aus:

Code:

=SUMME(ZÄHLENWENN(INDIREKT("'Haus "&ZEILE(INDIREKT("1:"&"2"))&"'!$A$5:$A$100");A6))

Die Formel muss mit Strg-Shift-Enter abgeschlossen werden.
Aktuell gilt sie nur für Haus 1 und Haus 2, bei mehreren Häusern musst du das bei Indirekt() anpassen.

[wavemaster]

steve1da,
das habe Ich jetzt nicht ganz verstanden, kannst du das mal in meiner Tabelle darsatellen.
Danke

[steve1da]

Was soll ich denn da darstellen?
Du nimmst die Formel, fügst sie in G6 ein und schließt sie mit Strg-Shift-Enter an Stelle von nur Enter ab. Danach ziehst du sie nach unten.
Kommen Häuser dazu, zB Haus 1 bis Haus 50, musst du in der ersten Formel den Teil  "1:"&"2"  in  "1:"&"50"  ändern. 
Das gilt aber nur so lange, wie die Blätter immer "Haus xy" heißen.

[wavemaster]

hallo steve1da,
jetzt hat es gefunkt. Es zählt jetzt wie oft die Position vorkommt. 
Da habe Ich mich vielleicht falsch ausgedrückt. Er soll die Menge der Positionen addieren ( nimmt die Tabelle zu grunde sollten dann 300m² angezeigt werden).
Geht das auch....
trotzdem schonmal vielen Dank.

[steve1da]

Geht auch, sogar ohne Abschluss mit Strg-Shift-Enter:

Code:

=SUMMENPRODUKT(SUMMEWENN(INDIREKT("'Haus "&ZEILE($1:$2)&"'!A5:A100");A6;INDIREKT("'Haus "&ZEILE($1:$2)&"'!C5:C100")))

[wavemaster]

steve1da,
du bist einfach ne wucht.
funktioniert tadellos.
Danke

[wavemaster]

Hallo Steve1da,
habe doch noch eine Frage.

wenn sich der Tabellenname ändert zb. von Haus 1 zu
Augusta 1.1 bis Augusta 1.6
Augusta 2
Luca 3 bis Luca 8

was muß Ich dann an der Formel ändern.


=SUMMENPRODUKT(SUMMEWENN(INDIREKT("'Haus "&ZEILE($1:$2)&"'!A5:A100");A6;INDIREKT("'Haus "&ZEILE($1:$2)&"'!C5:C100")))

Danke vorab.
Durch deine Hilfe kann Ich die Tabelle nun für mehrere Gewerke nutzen.

[steve1da]

Es war so klar dass da so kommt.

was muß Ich dann an der Formel ändern.

So ziemlich alles. Du musst jeden einzelnen Blattnamen in der Formel aufführen, und das an 2 Stellen.
Hier ist beschrieben wie das geht:
https://www.herber.de/excelformeln/src/call.pl?idx=342
Dort sind allerdings 2 Bedingungen in der Formel, "x" und "y". Du brauchst ja nur eine Bedingung, daher würde die Beispielformel so aussehen:

Code:

=SUMMENPRODUKT((T(INDIREKT("'"&{"JensF"."WF"."Boris"}&"'!A"&ZEILE(1:100)))="x")*(N(INDIREKT("'"&{"JensF"."WF"."Boris"}&"'!C"&ZEILE(1:100)))))

Allerdings scheint die Formel Schwierigkeiten mit dem Suchkriterium in Spalte A zu haben, daher muss du das auf B bzw. B6 ändern.