Prüfliste für Fahrzeuge erstellen

[SteffiT]

Hallo liebe Excel-Profis,

meine Excel-Liste lässt mich langsam verzweifeln. Ich soll für unsere KFZ-Abteilung eine Liste erstellen, in der hervorgeht, welche Fahrzeuge zu welcher Prüfung für einen bestimmten Monat anstehen. D.h. mein Kollege möchte gerne oben einen beliebigen Monat eintragen und Excel soll ihm eine Liste mit den Fahrzeugen und den anstehenden Prüfungen auswerfen. Im 2. Tabellenblatt befinden sich die Fahrzeugdaten. Mit der SVERWEIS-Funktion komme ich nicht weiter und auch mit DBAUSZUG bekam ich nichts heraus.

Ich danke euch schon einmal im Voraus für eure Hilfe.

Steffi

[Hydronaut]

Hallo Steffi

Hilfsspalte in Tabellenblatt "Fahrzeuge":

Code:

=ZÄHLENWENN(D2:E2;G$1)>0

In G1 steht der gesuchte Monat.
Und dann auf WAHR filtern.

[WillWissen]

Hi,

oder so:

Tabelle1

	A	B	C	D	E
1	Monat:	september
2
3
4
5
6	Zu prüfende Fahrzeuge
7	ME-AB 817	VW Caddy	Hr. Bayer	Juli	April

Formeln der Tabelle

Zelle Formel A7 =INDEX(Fahrzeuge!A:A;VERGLEICH(Tabelle1!$B$1;Fahrzeuge!F:F;0)) B7 =SVERWEIS(Tabelle1!$A7;Fahrzeuge!$A$1:$E$50;SPALTE(B1);0) C7 =SVERWEIS(Tabelle1!$A7;Fahrzeuge!$A$1:$E$50;SPALTE(C1);0) D7 =SVERWEIS(Tabelle1!$A7;Fahrzeuge!$A$1:$E$50;SPALTE(D1);0) E7 =SVERWEIS(Tabelle1!$A7;Fahrzeuge!$A$1:$E$50;SPALTE(E1);0)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Verweis-Formeln nach rechts ziehen

[Jockel]

Hi Günter, da bekommst du aber nur maximal ein Fahrzeug heraus...

[Jockel]

Hallo Steffi

Hilfsspalte in Tabellenblatt "Fahrzeuge":

Code:

=ZÄHLENWENN(D2:E2;G$1)>0

In G1 steht der gesuchte Monat.
Und dann auf WAHR filtern.

Hi Detlef, das müßte so..:

Code:

=ZÄHLENWENN(D2:F2;G$1)>0

[Jockel]

Hallo, formeltechnisch würde ich so tun..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	Monat:	April
2
3
4
5
6	Zu prüfende Fahrzeuge
7	ME-AB 803	HU
8	ME-AB 805	Sicherheitsüberprüfung
9	ME-AB 817	AU
10
11

Zelle	Formel
A7	{=WENNFEHLER(INDEX(Fahrzeuge!$A$2:$A$100;KKLEINSTE(WENN((Fahrzeuge!$D$2:$D$100=$B$1)+(Fahrzeuge!$E$2:$E$100=$B$1)+(Fahrzeuge!$F$2:$F$100=$B$1);ZEILE($A$1:$A$99));ZEILE(A1)));"")}
B7	=WENN(A7="";"";INDEX(Fahrzeuge!$A$1:$F$1;;VERGLEICH($B$1;INDEX(Fahrzeuge!$A$1:$G$100;VERGLEICH(A7;Fahrzeuge!$A$1:$A$100;0););0)))

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[WillWissen]

Hi Günter, da bekommst du aber nur maximal ein Fahrzeug heraus...

Hi Jörg,

ich bin wegen der Beispieltabelle auch nur von einem Fahrzeug ausgegangen. Aber das lässt sich ja leicht ändern:

Ein Hilfsspalte im Blatt Fahrzezuge

Fahrzeuge

	A	B	C	D	E	F	G
1	Kennzeichen	Fahrzeug	Ansprechpartner/in	HU	AU	Sicherheitsüberprüfung
2	ME-AB 803	VW Caddy	Hr. Meier	April	Mai	Januar
3	ME-AB 805	VW Caddy	Hr. Müller	Mai	Februar	April	x
4	ME-AB 815	VW Caddy	Hr. Schmitz	Juni	Oktober	Januar
5	ME-AB 817	VW Caddy	Hr. Bayer	Juli	April	April	x

Formeln der Tabelle

Zelle Formel G2 =WENN(F2=Tabelle1!$B$1;"x";"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8


Und das im Blatt 1:

Tabelle1

	A	B	C	D	E
1	Monat:	april
2
3
4
5
6	Zu prüfende Fahrzeuge
7	ME-AB 805	VW Caddy	Hr. Müller	Mai	Februar
8	ME-AB 817	VW Caddy	Hr. Bayer	Juli	April
9
10

Formeln der Tabelle

Zelle Formel A7 {=WENN(ZEILEN($1:1)>ZÄHLENWENN(Fahrzeuge!G:G;"x");"";INDEX(Fahrzeuge!A:A;KKLEINSTE(WENN(Fahrzeuge!G$1:G$99="x";ZEILE($1:$99));ZEILE(A1))))} B7 =WENNFEHLER(SVERWEIS($A7;Fahrzeuge!$A$1:$E$50;SPALTE(B1);0);"") C7 =WENNFEHLER(SVERWEIS($A7;Fahrzeuge!$A$1:$E$50;SPALTE(C1);0);"") D7 =WENNFEHLER(SVERWEIS($A7;Fahrzeuge!$A$1:$E$50;SPALTE(D1);0);"") E7 =WENNFEHLER(SVERWEIS($A7;Fahrzeuge!$A$1:$E$50;SPALTE(E1);0);"")

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[Fennek]

Hallo,

hier eine Lösung mit "Aggregat", die Bereiche müssen noch an die realen Daten angepasst werden.

mfg

[Jockel]

Hi Günter, ich kann das gewünschte Ergebnis in Tabelle1 Spalte B nicht finden...

[Jockel]

Hallo,

hier eine Lösung mit "Aggregat", die Bereiche müssen noch an die realen Daten angepasst werden.

mfg

Hallo, und vorallem an das gewünschte Ergebnisschema...