KGRÖSSTE mit WENN

[MarcXLS]

  KGRÖSSTE MIT WENN.xlsx (Größe: 14,38 KB / Downloads: 5)
Hallo Leute, ich bin noch nicht so lange mit Excel unterwegs..Heute habe mehrere Stunden erfolglos rumgebastelt mit KGRÖSSTE und WENN. Kann mir jemand helfen? Ich habe die Datei zur Illustration angehängt. Vielen Dank schon mal und ein gutes Neues Jahr! Grüsse, Marc

[shift-del]

Hallo Marc

In der Datei findet sich leider keiner deiner Formelversuche.

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D	E	F	G	H
9							RANGLISTE DEFENSIV
10	ABC	DEFENSIV	10,1%	0,101001		1	DEF	10,5%
11	DEF	DEFENSIV	10,5%	0,1050011		2	ABC	10,1%
12	GHI	ZYKLISCH	4,3%	0,0430012		3	MNO	8,5%
13	JKL	DEFENSIV	8,0%	0,0800013		4	JKL	8,0%
14	MNO	DEFENSIV	8,5%	0,0850014		5	VWX	7,0%
15	PQR	ZYKLISCH	4,7%	0,0470015
16	STU	ZYKLISCH	4,5%	0,0450016
17	VWX	DEFENSIV	7,0%	0,0700017
18	YZA	ZYKLISCH	5,1%	0,0510018

Zelle	Formel
D10	=C10+ZEILE()/10^7
G10	=WENNFEHLER(INDEX($A$10:$A$18;VERGLEICH(H10;$D$10:$D$18;0));"")
H10	{=WENNFEHLER(KGRÖSSTE(WENN($B$10:$B$18="DEFENSIV";$D$10:$D$18);ZEILEN(H$10:H10));"")}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[MarcXLS]

Hallo Marc

In der Datei findet sich leider keiner deiner Formelversuche.

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D	E	F	G	H
9							RANGLISTE DEFENSIV
10	ABC	DEFENSIV	10,1%	0,101001		1	DEF	10,5%
11	DEF	DEFENSIV	10,5%	0,1050011		2	ABC	10,1%
12	GHI	ZYKLISCH	4,3%	0,0430012		3	MNO	8,5%
13	JKL	DEFENSIV	8,0%	0,0800013		4	JKL	8,0%
14	MNO	DEFENSIV	8,5%	0,0850014		5	VWX	7,0%
15	PQR	ZYKLISCH	4,7%	0,0470015
16	STU	ZYKLISCH	4,5%	0,0450016
17	VWX	DEFENSIV	7,0%	0,0700017
18	YZA	ZYKLISCH	5,1%	0,0510018

Zelle	Formel
D10	=C10+ZEILE()/10^7
G10	=WENNFEHLER(INDEX($A$10:$A$18;VERGLEICH(H10;$D$10:$D$18;0));"")
H10	{=WENNFEHLER(KGRÖSSTE(WENN($B$10:$B$18="DEFENSIV";$D$10:$D$18);ZEILEN(H$10:H10));"")}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Hallo shift-del, danke für deine unterstützung. ich versuche das mal. grüsse, marc

[neopa]

Hallo Marc,

hier noch eine alternative Lösung  ohne Hilfsspalte und auch ohne Matrixformelabschluss mit AGGREGAT() anstelle KGRÖSSTE() :

In H10:

=WENNFEHLER(AGGREGAT(14;6;C$10:C$19/(B$10:B$19="DEFENSIV");ZEILE(A1));"")

Und in G10:

=WENN(H10="";"";INDEX(A:A;AGGREGAT(15;6;ZEILE(A$10:A$19)/(B$10:B$19="DEFENSIV")/(C$10:C$19=H10);ZÄHLENWENN(H$10:H10;H10))))


und beide Formeln nach unten kopieren