Nach Datum suchen

[ich2110]

Hallo und guten Tag,

ich benötige mal wieder Eure kompetente Hilfe.

Ich habe eine Spalte in meiner Datenbank in der sich Geburtsdaten befinden.

Formatiert nach Datum z. B.: 14.07.62 wobei im Feld dann 14.07.1962 steht.

Jetzt möchte ich ganz schnell herausfinden, wer heute Geburtstag hat.
Das, was ich mir gedacht habe, funktioniert leider nicht. 

Bin gespannt, wer mir hier helfen kann.

[WillWissen]

Hi,

etwas in dieser Art? Du brauchst dazu eine Hilfsspalte; der Rest ist Spielerei.

Arbeitsblatt mit dem Namen 'Daten'
	I	J	K	L	M
1	Geboren	Geb.-Liste	Tage bis zum Geburtstag	aktuelles Alter in Jahren	Jubiläen ab 50
2	13.01.67	13.01.	196	56
3
4	01.07.58	01.07.	0	65	65
5
6	14.07.60	14.07.	13	62
7	01.09.61	01.09.	62	61
8	27.04.68	27.04.	301	55	55

Zelle	Formel
J2	=WENN(I2<>"";DATUM(JAHR(HEUTE());MONAT(I2);TAG(I2));"")
K2	=WENN(I2<>"";DATUM(JAHR(HEUTE())+((MONAT(I2)*50+TAG(I2)-MONAT(HEUTE())*50-TAG(HEUTE()))<0);MONAT(I2);TAG(I2))-HEUTE();"")
L2	=WENN(I2<>"";WENN(DATUM(JAHR(HEUTE());MONAT(I2);TAG(I2))<=HEUTE();JAHR(HEUTE())-JAHR(I2);JAHR(HEUTE())-JAHR(I2)-1);"")
M2	=WENN([@Geboren]="";"";WENN((REST(JAHR(HEUTE())-JAHR(I2);5)=0)*((JAHR(HEUTE())-JAHR(I2))>49);JAHR(HEUTE())-JAHR(I2);""))

Zelle	bedingte Formatierung...	Format
K2	1: J2=HEUTE()	abc
K2	2: UND(HEUTE()<=J2;J2-HEUTE()<=10)	abc

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[ich2110]

Hi,

etwas in dieser Art? Du brauchst dazu eine Hilfsspalte; der Rest ist Spielerei.

Hallo Günter,

danke für Deine Tipps.

Somit heißt das im Klartext, es geht nur über eine Spalte in der ich die diese Daten: 16.04. oder andere eintrage?
Das war gerade das, was ich nicht wollte.  

Aber dann muss ich diese Spalte mal ganz am Ende einfügen, damit sie mir nicht meine gesamte Tabelle zerpflückt.

Ich hatte es mir aber schon fast gedacht.

Wie bekomme ich denn jetzt z. B. aus Spalte T = 11.04.1966 das Datum 11.04. in Spalte CY?

Wünsche Dir ein schönes Wochenende!

[WillWissen]

Hi Ingrid,

Code:

Das war gerade das, was ich nicht wollte.

was spricht denn gegen eine Hilfsspalte? Die kannst du doch einfach ausblenden. Sie ist ja auschließlich dazu da, alle Daten auf das aktuelle Jahr umzuformen und ist benutzerdef. TT.MM. formatiert.

Code:

Wie bekomme ich denn jetzt z. B. aus Spalte T = 11.04.1966 das Datum 11.04. in Spalte CY?

Pass einfach die Formel aus Spalte J aus meinem Beispiel auf die gewünschte Spalte an:

Code:

=WENN(T2<>"";DATUM(JAHR(HEUTE());MONAT(T2);TAG(Z2));"")

[shift-del]

Moin Ingrid

Ganz schnörkellos.

Code:

=TEXT(A2;"TTMM")=TEXT(HEUTE();"TTMM")

[MisterBurns]

Die Formel von shift-del lässt sich auch als bedingte Formatierung anwenden, dann werden Geburtstage farblich hervorgehoben. Ein Filter nach der Farbe gesetzt bietet eine Übersicht mit 3 Klicks.

[Case]

Jetzt möchte ich ganz schnell herausfinden, wer heute Geburtstag hat.

Hallo,  

schnell geht es auch per VBA:

  Geburtstag_wer_hat_heute_CEF.xlsb (Größe: 79,24 KB / Downloads: 6)

[RPP63]

Moin!
Ganz schnell geht es auch mit einem aktuellen Excel (2021, 365 und Online).
Liste von 1999 Geburtsdaten.

	A	B	C	D	E	F	G
1	GebDat	Name	Vorname	02.07.2023	GebDat	Name	Vorname
2	11.01.1960	Name0900	Vorname0900		02.07.1966	Name1540	Vorname1540
3	16.01.1960	Name0384	Vorname0384		02.07.1977	Name1884	Vorname1884
4	23.01.1960	Name1952	Vorname1952		02.07.1988	Name1699	Vorname1699
5	26.01.1960	Name0458	Vorname0458		02.07.1989	Name1282	Vorname1282
6	31.01.1960	Name0725	Vorname0725		02.07.1998	Name0986	Vorname0986
7	01.03.1960	Name0373	Vorname0373		02.07.1999	Name0460	Vorname0460
8	15.03.1960	Name1524	Vorname1524
9	25.03.1960	Name0824	Vorname0824
10	08.04.1960	Name0902	Vorname0902
11	14.04.1960	Name0227	Vorname0227
12	15.04.1960	Name1160	Vorname1160

Zelle	Formel
D1	=HEUTE()
E2	=FILTER(A2:C2000;TEXT(A2:A2000;"TTMM")=TEXT(D1;"TTMM"))

Gruß Ralf

[Case]

Hallo,  

da du ja offensichtlich viel mit "Daten" zu tun hast, lohnt auch ein Blick auf "Power Query bzw. Daten - Daten abrufen und transformieren". Damit geht das ganz, ganz schnell.
Einmal eingerichtet kannst du dir z. B. runde Geburtstage, Jubiläen oder was auch immer ausgeben lassen.  

Das geht natürlich auch mit Formeln und VBA. Es kommt immer darauf an, was du erreichen möchtest. VBA hat den Vorteil, dass du z. B. gleich eine Mail verschicken könntest, eine Serienbrief anstossen, oder eine Grußkarte drucken, oder, oder...