Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Letzter Tag X im Monat
#1
Hallo zusammen,

ich suche eine Formel, die anhand des Jahres (C4) und dem gewünschten Tag (C5) immer den letzten Tag im Monat raussucht.
Das soll dann wie im Beispiel aussehen.

Hat da jemand eine Idee und kann mir helfen?
Ich versteh das nicht.

VG
Meliodas.



.xlsx   Excelforum.xlsx (Größe: 8,31 KB / Downloads: 17)
Antworten Top
#2
Hola,
direkt der erste Treffer bei Google für
Excel letzter Sonntag im Monat
https://www.herber.de/forum/archiv/1176t...Monat.html
Gruß,
steve1da
Antworten Top
#3
Hi,

=LET(a;DATUM(C4;SEQUENZ(12)+1;0);b;XVERGLEICH(C5;TEXT(SEQUENZ(7);"TTTT"));a-WOCHENTAG(a)+b)
Gruß,
Helmut

Win10 - Office365 / MacOS - Office365
Antworten Top
#4
Das wundert mich aber, HKindler, wo wir es doch jetzt besser wissen!

=ARBEITSTAG.INTL(MONATSENDE(A1;0)+1;-1;"1111110")

C4 und C5 habe ich mir dort oben geschenkt. Hier für 12 Monate (Jahr in C4), alternativ:

=ARBEITSTAG.INTL(MONATSENDE(ZEILE($1:$12)&-C4;0)+1;-1;"1111110")
=ARBEITSTAG.INTL(DATUM(C4;ZEILE($2:$13);1);-1;"1111110")


Und "Sonntag" ist für C5 eine ganz eklige Angabe, die man sowieso nicht verwendet. Lieber 0 bis 6 (Sa-Fr), als Ergebnis via REST statt WOCHENTAG (eine überflüssige Excelfunktion):

=ARBEITSTAG.INTL(DATUM(C4;ZEILE($2:$13);1);-1;ERSETZEN(1111111;REST(C5-2;7)+1;1;0))

Kürzer als LET und AntikExcelfähig. 5 statt 7 Fkt.
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top
#5
@LC

PHP-Code:
=NETWORKDAYS.INTL(EOMONTH(A1;0)+1;-1;"1111110"
Ergibt hier (E2010) nur #NUM


Das zweite Argument in Networkdays.intl sollte hier ein Datum sein

Code:
=NETWORKDAYS.INTL(EOMONTH(A1;0)+1; EOMONTH(A1;1);"1111110")
Zum übersetzen von Excel Formeln:

http://dolf.trieschnigg.nl/excel/index.p...gids=en+de
Antworten Top
#6
Ich verwende A1: Datum und C4: Jahr.
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top
#7
Und vor allem wird WORKDAY und nicht NETWORKDAYS verwendet.
Und SCNR, @snb:
Zum übersetzen von Excel Formeln:

http://dolf.trieschnigg.nl/excel/index.p...gids=en+de
Gib einem Mann einen Fisch und du ernährst ihn für einen Tag. 
Lehre einen Mann zu fischen und du ernährst ihn für sein Leben. (Konfuzius)
Antworten Top
#8
@RPP

Danke, wenn man nicht gut liest (wie ich in deisem Fall) hilft auch ein 'Translator' wenig.
Ich bin wieder da.
Zum übersetzen von Excel Formeln:

http://dolf.trieschnigg.nl/excel/index.p...gids=en+de
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste