Position einer Zelle finden, durch die ersten Zeichen eines Strings

[Kyuboy]

Kann mir jemand evt bei diesem Problem helfen,

ich möchte das VBA das Excel Sheet durchsucht nach "PS:"
das sind in jedem fall die ersten 3 Zeichen der Zelle und immer in Spalte A,
danach soll mir VBA die Position der ZELLE ausgeben. Z.B.  "Wort in Zeile 3 Gefunden."

im Anhang eine Beispieldatei.

Danke !

MFG

[Werner.M]

Hallo,

so:

Code:

Private Sub CommandButton1_Click()
Dim raFund As Range

With Worksheets("Tabelle1")
   Set raFund = .Columns(1).Find(what:="PS:", LookIn:=xlValues, lookat:=xlPart)
   If Not raFund Is Nothing Then
       MsgBox "Wort in Zeile " & raFund.Row & " gefunden."
   Else
       MsgBox "Suchbegriff nicht vorhanden."
   End If
End With

Set raFund = Nothing
End Sub

Gruß Werner

[Werner.M]

Hallo,

oder z.B. so:

Code:

Private Sub CommandButton1_Click()
Dim raFund As Range

With Worksheets("Tabelle1")
   Set raFund = .Columns(1).Find(what:="PS:", LookIn:=xlValues, lookat:=xlPart)
   If Not raFund Is Nothing Then
       Application.Goto raFund, True
       'MsgBox "Wort in Zeile " & raFund.Row & " gefunden."
   Else
       MsgBox "Suchbegriff nicht vorhanden."
   End If
End With

Set raFund = Nothing
End Sub

Ohne Meldungsausgabe, die Fundzelle wird als erste Zelle oben links angezeigt.


Gruß Werner

[00202]

Hallo, :19:

eine weitere Möglichkeit: :21:

Code:

Option Explicit
Private Sub CommandButton1_Click()
    On Error Resume Next
    MsgBox "Wort in Zeile " & Evaluate("=MATCH(""PS:*"",A:A,0)") & " gefunden!"
    'Oder
    'Application.Goto Cells(Evaluate("=MATCH(""PS:*"",A:A,0)"), 1), True
End Sub

[snb]

Code:

Sub M_snb()
  On Error Resume Next

  With Tabelle1.Columns(1).Find("PS:*")
    .Parent.Shapes.AddPicture "G:\OF\camera.jpg", -1, -1, .Left, .Top, 100, 100
  End With
End Sub

[Kyuboy]

Vielen vielen Dank,

hat funktioniert, dieses Forum ist echt hilfreich wenn man nicht mehr weiter weiß.

MFG