[LAMBDA] Ostern "extended"

[RPP63]

Vorweg:
Osterformeln für Excel gibt es zuhauf.
Grundlage dieses Blogs sind:

• Excelformeln
  
• MVP Mourad Louha (maninweb) [LAMBDA]
  

Beide beziehen sich auf Gauß.
Obwohl Gauß Namenspatron meiner Schule ist, war er hier nicht fehlerfrei. 
Ich beziehe mich daher hier auf die Ergänzung der Osterformel von Lichtenberg
(die mit 10 Variablen im Gleichungssystem umfangreicher ist)

Excelformeln berücksichtigt die Anzeige des Osterdatums vor 1900 als Text, liefert aber vor der Kalenderreform falsche Ergebnisse.
Daher wechsele ich vor 1583 auf den julianischen Kalender.

Genug der Vorrede.
Formeln ► Namensmanager ► Neu
Name: Ostern
Kommentar: Datum des Ostersonntags anhand eines Jahres (vor 1900 als Text)
Bezieht sich auf:

=LAMBDA(Jahr;
LET(A;GANZZAHL(Jahr/100);
    B;15+GANZZAHL((3*A+3)/4)-GANZZAHL((8*A+13)/25);
    C;2-GANZZAHL((3*A+3)/4);
    D;REST(Jahr;19);
    E;REST(19*D+B;30);
    F;GANZZAHL((E+GANZZAHL(D/11))/29);
    G;21+E-F;
    H;7-REST(Jahr+GANZZAHL(Jahr/4)+C;7);
    I;7-REST(G-H;7);
    OS;G+I;
    OS_Jul;OS-GANZZAHL(Jahr/100)+GANZZAHL(Jahr/400)+2;
    K;WENN(Jahr<1583;TEXT(WENN(OS_Jul-31 < 1;OS_Jul;OS_Jul-31);"0#")&"."&WENN(OS_Jul > 31;"04.";"03.")&Jahr;
            WENN(Jahr<1900;TEXT(WENN(OS-31 < 1;OS;OS-31);"0#")&"."&WENN(OS > 31;"04.";"03.")&Jahr;
                DATUM(Jahr;3;OS)));K))

Ergibt:

	A	B
1	1875	28.03.1875
2	2021	04.04.2021
3	1452	09.04.1452
4	1981	19.04.1981

Name

Bezug

Ostern

=LAMBDA(Jahr;  LET(A;GANZZAHL(Jahr/100);  B;15+GANZZAHL((3*A+3)/4)-GANZZAHL((8*A+13)/25);  C;2-GANZZAHL((3*A+3)/4);  D;REST(Jahr;19);  E;REST(19*D+B;30);  F;GANZZAHL((E+GANZZAHL(D/11))/29);  G;21+E-F;  H;7-REST(Jahr+GANZZAHL(Jahr/4)+C;7);  I;7-REST(G-H;7);  OS;G+I;  OS_Jul;OS-GANZZAHL(Jahr/100)+GANZZAHL(Jahr/400)+2;  K;WENN(Jahr<1583;TEXT(WENN(OS_Jul-31 < 1;OS_Jul;OS_Jul-31);"0#")&"."&WENN(OS_Jul > 31;"04.";"03.")&Jahr;    WENN(Jahr<1900;TEXT(WENN(OS-31 < 1;OS;OS-31);"0#")&"."&WENN(OS > 31;"04.";"03.")&Jahr;      DATUM(Jahr;3;OS)));K))

Zelle	Formel
B1	=Ostern(A1:A4)

Wer es für 1452 nachrecherchieren will:
Die geläufigen Algorithmen im Netz berücksichtigen nicht die Kalenderreform.
Ich fand für Ostern am 9.4.1452 dies:
http://matrikel.uni-rostock.de/periode/1452Ost
(dort Zeitraum von Ostern bis Michaelis)

Gruß Ralf