Mehrere Zahlen aus einer Zelle, die auch Text beinhaltet, addieren

[Xophia]

Hallo zusammen,

mein Problem ist Folgendes:

In einer Zelle habe ich sowohl Text als auch Zahlen. An welcher Stelle in der Zelle der Text steht und an welcher die Zahl(en) kann sich von Zelle zu Zelle unterscheiden - darauf habe ich keinen Einfluss. Ich bräuchte eine Prüfung, wieviel der Gesamtzahlwert beträgt.

Eine Beispiel-Datei habe ich angehängt. Das gewünschte / zu erwartende Ergebnis der Berechnung habe ich in Spalte C geschrieben.

Eine Sache wäre noch wichtig:
Es müsste ohne Makros umzusetzen sein.


Habt ihr vielleicht einen Lösungsvorschlag?

Ich danke euch vielmals im Voraus!

Viele Grüße
Xophia

[LCohen]

C2: 

=SUMME(WENNFEHLER(--TEIL(WECHSELN(
A2
;" ";WIEDERHOLEN(" ";99));ZEILE($1:$19)*99-98;99);0))

jedoch nur für die "Leerzeichen-umschließen-Zahlen"-Fälle 2, 3, und 6. Die restlichen sind ziemlich mühsam (als Formel für alle Fälle 2-6):

C2: 

=SUMME(WENNFEHLER(--TEIL(WECHSELN(
TEXTVERKETTEN(WENN(ISTZAHL(--TEIL(" "&A2;ZEILE($2:$99);1))+ISTZAHL(--TEIL(" "&A2;ZEILE($1:$98);1))=1;" ";"");;TEIL(" "&A2;ZEILE($1:$98);1))
;" ";WIEDERHOLEN(" ";99));ZEILE($1:$19)*99-98;99);0))

[Xophia]

Hallo LCohen,

vielen Dank für deinen Lösungsvorschlag!

Es ist, wie du sagst - deine erste Formel gibt das gewünschte Ergebnis für A2, A3 und A6 an. Deine zweite Formel funktioniert zusätzlich noch mit A4 und A5. Allerdings gibt sie bei A6 als Ergebnis "109" statt richtigerweise "100" aus. Warum ist das so?

Ich habe noch eine kleine Anmerkung - ich habe die Formeln nicht mit "ENTER" abgeschlossen, sondern mit "STRG+SHIFT+ENTER", sodass sie schlussendlich mit geschweifter Klammer umrandet wurden. Nur dann wurden die gewünschten Ergebnisse angezeigt. Als "normale" Formeln nicht.

@LCohen - könntest du bitte noch mal das falsche Ergebnis der zweiten Formel für A6 prüfen? Ich danke dir vielmals! Bis hierhin ist es jedenfalls schon echt super!

[LCohen]

C2:

=SUMME(WENNFEHLER(--TEIL(WECHSELN(TEXTVERKETTEN(WENN(
ISTZAHL(--TEIL(" "&WECHSELN(A2;",";0);ZEILE($2:$99);1))+
ISTZAHL(--TEIL(" "&WECHSELN(A2;",";0);ZEILE($1:$98);1))=1;" ";"");;TEIL(" "&A2;ZEILE($1:$98);1))
;" ";WIEDERHOLEN(" ";99));ZEILE($1:$19)*99-98;99);0))

Schön, dass Du {} selbst hinbekommen hast.

[Xophia]

Mit deiner neuen Formel in geschweiften Klammern funktioniert es wunderbar, LCohen! Vielen, vielen Dank dafür!