Nach der vorderen Zelle etwas einfügen

[respecter11]

Guten Tag miteinander

Ich bin wieder mal da und habe eine Frage
Ich habe eine Datei erstellt, bei welcher man angeben kann, wie man sich selber sieht mit einer Auswahl zwischen 1-10.
Ich möchte von diesen Angaben die 3 Besten heraussuchen und auflisten. Sollte es mehr als 3 haben, die die Besten sind, so sollen die Besten 4 oder 5 aufgelistet werden. Wenn es sogar mehr als 5 hat, so soll eine Nachricht kommen mit "Vorsicht es gibt mehr als 5 mit der selben Anzahl!".
Das meiste funktioniert bereits, jedoch weiss ich nicht mehr wie ich die Beschreibung neben der Zahl bei den Besten 3 heraussuche, falls mehrere Zahlen gleich sind.
Wie funktioniert dies?

Falls jemand nicht genau weiss was ich meine, der kann mir gerne schreiben

/Respecter11

[neopa]

Hallo,

ich geh davon aus das "1-10" gar nicht gewertet werden soll.

In C28: =WENNFEHLER(AGGREGAT(14;6;C$8:C$22;ZEILE(A1));"")
in D28: =WENN(C28="";"";INDEX(D:D;AGGREGAT(15;6;ZEILE(Z$8:Z$22)/(LINKS(C$8:C$22;2)=C28&"");ZÄHLENWENN(C$28:C28;C28))))

Beide Formeln nach unten kopieren und nach rechts.

[BoskoBiati]

Hi,


mit Excel solltest Du Dich noch etwas intensiver befassen.

Arbeitsblatt mit dem Namen 'Selbsteinschätzung'
	C	D
28	6	Präsenz
29	5	Kritikfähigkeit
30	3	Anspruchsniveau
31	3	Belastbarkeit
32	3	Durchhaltevermögen
33	Es gibt noch mehr Werte mit 3 Punkten!

Zelle	Formel
C28	=WENNFEHLER(KGRÖSSTE(C$8:C$22;ZEILE(A1));"")
D28	=WENNFEHLER(INDEX(D:D;AGGREGAT(15;6;ZEILE($D$8:$D$22)/(C$8:C$22=C28);ZÄHLENWENN(C$28:C28;C28)));"")
C33	=WENN(ZÄHLENWENN(C$8:C$22;C32)>ZÄHLENWENN(C$28:C$32;C32);"Es gibt noch mehr Werte mit "&C32&" Punkten!";"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[neopa]

Hallo Edgar,

richtig, die auch gefragte Formel für C33 hatte ich ignoriert.

[respecter11]

Hi,


mit Excel solltest Du Dich noch etwas intensiver befassen.

Arbeitsblatt mit dem Namen 'Selbsteinschätzung'
	C	D
28	6	Präsenz
29	5	Kritikfähigkeit
30	3	Anspruchsniveau
31	3	Belastbarkeit
32	3	Durchhaltevermögen
33	Es gibt noch mehr Werte mit 3 Punkten!

Zelle	Formel
C28	=WENNFEHLER(KGRÖSSTE(C$8:C$22;ZEILE(A1));"")
D28	=WENNFEHLER(INDEX(D:D;AGGREGAT(15;6;ZEILE($D$8:$D$22)/(C$8:C$22=C28);ZÄHLENWENN(C$28:C28;C28)));"")
C33	=WENN(ZÄHLENWENN(C$8:C$22;C32)>ZÄHLENWENN(C$28:C$32;C32);"Es gibt noch mehr Werte mit "&C32&" Punkten!";"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Danke dir vielmals jetzt hat es einwandfrei geklappt danke dir

/Respecter11