Mit INDEX den Durchschnitt aus den letzten 10 Werten ermitteln

[NoName]

Hallo clever-excel-forum Mitglieder,

generell hatte und habe ich das Problem aus einer Reihe von Zahlen, die auch Platzhalter mit Text beinhalten einen Durchschnitt zu ziehen.
Ich habe natürlich Google an gemacht und hier mal im Forum geschaut ob jemand schon mal so ein Problem hatte.
Bin auf die Formel 1 gestoßen, diese funktioniert so wie ich es möchte nur “falsch herum“. (siehe Excel)
 
Für meine Auswertung meiner Excel benötige ich diese Formel (Formel 1) einmal gedreht, so dass Sie nicht mehr von oben nach unten arbeitet, sondern von unten nach oben.
Sofern es nicht möglich diese Formel 1 einmal zu “drehen“ gibt es eine andere Forme?
 
Formel 1:

Code:

{=WENN((B5="")+(ANZAHL(B$5:B5)<$E$1);"";MITTELWERT(INDEX(INDEX(B:B;MAX(1;KGRÖSSTE(WENN(ISTZAHL(B$5:B5);ZEILE($5:5));MIN(ANZAHL(B$5:B5);$E$1)))):B5;)))}

Hinweis: die geschweiften Klammern können durch: STRG + Shift + Enter eingefügt werden.
 
Sofern Unklarheiten bestehen umgehend Melden.
 
Mit freundlichen Grüßen
Johannes Arends

[GMG-CC]

Moin Johannes Arends,
bist du beim Bund oder Ausbilder oder ähnlich? (-> Dem Satz "Sofern Unklarheiten bestehen umgehend Melden." täte das Wörtchen "bitte" ganz gut und ist in Foren durchaus Usus und hilfreich. Und den Helfern brauchst du nun wirklich nicht zu erzählen, dass die geschweiften Klammern nicht direkt eingegeben werden müssen ...)

Mit der Formel zeigst du ja, dass du dich schon bemüht hast.   Mir ist es zu umständlich, solch ein Teil zu analysieren um dann doch zur falschen Schlussfolgerung zu gelangen. Wenn du von den niedrigsten 10 Werten den Mittelwert haben willst, dann kommt 1,4 heraus. Solch ein Wunsch-Ergebnis hätte ich mir gewünscht, oder mit entsprechender Beschreibung (beispielsweise "die 10 zuletzt eingegebenen numerischen Werte, wäre 4,3) die andere Zahl. Bei 10 Werten sollte das nicht so problematisch sein, die von Hand zu berechnen ...

Überhaupt nicht erkannt habe ich, warum mehrere Ergebnisse (Spalte_H) ... (ja, ich weiß, ich sollte die Formel analysieren. Aber Formeln mit >50 Zeichen sind für mich ein Gräuel...)

[shift-del]

@Günther
Zu Sätzen wie "Sofern Unklarheiten bestehen umgehend Melden." hatte ich mich gestern schon mal geäußert.
Das Forum ist kein Quiz in dem die Helfer die Fragen stellen.

@Johannes

Code:

=WENNFEHLER(MITTELWERT(B5:INDEX(B:B;AGGREGAT(15;6;ZEILE(B5:B$56)/ISTZAHL(B5:B$56);$E$1)));"")

[NoName]

Hallo Günther,
danke für deine Rückmeldung. :28:
Es sollte auf keinen Fall unfreundlich wirken ohne Bitte. Dieses habe ich nun verbessert. – Danke für den Hinweis.

Ja, ich habe mir schon einige Gedanken selbst gemacht, jedoch bei 2 ineinander arbeitenden INDEXen bin ich raus.

Ich möchte - um es noch mal zu konkretisieren fortlaufend aus den letzten X (10) numerischen Werten den Mittelwert bestimmen. 
Ich möchte nicht die 10 niedrigsten Werte, sondern einen normalen Mittelwert. Um die Unklarheiten mit den mehrere Ergebnissen (Spalte H) zu beseitigen 
habe ich nun noch mal die Spalten beschrieben und ihren Inhalt. (siehe oben)

Ich habe hier ein Beispiel aufgeführt. In meiner richtigen Excel geht es um 4072 Werte die Täglich um 7 Werte wachsen.
Dort ist eine Berechnung von Hand hoch Fehler anfällig, nicht variabel und kostet nur unnötig Zeit.

Mit freundlichen Grüßen
Johannes Arends

[NoName]

Hallo shift-del, / @shift-del,
 
vielen Danke für deine Formel funktionier einwandfrei.  :18:
 
Gibt es eine Paypal Adresse wo ich für diese Forum Geld spenden kann? 
(Foren dieses Erlaubt ist.)
 
@Günther
Die Änderungen, die ich gerade benannt habe werde ich nicht mehr Einfügen.
Mein Thema ist nämlich danke shift-del erledigt.
 
Mit freundlichen Grüßen
Johannes Arends

[LCohen]

AGGREGAT ist zwar denkbar, aber durch den Zusatz "wächst täglich um 7 Werte" klappt das ganze auch mathematisch ab Excel 1 aus 1985 (?):

=MITTELWERT(BEREICH.VERSCHIEBEN(B$5;X$1*7;;10;))

mit 

X1: =HEUTE()-Startdatum

(hier unter Außerachtlassung von Wochenenden und anderer Korrekturfaktoren)

Eine nervige Vola-Diskussion kann natürlich jetzt noch einsetzen.

[schauan]

Hallöchen,

hier wäre mal ein variabler Ansatz für den Mittelwert der letzten 5 Zellen mit INDEX. Das berücksichtigt allerdings nicht den Anspruch der letzten 5 "numerischen Zellen"

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	9	3
2	8
3	7
4	6
5	5
6	4
7	3
8	2
9	1
10

Zelle	Formel
B1	=MITTELWERT(INDEX(A1:A10;MAX(INDEX((A1:A10<>"")*ZEILE(A1:A10);0));0):INDEX(A1:A10;MAX(INDEX((A1:A10<>"")*ZEILE(A1:A10)-4;0));0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg