Registriert seit: 28.11.2017
Version(en): 2013
(28.11.2017, 14:32)Jockel schrieb: Hallo, ich würde so tun..:
PHP-Code:
=SUMMEWENNS(Plan_2018_landingsAC!$D$10:$D$18;Plan_2018_landingsAC!$A$10:$A$18;$C$4;Plan_2018_landingsAC!$C$10:$C$18;L$8)
Aber die Kriterien müssen vergleichbar sein...
Oder mit INDEX() ..:
PHP-Code:
=INDEX(Plan_2018_landingsAC!$D$10:$D$18;VERGLEICH($C$4&"*"&L$8;INDEX(Plan_2018_landingsAC!$A$10:$A$18&"*"&Plan_2018_landingsAC!$C$10:$C$18;);0))
Aber da muss noch WENNFEHLER() umzu... bei der ersten Formel nicht
Bei SUMMEWENNS zeigt er mir 0 an und bei INDEX #NV. Was meinst du mit WENNFEHLER() ? Muss ich dies noch beim INDEX mit einbauen?
Registriert seit: 10.04.2014
Version(en): Office 2019
(28.11.2017, 14:33)Der Steuerfuzzi schrieb: ...
Die Bezeichnungen in den Zellen L8:R8 müssen aber mit den Bezeichnungen in der Tabelle Plan_2018_landingsAC übereinstimmen, sonst funktioniert es nicht.
Hallo, das hatte ich bereits angemerkt...
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht
"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Registriert seit: 10.04.2014
Version(en): Office 2019
28.11.2017, 14:38
(Dieser Beitrag wurde zuletzt bearbeitet: 28.11.2017, 14:46 von Jockel.)
(28.11.2017, 14:36)onyx1985 schrieb: Bei SUMMEWENNS zeigt er mir 0 an und bei INDEX #NV. Was meinst du mit WENNFEHLER() ? Muss ich dies noch beim INDEX mit einbauen?
LESEN hilft... die Kriterien müssen vergleichbar sein A319 vs. A 319 das geht nicht... entweder beides A319 oder beides A 319..:
| Arbeitsblatt mit dem Namen 'HAM' |
| | L | M | N | O | P | Q | R |
| 8 | A 319 | A 320 | A 321 | A332 / B763 | B738 | CRJ 900 | E195 / C-Ser |
| 9 | | | | | | | |
| 10 | 12302 | 7983 | 0 | 0 | 0 | 0 | 0 |
| 11 | 12302 | 7983 | | | | | |
| Zelle | Formel |
| L10 | =SUMMEWENNS(Plan_2018_landingsAC!$D$10:$D$18;Plan_2018_landingsAC!$A$10:$A$18;$C$4;Plan_2018_landingsAC!$C$10:$C$18;L$8) |
| L11 | =WENNFEHLER(INDEX(Plan_2018_landingsAC!$D$10:$D$18;VERGLEICH($C$4&"*"&L$8;INDEX(Plan_2018_landingsAC!$A$10:$A$18&"*"&Plan_2018_landingsAC!$C$10:$C$18;);0));"") |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht
"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Registriert seit: 28.11.2017
Version(en): 2013
(28.11.2017, 14:33)Der Steuerfuzzi schrieb: Ich habe das wohl falsch verstanden, ich dachte, Du wolltest nur die Summe von HAM (Also die Zeile mit dem Ergebnis).
Hier mein Vorschlag:
Code:
=WENNFEHLER(VERWEIS(1;1/($C$4&L8=Plan_2018_landingsAC!$A$10:$A$18&Plan_2018_landingsAC!$C$10:$C$18);Plan_2018_landingsAC!$D$10:$D$18);"")
Die Bezeichnungen in den Zellen L8:R8 müssen aber mit den Bezeichnungen in der Tabelle Plan_2018_landingsAC übereinstimmen, sonst funktioniert es nicht.
Wow, klappt! Vielen Dank!!! Auf diese Funktion wäre ich überhaupt nicht draufgekommen... tausend Dank!!!
Registriert seit: 28.11.2017
Version(en): 2013
(28.11.2017, 14:38)Jockel schrieb: LESEN hilft... die Kriterien müssen vergleichbar sein A319 vs. A 319 das geht nicht... entweder beides A319 oder beides A 319
Ja ist mir erst jetzt aufgefallen, dass die nicht gleich sind... auch dir herzlichen Dank!!!
Registriert seit: 17.04.2014
Version(en): MS Office 365(32)
28.11.2017, 14:41
(Dieser Beitrag wurde zuletzt bearbeitet: 28.11.2017, 14:42 von Kuwer.)
Hallo,
oder für L10: =SUMMENPRODUKT((Plan_2018_landingsAC!A10:A18=C4)*(Plan_2018_landingsAC!C10:C18=L8)*Plan_2018_landingsAC!D10:D18)
allerdings, wie schon angemerkt, geht es nicht, wenn in L8 'A319' steht, aber in der Liste nur 'A 319' vorkommt.
Gruß Uwe
Registriert seit: 10.04.2014
Version(en): Office 2019
Hallo, nun hast du ja noch mehr Vorschläge... zusätzlich noch SUMMENPRODUKT() Also ich würde (warum wohl...?) mein SUMMEWENNS() bevorzugen... Auch weil es neben dem SUMMENPRODUKT() keine Fehlerabfrage braucht
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht
"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Registriert seit: 28.11.2017
Version(en): 2013
(28.11.2017, 14:49)Jockel schrieb: Hallo, nun hast du ja noch mehr Vorschläge... zusätzlich noch SUMMENPRODUKT() Also ich würde (warum wohl...?) mein SUMMEWENNS() bevorzugen... Auch weil es neben dem SUMMENPRODUKT() keine Fehlerabfrage braucht
Hab es auch ausprobiert und klappt wunderbar! Vielen Dank!
Eine kurze Frage noch: falls ich z.B. deine Funktion benutze und z.B. für Zelle M10 die Werte für die Typen A 320 UND 32S aufsummiert angezeigt lassen möchte was muss ich noch angeben?
Ich würde z.B. auf dem Tabellenblatt in Zelle M7 32S eingeben. Wie müsste ich den noch in die Funktion einbauen?
=SUMMEWENNS(Plan_2018_landingsAC!$D$10:$D$1000;Plan_2018_landingsAC!$A$10:$A$1000;$C$4;Plan_2018_landingsAC!$C$10:$C$1000;M$8&
M$7) ?
Registriert seit: 10.04.2014
Version(en): Office 2019
Hallo, in dem Fall komme ich auf das SUMMENPRODUKT() zurück..:
du musst das nur noch anpassen also dein M7 und M8 sind bei mir hier L8 und L13
PHP-Code:
=SUMMENPRODUKT((Plan_2018_landingsAC!A10:A18=C4)*((Plan_2018_landingsAC!C10:C18=L8)+(Plan_2018_landingsAC!C10:C18=L13));Plan_2018_landingsAC!D10:D18)
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht
"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Registriert seit: 28.11.2017
Version(en): 2013
(28.11.2017, 15:17)Jockel schrieb: Hallo, in dem Fall komme ich auf das SUMMENPRODUKT() zurück..:
du musst das nur noch anpassen also dein M7 und M8 sind bei mir hier L8 und L13
PHP-Code:
=SUMMENPRODUKT((Plan_2018_landingsAC!A10:A18=C4)*((Plan_2018_landingsAC!C10:C18=L8)+(Plan_2018_landingsAC!C10:C18=L13));Plan_2018_landingsAC!D10:D18)
Perfekt! Hat prima geklappt... vielen Dank!!! :15:
