LET-Funktion

[Charly CNX]

Hallo in die Runde
Ich schaffe es nicht die Formel aus Zelle N3 in die LET-Funktion Zelle O3 zu integrieren.
Könnt ihr mir bitte helfen?
VG Charly

[{Boris}]

Hi,

RANG.GLEICH braucht zwingend einen Bezug und kann mit Arrays nicht umgehen.
Du könntest nur die RANG-Formel mit dem Spill-Bereich dynamisieren. INDEX(O3#;;2) liefert dabei den benötigten Datentyp "Bezug".

=RANG.GLEICH(INDEX(O3#;;2);INDEX(O3#;;2);1)

---

Hi,

alternativ zu RANG.GLEICH kannst Du VERGLEICH verwenden. Da sind Arrays kein Problem.
Somit in die LET-Formel eingebaut:

=LET(
x;Spieltag_1[Mannschaft];
y;SORTIEREN(--TEXTNACH(Spieltag_1[Tore];":"));
Rng;VERGLEICH(y;y;0);
HSTAPELN(Rng;x;y))

[Charly CNX]

Hi Boris,
danke für die Antwort.
Da hab ich die Hilfe falsch interpretiert.
Kein Problem, ist eh nur ne Spielerei.
VG Charly

---

Das hilft weiter Boris.
Ich danke dir.
VG Charly

[{Boris}]

Hi,

nur der Vollständigkeit halber: Die Formel war noch nicht korrekt.
So ist es richtig:

=LET(
x;Spieltag_1[Mannschaft];
y;--TEXTNACH(Spieltag_1[Tore];":");
Rng;VERGLEICH(y;SORTIEREN(y);0);
SORTIEREN(HSTAPELN(Rng;x;y);3))