Monatskalender erstellen

[Roadie]

Hallo, Excel-Freunde!

Für eine bestimmte Aufgabenstellung suche ich mir gerade einen Wolf, ob es eine einfache Lösung gibt - finde aber nichts.

Die Aufgabe sieht so aus:
In Zelle A1 steht die Nummer des Monats (z. B. 8 für August), in Zelle B1 steht das Jahr (z. B. 2012).
In den Zellen A3 bis G3 stehen die Kürzel für die Wochentage ("MO" ... "SO")
In den nächsten Zeilen, also 4 bis ..., sollen jetzt die Tageszahlen des Monats erscheinen, natürlich passend zum jeweiligen Wochentag.
Für den August 2012 wäre also die "1" in der Zelle C4 zu sehen (A4 und B4 bleiben leer; in D4 steht eine "2" usw., A5 enthält eine "6" usw.)

Gibt es dafür in Excel eine "einfache" Lösung? Momentan breche ich mir bei einem Work-around die Finger, indem ich das Startdatum 01.08.2012 auf seinen Wochentag untersuche, damit die "1" in die richtige Spalte gesetzt wird. Die nachfolgenden Tage rechne ich dann einfach durch (vorherige Zelle + 1).

Hat jemand eine praktikable Lösung?

Besten Dank schon mal!

Der Roadie

[WillWissen]

Hi,


Schau doch mal hier rein

http://www.herber.de/excelformeln und bi...elcher=284

[Peter]

Hallo,

ich bin momentan etwas in Eile, deswegen nur ganz kurz:

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C	D	E	F	G	H	I	J	K
2	Januar 2010								Monat	Jahr
3	M	D	M	D	F	S	S		Januar	2010
4					1	2	3
5	4	5	6	7	8	9	10
6	11	12	13	14	15	16	17
7	18	19	20	21	22	23	24
8	25	26	27	28	29	30	31
9

Zelle	Formel
B2	=DATUM(K3;MONAT(J3&0);1)
B4	=WENN(MONAT($B$2+SPALTE(A$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2))=MONAT($B$2);$B$2+SPALTE(A$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2);"")
C4	=WENN(MONAT($B$2+SPALTE(B$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2))=MONAT($B$2);$B$2+SPALTE(B$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2);"")
D4	=WENN(MONAT($B$2+SPALTE(C$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2))=MONAT($B$2);$B$2+SPALTE(C$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2);"")
E4	=WENN(MONAT($B$2+SPALTE(D$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2))=MONAT($B$2);$B$2+SPALTE(D$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2);"")
F4	=WENN(MONAT($B$2+SPALTE(E$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2))=MONAT($B$2);$B$2+SPALTE(E$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2);"")
G4	=WENN(MONAT($B$2+SPALTE(F$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2))=MONAT($B$2);$B$2+SPALTE(F$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2);"")
H4	=WENN(MONAT($B$2+SPALTE(G$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2))=MONAT($B$2);$B$2+SPALTE(G$1)+7*(ZEILE($A1)-1)-WOCHENTAG($B$2;2);"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Die Anpassung auf die von dir genannten Zellen solltest du selbst hinbekommen, oder?

[Roadie]

@ WillWissen
Danke für deinen Tipp. Den hatte ich auch schon ausprobiert, hat mir aber nicht weitergeholfen

@Peter
Exakt das ist es, was ich brauche! Vielen Dank! :18:

Ich schließe damit diesen Trööt.

[Jockel]

Hallo auch von mir ein Lösungsvorschlag..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1	10	2014
2
3	Mo	Di	Mi	Do	Fr	Sa	So
4			1	2	3	4	5
5	6	7	8	9	10	11	12
6	13	14	15	16	17	18	19
7	20	21	22	23	24	25	26
8	27	28	29	30	31	1	2
9	3	4	5	6	7	8	9

Zelle	Formel
A4	=WENN(WOCHENTAG($A$1&"/"&$B$1;2)=SPALTE(A$1);($A$1&"/"&$B$1)+0;"")
B4	=WENN(A4<>"";A4+1;WENN(WOCHENTAG($A$1&"/"&$B$1;2)=SPALTE(B$1);($A$1&"/"&$B$1)+0;""))
C4	=WENN(B4<>"";B4+1;WENN(WOCHENTAG($A$1&"/"&$B$1;2)=SPALTE(C$1);($A$1&"/"&$B$1)+0;""))
D4	=WENN(C4<>"";C4+1;WENN(WOCHENTAG($A$1&"/"&$B$1;2)=SPALTE(D$1);($A$1&"/"&$B$1)+0;""))
E4	=WENN(D4<>"";D4+1;WENN(WOCHENTAG($A$1&"/"&$B$1;2)=SPALTE(E$1);($A$1&"/"&$B$1)+0;""))
F4	=WENN(E4<>"";E4+1;WENN(WOCHENTAG($A$1&"/"&$B$1;2)=SPALTE(F$1);($A$1&"/"&$B$1)+0;""))
G4	=WENN(F4<>"";F4+1;WENN(WOCHENTAG($A$1&"/"&$B$1;2)=SPALTE(G$1);($A$1&"/"&$B$1)+0;""))
A5	=MAX(A4:G4)+1
B5	=A5+1
C5	=B5+1
D5	=C5+1
E5	=D5+1
F5	=E5+1
G5	=F5+1

Zelle	bedingte Formatierung...	Format
A4	1: =MONAT(A4)<>$A$1	abc

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Roadie]

@Jockel

Auch dir vielen Dank! Ich teste eure Vorschläge!