Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Mehrstellige Zahl aus Zelle mit diversem Text extrahieren
#1
Hallo zusammen,

ich habe noch ein "Problem" an dem ich mir seit Stunden die Zähne ausbeiße.
Ich möchte aus einer Zelle, in der verschiedene Text- und Zahlenkombinationen vorkommen, eine mehrstellige Zahl extrahieren; in meinem Beispiel 7stellig.
Sollte keine 7stellige Zahl vorkommen, also mehr oder weniger Stellen oder gar keine Zahl, dann soll beispielsweise "9999999" ausgegeben werden.

In meiner Beispielmappe habe ich mein Ergebnis über Blitzvorschau (Spalte C) in Verbindung mit WENN (Spalte D) erreicht. Damit bin ich aber nicht zufrieden.
Bei den Versuchen in den Spalten F, G und H habe ich mich trotz intensiver Recherche total verlaufen. Wobei H nicht funktionieren kann, weil im Textfeld ":" nicht vorkommt.

Ich bin dankbar für jede Hilfe.

LG
derkneifel


Angehängte Dateien
.xlsx   Mappe3.xlsx (Größe: 9,89 KB / Downloads: 24)
Antworten Top
#2
Hi,

teste mal - hier für eine exakt 7-stellige Zahl (also auch keine 8-stellige):

=ANZAHL(--TEIL(WECHSELN(A1&" ";" ";"#");ZEILE($1:$100);7))*(ANZAHL(--TEIL(WECHSELN(A1&" ";" ";"#");ZEILE($1:$100);8))=0)

Ergebnis 1 (wahr) oder 0 (falsch).

Für max. 100 Zeichen pro Zelle. Bei Bedarf ZEILE($1:$100) erweitern.
Antworten Top
#3
Hi,

z.B. so:

Code:
=LET(a;VERWEIS(9^99;1*TEIL(A1;MIN(WENN(ISTZAHL(1*TEIL(A1;SPALTE(1:1);1));SPALTE(1:1)));SPALTE(1:1)));b;VERWEIS(8^88;1*RECHTS(A1;SPALTE(A1:Z1)));c;LÄNGE(a);d;LÄNGE(b);WENNFEHLER(WENN(c=7;a;WENN(d=7;b;"keine 7-stellige Zahl"));"keine 7-stellige Zahl"))
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#4
Hi Edgar,

aber nicht mit der angegebenen Excelversion (2016).
Antworten Top
#5
Gibt leider immer nur 0 aus.

...okay, mit Strg+Shift+Enter werden 0 und 1 richtig ausgegeben, ich brauche aber die 7stellige Zahl.
Antworten Top
#6
Hi,

die Zahl erhältst Du (auf die Schnelle) mit:

=WENN(ANZAHL(--TEIL(WECHSELN(A1&" ";" ";"#");ZEILE($1:$100);7))*(ANZAHL(--TEIL(WECHSELN(A1&" ";" ";"#");ZEILE($1:$100);8))=0)>0;MIN(WENN(ISTZAHL(--TEIL(WECHSELN(A1&" ";" ";"#");ZEILE($1:$100);7));--TEIL(WECHSELN(A1&" ";" ";"#");ZEILE($1:$100);7)));"keine 7-stellige Zahl")
[-] Folgende(r) 1 Nutzer sagt Danke an {Boris} für diesen Beitrag:
  • derkneifel
Antworten Top
#7
Gibt leider nur "keine 7-stellige Zahl" aus.
Antworten Top
#8
Hi,

natürlich auch (in Deiner Excelversion) mit Strg+Shift+Enter abschließen.
Die Formel ist getestet.
[-] Folgende(r) 1 Nutzer sagt Danke an {Boris} für diesen Beitrag:
  • derkneifel
Antworten Top
#9
Vielen Dank, Boris.
Ist eine ganz schön große Formel für ein vermeintlich kleines Problem.
Ich werde sie wohl kopieren und anwenden/anpassen können, aber wahrscheinlich nie verstehen.
Antworten Top
#10
Etwas kürzer ... und es darf nur eine 7stellige vorhanden sein:

=SUMME(WENNFEHLER(WENN(LÄNGE(
--GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A:F)*99-98;99)))=7;
--GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A:F)*99-98;99)));))
(Strg-Umsch-Eing)

Lässt sich kürzer LETten:

=LET(x;SUMME(WENNFEHLER(--TEXTTEILEN(A1;" ");));WENN(LÄNGE(x)=7;x;))
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste