Mittelwerte in Abhängigkeit anderer Spalte

[Hopfenmeile]

Guten Tag,

ich möchte die Mittelwerte aus Spalte B ermitteln, wenn ein Wert in Spalte C steht.
zB Steht in  C10 ein Wert, so nimmt Excel den Mittelwert von B10:B10, steht in C9 ein Wert, so soll in Spalte D stehen =MITTELWERT(B9:B10), steht in C8 ein wert, dann =MITTELWERT(B8:B10)...

ist nun in Spalte C über der zuletzt befüllten Zelle, eine leere Zelle, so soll Excel beim Mittelwert rechnen, wieder von neuem beginnen.

Ich habe eine Bsp.tabelle angefügt.

Vielen Dank für jeden Tipp.

[BoskoBiati]

Hi,

in D2 und nach unten ziehen:

Code:

=WENN(C2="";"";MITTELWERT(B2:INDEX(B:B;AGGREGAT(15;6;ZEILE(B2:$B$50)/(C2:$C$50="");1)-1)))

[Peter]

Hallo,

wenn die Versionsangabe für die XL-Version stimmt (XP) dann geht die Formel mit Aggregat aber schief.

[BoskoBiati]

Hi Peter,

stimmt, dann eben so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	F
2

Zelle	Formel
F2	{=WENN(C2="";"";MITTELWERT(B2:INDEX(B:B;KKLEINSTE(WENN(C2:$C$30="";ZEILE(C2:$C$30));1)-1)))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Hopfenmeile]

vielen Dank,

bei mir kommt #NAME?  Fehler

[Hopfenmeile]

vielen vielen DANK!! Es geht nun, ja habe XP.

[Jonas0806]

Hallo,

nur der Vollständigkeit wegen, hier eine matrixfreie Lösung:

PHP-Code:

=WENN(C2="";"";MITTELWERT(B2:INDEX(B:B;MIN(INDEX((C2:$C$30="")*ZEILE(C2:$C$30)+(C2:$C$30<>"")*9^99;))-1))) 


[Hopfenmeile]

ich habe noch eine weitere Frage.
Ich möchte gerne den oberen Block automatisch übertragen lassen in Tabelle2 wie in der Bsptabelle.

Geht das?