Liste für Abrechnung

[Babette]

Hallo,
freue mich erst mal, dass ich hier vielleicht Hilfe bekommen kann.  
Also ich habe eine Liste erstellt, die jetzt schon jahrelang funktionierte. Jetzt ist leider eine dritte Option hinzugekommen - das bekomme ich igw. nicht hin.

Hier die jetzige Formel:

=WENN(L35="x";
WENN($I35=1;WENN($D35>($B$25);$B$2;$BC$2);
WENN($I35=3;WENN($D35>($J$25);$J$2;$BG$2);
WENN($I35=4;WENN($D35>($N$25);$L$2;$BJ$2))));)

umgesetzt:

=WENN(L35="x";
WENN($I35=1;WENN(Datum>(Datum);Preis;Preis);
WENN($I35=3;WENN(Datum>(Datum);Preis;Preis);
WENN($I35=4;WENN(Datum>(Dautum;Preis;Preis))));)

Jetzt kommt noch ein drittes Datum und ein dritter Preis ins Spiel, da sich die Preise dann wieder ändern.

Reicht diese Information um mir zu helfen?

Liebe Grüße
Babette

[BoskoBiati]

Hi,

ich glaube, da wäre eine Datei hilfreich, da die Formel sehr undurchsichtig und wohl eher unausgegoren ist. Keine Ausrede wegen snsibler Daten, die kann man durch Spieldaten ersetzen.

Hier mal eine Formel mit gleichem Ergebnis:

Code:

=WENN((L35="x")*(ODER(I35={1;3;4}));WENN(D35>INDEX(25:25;VERWEIS(I35;{1;3;4};{2;10;14}));INDEX(2:2;VERWEIS(I35;{1;3;4};{2;10;12}));INDEX(2:2;VERWEIS(I35;{1;3;4};{55;59;62})));)

[Babette]

Gerne, hier die Excelliste...
ich hoffe ihr blickt da durch

[shift-del]

Moin Babette

Alles auf ein Blatt. Ehemaliger Multiplan-Nutzer?

[Babette]

Also, die Liste ist vor ca. 28 Jahren entstanden. Ich hatte keine Ahnung von Excel, musste aber eine Liste erstellen. So, jetzt ist einige Zeit vergangen und ich muss Änderungen vornehmen... Die fallen mit jetzt noch schwerer. Ich nehme gerne Anregungen für Änderungen entgegen. Ob ich das dann umsetzen kann, weiß ich nicht.

[Babette]

Hallo BoskoBiati,
deine Formel funktioniert  

Leider verstehe ich sie nicht. Würde aber gerne wissen, was ich da mache.... Kannst du mir das mit Index, Verweis und so erklären. Kann ja sein, dass ich die mal verändern muss und dann geht nix mehr...

[LCohen]

Da sie ja das tut, was Deine eigene Formel auch tut, erklärt sie sich doch von allein.

Es ist aber immer ganz sinnvoll (als Helfer), Formeln so zu posten, dass man eine Regelmäßigkeit entdeckt (ich habe inhaltlich nicht geprüft oder optimiert):

=WENN((L35="x")*(ODER(I35={1;3;4}));
WENN(D35>
INDEX(25:25;VERWEIS(I35;{1;3;4};{02;10;14}));
INDEX(02:02;VERWEIS(I35;{1;3;4};{02;10;12}));
INDEX(02:02;VERWEIS(I35;{1;3;4};{55;59;62})))
;)

[BoskoBiati]

Hi,

da I35 nur die Werte 1, 3 und 4 annehmen kann, geht es auch einfacher:

Code:

=WENN((L35="x");WENN(D35>INDEX(25:25;VERWEIS(I35;{1;3;4};{2;10;14}));INDEX(2:2;VERWEIS(I35;{1;3;4};{2;10;12}));INDEX(2:2;VERWEIS(I35;{1;3;4};{55;59;62})));)

Allerdings würde ich empfehlen, die Zeilen 1 bis 27 in ein separates Blatt zu stellen, es ist nicht unbedingt sinnvoll, erst einmal 30 fixierte Zeilen zu haben, bevor die Tabelle kommt, mit der man arbeitet.
Eine Neuordnung des Aufbaus der Zeilen 1 bis 27 wäre ggf. auch von Vorteil, da man manche Formeln vereinfachen könnte.

=SUMME(D38-C38) ist Unfug.
Die Formel für die Zahl bei der Krankenkasse geht auch vieeel einfacher:

Code:

=(H29="pbk")*4+(H29="bg")*3+ODER(H29={"aok";"bek";"bkk";"gek";"dak";"ikk";"tkk";"kkh";"hkk";"big";"bw";"LKK";"kn"})

Was soll das werden:

Code:

=SUMME(BG29*BK29)*RUNDEN(1;2)

Ich könnte mir eher das vorstellen:

Code:

= RUNDEN(BG29*BK29;2)

[Babette]

Hey, ich noch mal....

habe das alles ziemlich verstanden nur das mit dem Eintrag
2;10;14
2;10;12
55;59;62
nicht.
Sind das die Spalten die du in Zahlen umgewandelt hast also A bis BW oder was sollen die bedeuten?

=WENN((L37="x")*(ODER(I37={1;3;4}));WENN(D37>INDEX(25:25;
VERWEIS(I37;{1;3;4};{2;10;14}));INDEX(2:2;
VERWEIS(I37;{1;3;4};{2;10;12}));INDEX(2:2;
VERWEIS(I37;{1;3;4};{55;59;62})));)

[BoskoBiati]

Hi,

Das sind alles Spaltennummern.

Was ich nicht verstehe ist das:

Code:

=WENN(P29="x";WENN(I29=1;WENN(D29<DATUM($B$25;$B$26;$B$27);$B$3;$BC$3);WENN(I29=2;WENN(D29<DATUM($H$25;$H$26;$H$27);$H$3;$BE$3);WENN(I29=3;WENN(D29<DATUM($J$25;$J$26;$J$27);$J$3;$BG$3);WENN(I29=7;WENN(D29<DATUM($N$25;$L$26;$L$27);$K$3;$BI$3);WENN(I29=4;WENN(D29<DATUM($K$25;$K$26;$K$27);$L$3;$BJ$3))))));)

I kann doch nur 1, 3 oder 4 sein. Wieso prüfst Du auf  2 und 7?


Ich habe einige der Formeln in den Zeilen 29 und 30 mal so geändert, wie sie in Excel sein sollten:


  Mappe1_20230215.xlsx (Größe: 273,52 KB / Downloads: 5)