Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Maximal einmal zählen trotz mehreren gesuchten Wörtern in einer Zelle
#1
Smile 
Hallo zusammen,

ich bin aktuell dabei für meinen Job als Sifa Unfallzahlen aus unserem Verbandbuch auszuwerten und diese möglichst in Diagrammen darzustellen. Dabei bin ich auf ein Hindernis gestoßen, welches ich bisher noch nicht überwinden konnte.
Vielleicht kann mir da jemand von euch Excel Genies helfen.
Ich bekomme sehr umfangreiche Daten in einer Zelle übermittelt und möchte nun nach Körperteilen zählen. 
Ich möchte aber nicht ganz so detailliert zählen wie mir die Daten übermittelt werden, sondern zusammenfassen, damit es übersichtlich bleibt. Zum Beispiel Oberschenkel, Knie und Schienbein als "Bein". Nachfolgend ein Beispiel wie die Zelle gefüllt sein kann.

offene Wunde (Riss-, Schuerf-, Platzwunde, etc.), Schienbein, links|offene Wunde (Riss-, Schuerf-, Platzwunde, etc.), Knie, links|offene Wunde (Riss-, Schuerf-, Platzwunde, etc.), Arm, links

Um mir nun aus allen Einträgen die Beinverletzungen zu Zählen habe ich folgende Formel genutzt.

=ZÄHLENWENN('Daten FLW'!$G$2:$G$767;"*Bein*")+ZÄHLENWENN('Daten FLW'!$G$2:$G$767;"*Knie*")+ZÄHLENWENN('Daten FLW'!$G$2:$G$767;"*Schenkel*")+ZÄHLENWENN('Daten FLW'!$G$2:$G$767;"*Wade*")+ZÄHLENWENN('Daten FLW'!$G$2:$G$767;"*Hüfte*")+ZÄHLENWENN('Daten FLW'!$G$2:$G$767;"*Becken*")

Mein Problem ist nun folgendes. Mit meiner Formel zählt er den obenstehenden Eintrag als 2, weil dort "Bein" und "Knie" vorkommt. Ich möchte aber gern, dass dies nur als 1 gezählt wird. Ist das machbar?

Beste Grüße
Antworten Top
#2
Hi,

z.B.:

=SUMME(NACHZEILE('Daten FLW'!$G$2:$G$767;LAMBDA(a;--(SUMME(ZÄHLENWENN(a;"*"&{"Bein"."Knie"."Schenkel"."Wade"."Hüfte"."Becken"}&"*"))>0))))
Antworten Top
#3
Hallo,

neben der Lösung von {Boris} (er war schneller) eine weitere Möglichkeit mit MAP und SUCHEN ...

PHP-Code:
=LET(Suchbegriffe;$U$3:$U$6;Werte;$B$3:$B$7;SUMME(NACHZEILE(Werte;LAMBDA(A;WENN(SUMME(MAP(Suchbegriffe;LAMBDA(V;WENNFEHLER(SUCHEN(V;A);0))))>0;1;0))))) 

wo dann in U3:U6 die Begriffe Bein, Knie, usw. drin stehen und B3:B7 die Werte, bei Dir 'Daten FLW'!$G$2:$G$767

Gru0
Microsoft Excel Expert · Microsoft Most Valuable Professional (MVP) :: 2011-2019 & 2020-2022 :: 10 Awards
https://de.excel-translator.de/translator :: Online Excel-Formel-Übersetzer :: Funktionen :: Fehlerwerte :: Argumente :: Tabellenbezeichner
Antworten Top
#4
Hallo Boris, hallo Maninweb,

vielen Dank für eure schnelle Antwort. Bekomme die Formel aber leider nicht zum Laufen.
Es wird mir die ganze Zeit #NAME? angezeigt. Habe dann nach einigem Stöbern auch herausgefunden, warum dem so ist.
Ich habe nämlich nicht, wie zuerst angenommen, Office 365 sondern nur Office 2016   33
Muss ich gleich mal im Profil anpassen. 

Habt ihr dafür auch eventuell eine Lösung?

Beste Grüße
Antworten Top
#5
Hi,

die Auslagerung der Suchbegriffe (außerhalb der Formel) ist prinzipiell immer eine gute Idee (wie von Mourad praktiziert), da man bei geänderten Anforderungen nicht in der Formel selbst rumfummeln muss.

Und da "Platz zu sparen", kann man die aber auch in EINE Zelle schreiben - mit einem eindeutigen Trennzeichen.

Im Beispiel steht in der Zelle P1:

Bein,Knie,Schenkel,Wade,Hüfte,Becken

Dazu dann diese Formel:

=SUMME(NACHZEILE('Daten FLW'!$G$2:$G$767;LAMBDA(a;--(SUMME(ZÄHLENWENN(a;"*"&TEXTTEILEN(P1;",")&"*"))>0))))

Hi,

für Excel 2016 erledige das mit einer Hilfsspalte:

=--(SUMME(ZÄHLENWENN('Daten FLW'!G2;"*"&{"Bein"."Knie"."Schenkel"."Wade"."Hüfte"."Becken"}&"*"))>0)

und 766 Zeilen runterkopieren.

Dann aus dieser Hilfsspalte einfach nur die SUMME ermitteln.
[-] Folgende(r) 1 Nutzer sagt Danke an {Boris} für diesen Beitrag:
  • VanDalen13
Antworten Top
#6
(19.06.2024, 14:08){Boris} schrieb: Hi,

die Auslagerung der Suchbegriffe (außerhalb der Formel) ist prinzipiell immer eine gute Idee (wie von Mourad praktiziert), da man bei geänderten Anforderungen nicht in der Formel selbst rumfummeln muss.

Und da "Platz zu sparen", kann man die aber auch in EINE Zelle schreiben - mit einem eindeutigen Trennzeichen.

Im Beispiel steht in der Zelle P1:

Bein,Knie,Schenkel,Wade,Hüfte,Becken

Dazu dann diese Formel:

=SUMME(NACHZEILE('Daten FLW'!$G$2:$G$767;LAMBDA(a;--(SUMME(ZÄHLENWENN(a;"*"&TEXTTEILEN(P1;",")&"*"))>0))))

Hi,

für Excel 2016 erledige das mit einer Hilfsspalte:

=--(SUMME(ZÄHLENWENN('Daten FLW'!G2;"*"&{"Bein"."Knie"."Schenkel"."Wade"."Hüfte"."Becken"}&"*"))>0)

und 766 Zeilen runterkopieren.

Dann aus dieser Hilfsspalte einfach nur die SUMME ermitteln.
Vielen Dank,

die zweite Lösung funktioniert und reicht mir völlig aus.  23
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste