Mittelwert unter zwei Bedingungen

[Joerg_de]

Hallo,

ich weiß, es ist lange her, aber vielleicht kann sich noch jemand erinnern an das alte Office 2003 und hier an die Formel in E33
=MITTELWERT(WENN(E3:E26<0;E3:E26))

Da wird also jetzt der Mittelwert berechnet nur der negativen Zahlen in Spalte E - alle anderen bleiben unberücksichtigt.

Wenn jetzt als weitere Einschränkung gefordert wird, dass in Spalte D der Wert größer als 10,0 ist, wie setze ich das um?

=MITTELWERT(WENN(UND(E3:E26<0;D3:D26>10);E3:E26))
in G33 liefert mir 0,0 als Ergebnis und ich frage mich, was da nicht stimmt.

Danke, und

schönen Gruß
Jörg

[steve1da]

Hola,
in Matrixformeln ist das UND ein *.
=MITTELWERT(WENN((E3:E26<0)*(D3:D26>10);E3:E26))
Gruß,
steve1da

[slowboarder]

Hi

UND und ODER sind in Excel Auswertefunktionen vergleichbar mit Summe, Summenprodukt, Min, Max usw

Dh in einer Matrix angewendet, liefern sie einen einzigen Ergebniswert.

Wenn du jedoch für jeden Matrixwert ein eigenes Ergebnis haben willst, musst du einen Einzelwert-Operator (+-*/) anwenden.
Für UND und ODER gibt es so einen Operator nicht, aber man kann alternativ die Rechenoperationen * für UND und + für ODER verwenden, weil Wahrheitswerte in Berechnung äquivalent 0 (Falsch) und 1 (wahr) sind.

Die daraus resultierende Formel hat dir SF gezeigt.

Alternativ kann man für eine UND-Verknüpfung auch mehrere Wenn kombinieren:

=Mittelwert(Wenn(E3:E26<0;Wenn(D3:D26>10;E3:E26)))

Gruß Daniel

[Joerg_de]

Vielen Dank!

---

Hallo,

das ist ja interessant, dass
=MITTELWERT(WENN(E3:E26<0;WENN(D3:D26>10;E3:E26)))
genau das gleiche liefert wie
=MITTELWERT(WENN((E3:E26<0)*(D3:D26>10);E3:E26))

Da kann man also seinen pers. Geschmack ein bisschen mit berücksichtigen - mich hatte das "*" irgendwie immer etwas gestört [oder besser "verwirrt"], aber ich kannte ja auch den Zusammenhang bisher nicht. 

Vielen Dank!