Mittelwerte anhand von Werten in anderer Zelle berechnen

[Sternchen]

Hallo zusammen,

meine Tabelle über stündliche Temperaturwerte von 1991 bis 2021 hat folgendes Format:

Datum+Uhrzeit    Temperatur
1991010100         3,4
1991010101         4,4
usw.

Ich möchte anhand des Monats im Datum Mittelwerte der Temperatur über den gesamten Zeitraum für Frühjahr (März-Mai), Sommer (Juni-August), Herbst (September-November) und Winter (Dezember-Februar) berechnen. Herauskommen sollten also am Ende 4 Werte.

Kann da jemand weiterhelfen?
Vielen Dank schonmal.
Grüße

[Stoffo]

Moin,

du könntest dir mit =Teil(A1;5;2) in einer Hilfsspalte die Monate auswerfen lassen und dann mittels wenn Funktion mittelwerte bilden lassen.

[LCohen]

C2: =LET(x;MONATSENDE(TEXT(A2;"0000""-""00""-""00 00:");-2);DATUM(JAHR(x);MONAT(MONAT(x)&0)*3;1)) 

und dann Pivot 

• Vorspalte C und 
  
• Werte B als Mittelwert.
  

Hier auch für älteres Excel:
C2: =DATUM(JAHR(
MONATSENDE(TEXT(A2;"0000""-""00""-""00 00:");-2));MONAT(MONAT(
MONATSENDE(TEXT(A2;"0000""-""00""-""00 00:");-2))&0)*3;1))

Frühjahr = 3
Sommer = 6
Herbst = 9
Winter = 12

entspricht dem jeweils ersten Monat der Jahreszeit. Jan+Feb 1991 ergibt Winter 1990!

[Sternchen]

Danke dafür.
Könntest du mir noch mit der Wenn-Funktion helfen. Ich bin leider nicht so fit in Excel.

[Stoffo]

Moin,
s.o.

[LCohen]

=MITTELWERT(SUMMEWENN(x;y;z)) ist ja auch etwas ganz anderes als =SUMMEWENN(x;y;z), stoffo. Oder?

Man sollte immer selbst Daten verwenden, statt sich nur eine Formel auszudenken.

[BoskoBiati]

Hi,

als einfache Variante:

A enthält Datumswerte, B die Temperaturen.
Hilfsspalte C mit folgender Formel, vom ersten bis zum letzten Wert:

Code:

=REST(MONAT(TEIL(A1;5;2)+1&0)+2;4)+1

In D:

Code:

=MITTELWERTWENN(C:C;ZEILE(A1);B:B)

nach unten ziehen, bis insgesamt in 4Zeilen die Formel steht.

[LCohen]

Stimmt, so war auch die Anforderung des TE.

Wenn ich aber die Mittelwerte der 4 Quartale jahresweise vergleichen möchte, wäre die Pivottabelle eine schöne Sache.

[Sternchen]

Danke für die Hilfe!
Hab es jetzt mit der Teil-Funktion und einer Pivot-Tabelle gelöst.
Grüße