SVERWEIS mit ARRAY kombinieren

[HoboGobo]

Hallo,

leider habe ich weder über Google-Suche (vielleicht fehlen mir die richtigen Begriffe) noch mit selber Probieren eine Lösung gefunden.

Ich möchte zwei Arrays (Zeilen) aus Zahlen in der Art wie SUMMENPRODUKT verarbeiten, allerdings ist eine der Zeilen variabel.
Mit SVERWEIS kriege ich eine Zelle, abhängig von der Zeile, aber ich benötige einen ARRAY abhängig von der Zeile.

Ich habe dazu eine Beispiel-Datei angehangen.
Ich möchte also z.B. alle Zahlen aus C1 - G1 mit den Zahlen aus Zeile 2 oder 3 wie in Summenprodukt verarbeiten, aber in einer Bedingung ähnlich SVERWEIS festlegen, ob es die zweite (Zweiter) oder dritte Zeile (Dritter) ist.

Ich hoffe, jemand kann mir helfen. 
HoboGobo

[WillWissen]

Hi,

Ich habe dazu eine Beispiel-Datei angehangen.

wenn du rechts den Button "Attachment hinzufügen" angeklickt hättest, könnten wir sie auch sehen.

[schauan]

Halöchen,

hier mal mit SUMME ein Ansatz, wie DU einen Zeilenbereich festlegen kannst.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Name	Wert1	Wert2	Wert3	Wert4
2	Ich	1	2	3	4
3	Du	5	6	7	8
4	Er	9	0	1	2
5
6			Summe
7	Name	Ich	10

Zelle	Formel
C7	=SUMME(INDEX(B2:B4;VERGLEICH(B7;A2:A4;0);1):INDEX(E2:E4;VERGLEICH(B7;A2:A4;0);1))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo André, reicht hier nicht ..:

PHP-Code:

=SUMME(INDEX(B2:E4;VERGLEICH(B7;A2:A4;0);)) 


Hier mal mehrere "Ansätze"..:

Arbeitsblatt mit dem Namen 'Blatt1'
	A	B	C	D	E
1	Name	Wert1	Wert2	Wert3	Wert4
2	Ich	1	2	3	4
3	Du	5	6	7	8
4	Er	9	0	1	2
5
6			Summe
7	Name	Er	12
8			12
9			12
10			12
11			12

Zelle	Formel
C7	=SUMME(INDEX(B2:B4;VERGLEICH(B7;A2:A4;0);1):INDEX(E2:E4;VERGLEICH(B7;A2:A4;0);1))
C8	=SUMME(INDEX(B2:E4;VERGLEICH(B7;A2:A4;0);))
C9	=SUMME(BEREICH.VERSCHIEBEN(B1:E1;VERGLEICH(B7;A2:A4;0);;;))
C10	=SUMME(WAHL(VERGLEICH(B7;A2:A4;0);B2:E2;B3:E3;B4:E4))
C11	=SUMME(INDEX((B2:E2;B3:E3;B4:E4);;;VERGLEICH(B7;A2:A4;0)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[schauan]

Hi Jörg,

ja, klar. Ich war in Gedanken nur schon beim nächsten Step, die Summe auch hinsichtlich der Spalten einzugrenzen, z.B. Summe von Ich im Bereich Wert2 : Werrt3, wobei die Begrenzung Wert2 und Wert3 dann auch per Auswahl oder Eingabe definiert werden.

[HoboGobo]

Hallo,

entschuldigt bitte die späte Rückmeldung.
Ich konnte alles lösen und bin sehr dankbar für eure Hilfe.
Dass die Datei nicht angehangen wurde, ist wohl meiner Unerfahrenheit hier im Forum geschuldet.
Das ihr mir trotzdem helfen konntet/geholfen habt, spricht sehr für das Forum.

:17: :18: