Minimum, Wenn, Ausgabe von drei Zellen

[SMC]

Hallo, ihr Lieben!

Ich hänge an folgender Aufgabenstellung:

Ich habe sechs Verkäufer. Diese sechs Verkäufer schicken mir jeweils eine Preisliste mit Artikeln. Die Preisliste ist aufgeteilt in Verkäuferartikelnummer, Menge, Preis. Nicht jeder Verkäufer hat jeden Artikel, es gibt also auch einige leere Zellen.
Nun möchte ich einen Preisvergleich machen. Quasi den Minimumwert ermitteln. Soweit komme ich. Nun aber unter der Einschränkung, dass die Menge nicht leer sein darf und größer als 0 sein muss.

Soweit die Bedingung, die für euch wahrscheinlich ein Klacks ist.
Meine größte Hürde gerade: Ich möchte insgesamt drei Daten ausgegeben bekommen. Wenn quasi der günstigste Preis ermittelt ist, möchte ich den Verkäufer, die Menge und eben den Preis in einer Tabelle sehen. Geht das? Wenn ja, wie?

Vielen Dank schon jetzt für eure Mühe!

Anbei ein Bild, um es verständlicher zu machen

   

[Fred11]

Hallo SMC,

den günstigsten Preis mit MIN(WENN(…)) bzw. MINWENNS(…) ermitteln
Und dann mit INDEX/VERGLEICH zu diesem Preis die Menge und den Lieferant ermitteln.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1		günstigstes Angebot
2	Artikelnummer	Lieferant	Menge	Preis
3	12595	Verkäufer3	6	18,6
4	18136	Verkäufer5	2	1,9
5	61021	Verkäufer1	4	8

Zelle	Formel
B3	=INDEX($E$1:$O$1;VERGLEICH(D3;$F3:$P3;0))
C3	=INDEX($E3:$O3;VERGLEICH(D3;$F3:$P3;0))
D3	{=MIN(WENN(($F$2:$P$2="Preis")*($F3:$P3>0)*($E3:$O3>0);$F3:$P3))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

(Formeln nach unten ziehen; Dollarzeichen beachten)

bei deinem Office 365 sollte in D3 für den günstigsten Preis auch folgende Formel funktionieren:
=MINWENNS($F3:$P3;$F$2:$P$2;"Preis";$F3:$P3;">0";$E3:$O3;">0")

Gruß
Fred

[SMC]

Hallo Fred,

hab Tausend Dank für deine flinke und tolle Antwort. Ich hab es direkt getestet und bin nun doch noch über eine Sache gestolpert. Ich hab nämlich noch ein paar mehr Spalten in meiner Tabelle. Dachte, ich kann die Formel einfach anpassen, aber an irgendeiner Stelle hapert es dann doch. Wärst du so lieb und würdest bitte nochmal schauen? Vor Menge und Preis hab ich die Artikelnummer des Lieferanten. Dachte, das wäre hierfür nebensächlich, weil ich die an einer ganz anderen Stelle benötige. Aber...
Office 365 ist vorhanden.

Vielen Dank im Voraus!
Sarah

   

[steve1da]

Hola,

aber an irgendeiner Stelle hapert es dann doch.

was heißt das genau? Wie sieht dein Versuch aus und was passiert (oder passiert nicht)?

Gruß,
steve1da

[SMC]

Hey Steve,

schau mal in das Bild in meiner Antwort an Fred. Da wird beim zweiten Datensatz Kauderwelsch ausgegeben. Als wäre es um eine Spalte nach links verrutscht.

LG Sarah

[steve1da]

Total toll dass man auf Bildchen keine Formeln sieht....

Code:

=INDEX($E$1:$T$1;VERGLEICH(D3;G3:V3;0))

Code:

=INDEX(F3:U3;VERGLEICH(D3;G3:V3;0))

Code:

=MIN(WENN(($G$2:$V$2="preis")*(G3:V3>0)*(F2:U3>0);G3:V3))

[SMC]

Hätte ich dir auch gegeben, sorry. Habe deine Formeln eingetragen und von Verkäufer2 besteht das Problem weiterhin. Von ihm werden mir Artikelnummer statt Menge und Menge statt Preis ausgegeben, sobald die Menge "0" ist (Manchmal führen ja mehrere Verkäufer einen Artikel, wo nur in dem Moment kein Bestand vorhanden ist).

[steve1da]

Auf die Schnelle:
=WENNFEHLER(INDEX($E$1:$T$1;VERGLEICH(D3;G3:V3;0));"")
=WENNFEHLER(INDEX(F3:U3;VERGLEICH(D3;G3:V3;0));"")
=WENN(MIN(WENN(($G$2:$V$2="preis")*(G3:V3>0)*(F3:U3>0);G3:V3))=0;"";MIN(WENN(($G$2:$V$2="preis")*(G3:V3>0)*(F3:U3>0);G3:V3)))

[SMC]

Bin total beeindruckt, hab vielen Dank!!!!!!