Reihe fortsetzen

[Dawoods]

Hallo,

ich muss eine Vielzahl von Lagerplätzen anlegen. Die Grundform lautet A-1-1-1 (also, Lagerort A-Gasse1-Regal1-Fach1). Weiß jemand ne Formel, wie die Reihe automatisch fortgesetzt werden kann, wenn jedes Regal 5 Fächer hat? Also mal die ersten drei Regale als Beispiel. Hoffe, das war verständlich.
Meine Formel will nicht gehen ="A-1-" & Ganzzahl((Zeile(A2)-2)/5)+1 & "-" & Rest(Zeile(A2)-2,5)+1 & "-" & Wenn(Rest(Zeile(A2)-2,5)=0,5,Rest(Zeile(A2)-2,5))
A-1-1-1
A-1-1-2
A-1-1-3
A-1-1-4
A-1-1-5
A-1-2-1
A-1-2-2
A-1-2-3
A-1-2-4
A-1-2-5
A-1-3-1
A-1-3-2
A-1-3-3
A-1-3-4
A-1-3-5

[LCohen]

A1: ="A"&BASIS(ZEILE()-1;5;3)

Die Ziffern kannst Du dann 5xWECHSELN von 4 in 5 ... bis ... 0 in 1. Und Striche bastelst Du dann auch noch rein.
____________
XL365: =LET(x;"A"&BASIS(SEQUENZ(216;;0);6;3);FILTER(x;ISTFEHLER(SUCHEN(0;x)))) ohne o.g. Aktionen

[Kuwer]

Hallo,

in A1 kommt 111
in A2 kommt =A1+1+((REST(A1/10;1)*10>4)*5)

Benutzerdefiniertes Zahlenformat stellst Du auf \A-#0-0-0 ein.

Gruß Uwe

[RPP63]

Moin Uwe!
Ich hatte etwas ähnliches wie Du.
Allerdings den gleichen Fehler! 
Wir erhalten falsche Werte, wenn die mittlere Ziffer 0 ist (laut Vorgabe wahrscheinlich nicht gewollte 201)
Es dürfte kein Regal 0 geben.

Gruß Ralf

(evtl. meldet sich der TE?)

Meine ungelenke Lösung, die gleich das richtige Format auswirft:
=LET(s;SEQUENZ(216;;111);TEXT(FILTER(s;(REST(s;10)<6)*(--RECHTS(s;2)<56)*(RECHTS(GANZZAHL(s/10)))*RECHTS(s));"A-0-0-0"))
Entsprechend bei LCohen:
=LET(x;BASIS(SEQUENZ(216;;0);6;3);TEXT(--FILTER(x;ISTFEHLER(SUCHEN(0;x)));"A-0-0-0"))

---

… wobei ich und LCohen davon ausgehen, dass es nicht nur 5 Böden, sondern auch nur 5 Regale pro Gang gibt …
Wahrscheinlich bist folglich Du auf der richtigen Spur.
(immer schön, wenn eine Threaderöffnung Interpretationsspielraum lässt.) 

[Kuwer]

Hi Ralf,

darauf hatte ich gar nicht geachtet. Ebensowenig auf die Gleitkommaproblematik. 

So dann korrigiert:

=A1+1+((GANZZAHL(REST(A1/10;1)*10)>4)*5)+(REST((A1+5)/100;1)=0)*10

Gruß, Uwe

[maninweb]

Hallo,

ein weiterer Lösungsvorschlag ...

PHP-Code:

A1=LET(N;5;M;ZUSPALTE(SEQUENZ(N;1;10;10)+SEQUENZ(1;N));WEGLASSEN(REDUCE(0;SEQUENZ(N);LAMBDA(A;V;VSTAPELN(A;TEXT(V&M;"A-0-0-0"))));1)) 


Gruß

[BoskoBiati]

Hi,

geht auch ohne neue Funktionen recht einfach:

Code:

="A-"&KÜRZEN((ZEILE()-1)/9/5;)+1&"-"&KÜRZEN(REST(ZEILE()-1;9*5)/5;)+1&"-"&REST((ZEILE()-1);5)+1

Die 9 ergibt die Anzahl von Regalen pro Gasse und die 5 die Anzahl von Fächern pro Regal. D.h., die beiden Zahlen sind die Variablen, die geändert werden müssen, um die Formel an andere Gegebenheiten anzupassen.
Um die Startzeile flexibel zu halten, genügt es, in der Startzelle "Zeile()" durch "Zeile(A1)" zu ersetzen.
Einziger Nachteil: Man muß die Formel ziehen.
Mit dieser Formel:

Code:

="A-"&KÜRZEN((ZEILE(A1:A405)-1)/9/5;)+1&"-"&KÜRZEN(REST(ZEILE(A1:A405)-1;9*5)/5;)+1&"-"&REST((ZEILE(A1:A405)-1);5)+1

spillt sie bis 9Gassen zu 9Regalen mit je 5Fächern

[Dawoods]

Hallo zusammen,
Danke für eure Mühe. Pro Gang gibt es 86 Regale. Konnte eure Vorschläge nicht alle anwenden und euch antworten. In der Arbeit kam noch mehr Arbeit dazwischen

[RPP63]

Dir liegt ein brainstorming mit richtig vielen, richtig guten Lösungen vor.
Mach was draus, falls Du Zeit findest.

[BoskoBiati]

Hi,

Code:

="A-"&KÜRZEN((ZEILE(A1:A4300)-1)/86/5;)+1&"-"&KÜRZEN(REST(ZEILE(A1:A4300)-1;86*5)/5;)+1&"-"&REST((ZEILE(A1:A4300)-1);5)+1

10Gassen a 86 regale