Outlook Exportieren, Pfad Probleme

[DoubleDenU]

Moin,

unzwar ich hab ein kleines Problem.
Ich möchte unabhänig vom Pfad eine PDF erstellen und diese in Outlook einfügen zum versenden.

Eigentlich funktioniert alles Perfekt, allerdings nicht auf einen anderen Rechner.
Bei mir speichert er Temporär die PDF und fügt sie in Outlook ein.

Bei anderen kommt ein Laufzeitfehler "2147024894" - Überprüfen sie den Pfad und Dateinamen.


Code:

Code:

Dim strPDF As String
Dim OutlookApp As Object, strEmail As Object
Set OutlookApp = CreateObject("Outlook.Application")
Set strEmail = OutlookApp.CreateItem(0)


Range("A1:J144").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
   Range("N4") & ".pdf", Quality:=xlQualityStandard _
  , IncludeDocProperties:=False, IgnorePrintAreas:=False, OpenAfterPublish _
  :=False

strPDF = Range("N4") & ".pdf"
With strEmail
  .To = ""
  .Subject = Range("N4")
  .Body = "Hier könnte ihr Text stehen"
  .Attachments.Add strPDF
  .Display
  Kill strPDF
End With
   
Set OutlookApp = Nothing
Set strEmail = Nothing
End Sub

Er erkennt den strPDF nicht. Aber wie gesagt nur bei anderen Computern. Ich habe die EXEL auf ein Sharepoint bei mir funktioniert es ohne Probleme?

[Niko]

Vielleicht mal so probieren...habe Environ hinzugefügt

Code:

Sub ExportundEmail()
    Dim strPDF As String
    Dim OutlookApp As Object, strEmail As Object
    Set OutlookApp = CreateObject("Outlook.Application")
    Set strEmail = OutlookApp.CreateItem(0)

    Range("A1:J144").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
       Environ("temp") & "\" & Range("N4") & ".pdf", Quality:=xlQualityStandard _
      , IncludeDocProperties:=False, IgnorePrintAreas:=False, OpenAfterPublish _
      :=False

    strPDF = Environ("temp") & "\" & Range("N4") & ".pdf"
    With strEmail
      .To = ""
      .Subject = Range("N4")
      .Body = "Hier könnte ihr Text stehen"
      .Attachments.Add strPDF
      .Display
      Kill strPDF
    End With

    Set OutlookApp = Nothing
    Set strEmail = Nothing
End Sub

bei mir funktioniert es so ohne Probleme, anbei die Datei zum testen. 
  Mappe_Mail_export.xlsm (Größe: 17,56 KB / Downloads: 1)

Hoffe es hilft Ihnen!

[DIZA]

zur Info CP
https://www.ms-office-forum.net/forum/sh...p?t=385513