Probleme mit WENN UND ODER verschachteln

[sea-spin]

Hallo,

habe da mal wieder ein Problem.

Ich benötige ein Ergebnis, was aufgrund mehrerer Prüfungen erstellt werden soll.

Im Moment komme ich einfach nicht weiter.

Die Excel Liste ist im Anhang

Unter O (gelb) meine Berechnung, unter P (grün), das sollte rauskommen.

Ein paar Werte werden falsch berechnet.

[shift-del]

Hallo

Zumindest hast du im Bereich I:N nicht alle Bezüge auf Zeile 2 fixiert.

Code:

=WENN(UND(ODER(ODER(UND(UND(C2=0;F2<1200;G2<1200;H2<1200;(F2+G2+H2)<3600;E2<31,5)))));A2*2+$I$2;(WENN(A2<1,01;J$2+(B2*1,19-$I$2);WENN(A2<1,51;K$2+(B2*1,19-$I$2);WENN(A2<2,01;L$2+(B2*1,19-$I$2);WENN(A2<2,96;M$2+(B2*1,19-$I$2);A2*N$2+(B2*1,19-$I$2)))))))

Spalte D geht überhaupt nicht in die Berechnung ein.

Mehr kann man als Außenstehender dazu nicht schreiben.

[sea-spin]

Hallo,

vielen Dank, habe ich geändert und nun habe ich auch den Fehler gefunden, lag an der Berechnung mit 100 %

Nun bin ich etwas weiter und habe diese Formel zusammengestellt

=WENN(UND(ODER(ODER(UND(UND(E2=0;H2<1200;I2<1200;J2<1200;(H2+I2+J2)<3600;G2<31,5)))));C2*(1+$Q$2)+($T$2-$L$2);(WENN(C2<1,01;$M$2+(D2*1,19-$L$2);WENN(C2<1,51;$N$2+(D2*1,19-$L$2);WENN(C2<2,01;$O$2+(D2*1,19-$L$2);WENN(C2<2,96;$P$2+(D2*1,19-$L$2);C2*(1+$Q$2)+(D2*1,19-$L$2)))))))

jetzt würde ich gerne den DANN_WERT =C2*(1+$Q$2)+($T$2-$L$2)

Durch folgendes ersetzen.....

(WENN(C2<1,01;$M$2+($T$2-$L$2);WENN(C2<1,51;$N$2+($T$2-$L$2);WENN(C2<2,01;$O$2+($T$2-$L$2));(WENN(C2<2,96;$P$2+($T$2-$L$2);C2*(1+$Q$2)+( $T$2-$L$2)))))))

Wenn ich das einfach austausche erhalte ich eine Fehlermeldung mit zuviel Argumente.

Habe ich da irgendwo einen Klammerfehler, den ich übersehe?

[LCohen]

=WENN(C2<2,96;VERWEIS(C2-1%;{0.1.1,5.2};M2:P2);C2*(1+Q2))+T2-L2

[sea-spin]

Vielen Dank. Versuche ich morgen mal nachzuvollziehen,

aber wieso kann ich nicht einfach den kurzen Therm durch den langen Therm ersetzen?

Habe ich da einen Klammerfehler? 

Excel soll ja bis zu 64 verschachtelte WENN Funktionen unterstützen

Was mach ich hier falsch?

[LCohen]

1. Deine erste Formel funktioniert.
2. Schreibe den "Rot-Ersatz" separat in eine Zelle (mit = natürlich; muss nun ein Ergebnis geben).
3. Das, was ersetzt werden soll, behandelst Du genauso wie 2. 
4. Tue 2. in die Zwischenablage, markiere 3. sorgfältig und dann Strg-V.

Von Thermalbädern war hier übrigens nicht die Rede ;)

[sea-spin]

Hallo,

vielen Dank, werde ich mir anschauen und hoffe es klappt.

Danke

[quinoman]

Hallo !

Ja, es liegt an einer Klammer. An der rot markierten Stelle wird der verschachtelte Wenn - Ausdruck durch die zweite schließende Klammer beendet.
(WENN(C2<1,01;$M$2+($T$2-$L$2);WENN(C2<1,51;$N$2+($T$2-$L$2);WENN(C2<2,01;$O$2+($T$2-$L$2));(WENN(C2<2,96;$P$2+($T$2-$L$2);C2*(1+$Q$2)+( $T$2-$L$2)))))))
Gruss, Quinoman

[quinoman]

=WENN(C2<2,96;VERWEIS(C2-1%;{0.1.1,5.2};M2:P2);C2*(1+Q2))+T2-L2

Hallo, sehr elegante Lösung. Aber ich bekomme beim Wert 2,01 (und nur damit) ein anderes Ergebnis, als mit der (korrigierten) "Wenn-Schachtel", oder habe ich etwas falsch verstanden/übersehen ?
Grüße, Quinoman

[LCohen]

Du hast ja Augen im Kopf und siehst in meiner Formel, wo die 2,01 behandelt wird (auch wenn man sie nicht sieht). Dann musst Du den Wert entsprechend ändern, z.B.:

{0.1.1,5.2,01}
{0.1.1,5.1,99}

Rein logisch müsste das Problem aber auch bei 1,01 und 1,51 auftreten, denn Du wirst ja wohl immer den gleichen Vergleichsoperator gewählt haben wollen.