Kontoauszug aus anderen Tabellen erstellen

[ninchje87]

Hallo zusammen,

vielleicht findet sich hier nochmal jemand der mir helfen kann. 
Ich hänge die Datei an.
Ich hätte gerne für jedes Kind einen Kontoauszug, wie in der Datei dargestellt. 
Hier sollte, wenn möglich, die Daten aus der ersten Tabelle automatisch übernommen werden, wenn dort etwas eingetragen wird. 
Kann mir jemand sagen, wie ich das anstelle? Probiere seit Stunden rum, aber das Ergebnis ist leider nicht zufriedenstellend 

Vielen Dank und liebe Grüße

[steve1da]

Hola,
Positionen:

Code:

=WENNFEHLER(INDEX(Tabelle1!$C$10:$C$15;AGGREGAT(15;6;ZEILE(Tabelle1!$C$10:$C$15)-9/((Tabelle1!$I$2:$AB$2=$D$7)*(Tabelle1!$I$10:$AB$15<>""));ZEILE(A1)));"")

Beträge:

Code:

=WENNFEHLER(INDEX(Tabelle1!$I$10:$AB$15;AGGREGAT(15;6;ZEILE(Tabelle1!$C$10:$C$15)-9/((Tabelle1!$I$2:$AB$2=$D$7)*(Tabelle1!$I$10:$AB$15<>""));ZEILE(A1));VERGLEICH($D$7;Tabelle1!$I$2:$AB$2;0));"")

Gruß,
steve1da

[slowboarder]

Hi

in Tabelle2!B11:
=LET(a;FILTER(Tabelle1!$I$10:$AB$54;Tabelle1!$I$2:$AB$2=$D$7);FILTER(Tabelle1!$C$10:$C$54;a<>"";""))

in Tabelle2!D11: 
=LET(a;FILTER(Tabelle1!$I$10:$AB$54;Tabelle1!$I$2:$AB$2=$D$7);FILTER(a;a<>"";""))

Gruß Daniel

[EA1950]

Hallo,

in Zelle Tabelle2!B11 (mit maximalen Resultatbereich Tabelle2!B11:D27):

PHP-Code:

=LET(
    Beträge;    Tabelle1!$I$10:$AB$54;
    Kinder;     Tabelle1!$I$2:$AB$2;
    Positionen; Tabelle1!$C$10:$C$54;
    BankDatum;  Tabelle1!$G$10:$G$54;
    KndBtr; FILTER(Beträge; Kinder = $D$7);
    FILTER(HSTAPELN(Positionen; BankDatum; KndBtr); KndBtr <> ""; {"Keine". "Bewegung". ""})
) 


und in Zelle Tabelle2!D28 (mit Resultatbereich Tabelle2!D28:D30):

PHP-Code:

=LET(
    btr; INDEX($B$11#; 0; 3);
    ein; SUMMEWENN(btr; ">0");
    aus; SUMMEWENN(btr; "<0");
    VSTAPELN(ein; aus; ein + aus)
) 


Diese 2. Formel greift auf den Resultatbereich der 1. Formel (3.Spalte) zu.