Matrixbildung deaktivieren

[schauan]

Hallöchen,

kann man eigentlich die Matrixbildung bei Formeleingabe deaktivieren?

Wenn ich hier die Formel normal eingebe, bildet mir Excel eine Matrix von H1 bis H4.
Das gewünschte Ergebnis in Spalte F bekomme ich nur, wenn ich die Formel mit STRG-Shift-Enter abschließe. Geht das auch anders?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H
1	A1	B1	C1	D1		A1B1		A1B1
2	A2	B2	C2	D2		B1C1		A2B2
3	A3	B3	C3	D3		C1D1		A3B3
4	A4	B4	C4	D4		D1A1		A4B4

Zelle	Formel
F1	{=INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE();-4)))&INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE(A2);-4)))}
H1	=INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE();-4)))&INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE(A2);-4)))
F2	{=INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE();-4)))&INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE(A3);-4)))}
F3	{=INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE();-4)))&INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE(A4);-4)))}
F4	{=INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE();-4)))&INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE(A5);-4)))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

[{Boris}]

Hi André,

das hast Du schon richtig gemacht, den Spill mit Strg+Shift+Enter zu unterdrücken.
Andernfalls musst Du den jeweils ersten Eintrag aus dem Spill mit einem zusätzlichen INDEX auslesen:

H1:
=INDEX(INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE();-4)));1)&INDEX(INDEX($A$1:$D$4;ZEILE()/4;4-ABS(REST(ZEILE(A2);-4)));1)
und runterkopieren.

Das "Problem" in Deiner Formel ist ZEILE()/4 - denn sobald da beim Ergebnis noch eine 0 vor dem Komma steht, wird die Null als Zeilenindex an INDEX übergeben - und somit bekommst Du jeweils 4 Werte geliefert, die in xl365 gespillt werden, vorher eben nicht (da wird der erste Wert genommen).

[schauan]

Hi Boris,

dankeschön, wieder was dazu gelernt

[maninweb]

Hallo,

das Überlaufen der Formel in F1 kannst Du in diesem Fall auch mit dem @-Zeichen  (=@INDEX...&@INDEX...) durch Verwenden der impliziten
Schnittmenge unterdrücken. Allerdings ist das ggf. inkompatibel mit älteren Excel-Versionen. Von daher ist die Lösung von Boris geeigneter.

Gruß