Rechnen nach Kategorie

[Sabotaz]

Hallöchen!

Ich hab schon wieder eine Blockade. Ich suche eine Möglichkeit, aus einer Tabelle von Aufträgen bestimmte Werte für Statistiken herauszufiltern, komme aber da nicht weiter. Gern möchte ich wieder bei einer Formeln bleiben. 

Im Anhang eine Beispieldatei.

Ziel ist, dass die Werte von Aufträgen addiert werden, wenn bestimmte Voraussetzungen gegeben sind: 
Typ? Status? Erledigt?

Ich danke schonmal und Grüße!

[shift-del]

Moin

Arbeitsblatt mit dem Namen 'Tabelle1'
	I	J	K
1		Anzahl	Wert
2	offene Reparaturen Status D	1	1.166,00 €
3	zugewiesene Reparaturen Status D	0	0,00 €
4	Offene Reparaturen nicht Status D	1	4.255,00 €
5	erledigte Termine	2	9.283,00 €
6	erledigte Reparaturen	1	9.123,00 €

Zelle	Formel
J2	=ANZAHL(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($D$2:$D$6="D")*($F$2:$F$6="");""))
K2	=SUMME(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($D$2:$D$6="D")*($F$2:$F$6="");0))
J3	=ANZAHL(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($D$2:$D$6="D")*($B$2:$B$6<>"");""))
K3	=SUMME(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($D$2:$D$6="D")*($B$2:$B$6<>"");0))
J4	=ANZAHL(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($D$2:$D$6<>"D")*($F$2:$F$6="");""))
K4	=SUMME(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($D$2:$D$6<>"D")*($F$2:$F$6="");0))
J5	=ANZAHL(FILTER($E$2:$E$6;($F$2:$F$6="JA");""))
K5	=SUMME(FILTER($E$2:$E$6;($F$2:$F$6="JA");0))
J6	=ANZAHL(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($F$2:$F$6="JA");""))
K6	=SUMME(FILTER($E$2:$E$6;($A$2:$A$6="REP")*($F$2:$F$6="JA");0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[Sabotaz]

Soso. Filter also! Großartig, darauf wär ich nicht gekommen, wusste aber auch nicht, wie ich das Dr. Google erklären sollte... 

Vielen Dank! 

Thema gelöst!

[HKindler]

Hi,

dadurch, dass hier nur UND-Bedingungen vorkommen und auch nur verglichen (=, <>, >, < etc.) und nichts gerechnet (z.B. MONAT($G$2:$G$6)=2 ) wird, würde auch ZÄHLENWENNS und SUMMEWENNS funktionieren. Das hat den Vorteil dass man ungestraft ganze Spalten angeben kann. Außerdem funktioniert es auch bei älteren Excel-Versionen.

z.B.
J2: =ZÄHLENWENNS(A:A;"REP";D:D;"D";F:F;"")
K2: =SUMMEWENNS(E:E;A:A;"REP";D:D;"D";F:F;"")

[Sabotaz]

Ich habe mich für die Variante von HKindler entschieden und sie funktioniert super. Der Filter-Funktion werde ich mich trotzdem mal demnävhst annehmen, könnte interessant sein!

Danke und Grüße!