Median zweier Spalten

[Ego]

Hallo,

 A) @ shift-del zu:

Ich verstehe nicht was es da groß zu recherchieren gibt. ... Einfach beide Varianten probieren und die Variante nehmen die ein für dich plausibles Ergebnis liefert.

Das wird schwierig wenn man auf :

der Median bei den Minuten ist 4 und bei den Kunden ist 22, du möchtest wissen für die 22 Kunden die der Median ist welche Minuten links daneben stehen oder?

mit:

Ja genau!

antworten muss.

B) @Martin
Nach deiner ersten Beschreibung

Ich möchte nun herausfinden in wie viel Minuten (im Median) die Kunden Antwort erhalten haben.

nehme ich an, dass shift-del's Lösung noch nicht die Antwort auf deine Anfrage ist.
Sie ermittelt den Median über die auftretenden Zeitklassen und nicht, wie meines Erachtens gewünscht, den Median der Wartezeit der Kunden.

a) Median aus Originaldaten
Deine Häufigkeitstabelle kommt doch aus der Aufzeichnung der Zeiten für einzelne Kunden. Dann ist es am einfachsten den Median aus diesen Daten zu ermitteln.

b) Median aus der Häufigkeitstabelle.
Wenn die Originaldaten nicht mehr zur Verfügung stehen, wird es ein wenig aufwändiger. Hier eine Lösung mit zwei Hilfsspalten (deine Daten in A2:B10; ungetestet, da ich zur Zeit kein Excel zur Verfügung habe):
1. auflaufende Häufigkeit in Spalte C ab C2
"= C1+B2"
2. Median(-teile) in Spalte D ab D2

Code:

=(Wenn(und(C1<abrunden(($C$10+1)/2;0);C2>=abrunden(($C$10+1)/2;0));A2;0)+Wenn(und(C1<aufrunden(($C$10+1)/2;0);C2>=aufrunden(($C$10+1)/2;0));A2;0))/2

3. Median
"=Summe(D2:D10)"

[shift-del]

Hier mal zum Vergleich:

Arbeitsblatt mit dem Namen 'Tabelle1'
	C	D
1	Median aus Wertetabelle	6,5
2	Median aus Häufigkeitstabelle	6,5
3	Median mit Hilfsspalten	6,5

Zelle	Formel
D1	=MEDIAN(A2:A265)
D2	=AGGREGAT(17;6;Klassen/(SPALTE(1:1)<=Häufigkeiten);2)
D3	=SUMME(I2:I10)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Cadmus]

Als Alternative mit wenigen Klicks eine Pivot Table fertigen. Den Minutenbereich kannst du ggf. z.B. in 10er Schritte gruppieren.

[shift-del]

@Cadmus
Wo ist da jetzt der Median?

[Cadmus]

Wenn der "Chef" nun herausbekommen möchte wieviele Minuten der Median aller Kunden Antwort erhalte hat.... was müsste er in Excel tun.... hoffe dass es nun verständlicher ist ??

Wenn ich die Frage des Chefs richtig auslege, würde ich dem Chef sagen, dass nach ca. 6 Minuten die Hälte der Anfragen erledigt ist.

[LCohen]

Komisch, manchmal häuft sich die Frage nach genau einer Sache urplötzlich, so über alle Foren nach dem MEDIAN.

---

Nimmt man dort in D1: 0,5, ergibt sich mit den Daten dieses Threads in A2[:B10]: 7 aus der dort erwähnten Formel von neopa

=MAX(INDEX(D1>A2:A99*(SUMMEWENN(A2:A99;"<="&A2:A99;B1:B98)/SUMME(B2:B99));))

(was im allgemeinen ausreicht, da man in der Realität die doch sehr zufällige bzw. konstruierte, aber der Ordnung halber notwendige akademische Mittlung unterlässt. Kontrolle: bei D1: 0,499 ergibt sich 6).

Sie benötigt dabei keine Hilfsspalte und keinen {}-Abschluss und klappt auch vor Excel 2010.

---

shift-del's "2. Quartil"-Formel: 

=AGGREGAT(17;6;A2:A99/(SPALTE(1:1)<=B2:B99);2) 

ist statistisch korrekt: 6,5. Ein schönes Beispiel für die Verkürzungs-Power von AGGREGAT! Mal sehen, ob WF es aufnimmt.

---

Für frei wählbares QUANTIL statt QUARTIL klappt:

=AGGREGAT(16;6;A2:A99/(SPALTE(1:1)<=B2:B99);D1) (zur Erinnerung D1: 0,5)

welches somit mit der neopa-Formel gleichzieht. 

---

Nachteil von AGGREGAT ggü der neopa-Formel:

=AGGREGAT(16;6;A2:A99/(SPALTE(A1:CJ1)<=B2:B99);0,5) ergibt noch 6,5
=AGGREGAT(16;6;A2:A99/(SPALTE(A1:CI1)<=B2:B99);0,5) ergibt nur 6

Erläuterung: Der höchste Wert in B:B (Klassenhäufigkeit) ist 88, was =SPALTEN(A1:CJ1) entspricht. 
Umkehrschluss: Somit darf keine einzelne Klassenhäufigkeit größer als 16384: =SPALTE(1:1) sein.

[Moppeldi]

Ich wollte mich herzlich für die Hilfe auf verschiedenen Wegen bedanken!