Indexformel mit Matrixwerten aus nur einer Zelle

[LB1972]

Guten Morgen zusammen,

Excel kennt bei der Indexformel die Syntax, die angesprochene Matrix als Zeichenkette zu beschreiben.

Code:

G9=INDEX({2.4.8;3.9.27;5.25.125};$D9;G$8)

Das bringt in meiner Beispieldatei mit D9=1 und G8 = 3 das richtige Ergebnis 8 (=Wert 3. Spalte @ 1.Zeile)
Wenn ich jedoch versuche, die Wertematrix {2.4.8;3.9.27;5.25.125}
in einer Zelle bereitzustellen (N7 = {2.4.8;3.9.27;5.25.125}), dann funktioniert es nicht, dass die Indexformel die dort genannten entsprechend Werte verarbeitet (siehe J9:L11)
Hat jemand einen Tipp, wie das gehen könnte?
Vielen Dank schon mal
Gruß Ludwig

[LCohen]

  LB1972_Verwendung_Index.xlsx (Größe: 10,38 KB / Downloads: 11)

[WillWissen]

Hi LCohen,

ideal! Trotz Formelauswertung bin ich aber nicht dahinter gekommen, warum der Unterstrich die Matrix berücksichtigt und nicht den Zellbezug notiert. Könntest du das eventuell erläutern? Wäre super. Danke.

[LCohen]

Das ist leider nur ein ganz fieser fauler Trick ;)

Es handelt sich um eine benannte Formel. _N7 ist also nur ein Name. Ich hätte das Ding auch Trump oder Kim nennen können.

Besonders gemein von mir: Dass ich nicht den Inhalt der Zelle N7 einfach gelöscht habe. Dann wäre es sofort aufgefallen.

Hier die Alternative ohne Namen (also so, wie TE es wollte):

J9: =--TEIL(WECHSELN(WECHSELN(WECHSELN(WECHSELN($N$7;";";".");"{";" ");"}";" ");".";WIEDERHOLEN(" ";99));($I9*3-3+J$8)*99-98;99)

[WillWissen]

Hi,

danke. Das war echt gemein :22:

[LB1972]

Hallo LCohen und WillWissen,

danke für diese Idee, die auch ich jetzt begriffen habe und deutlich besser als meine Ratlosigkeit ist.
… und jetzt kommt der undankbare Teil meiner Antwort  :
Gibt es eine Möglichkeit, die Matrix auch in einer Zelle statt in der Namensrefernz zu formulieren?
Das wäre dann doch praktischer in der Handhabung.
Gruß Ludwig

[LCohen]

Anstelle der Konstantenhinterlegung ginge aber auch 

_N7: =AUSWERTEN($N$7) 

(in einer .xlsm). Dann wird auf die Zelle zugegriffen, wie gewünscht.

EDIT: Überschneidung mit TE's Nachfrage.

[LB1972]

Hallo LCohan,
ich habe jetzt im Namensmanger "Zelle_links_auswerten" definiert:

Code:

=AUSWERTEN(INDIREKT("Z"&ZEILE()&"S"&(SPALTE()-1);FALSCH))

Die verwende ich in meinem neuen Bezug O7 (blaue Zelle die direkt rechts von meiner Eingabesteht). Wenn ich die mit der Funktionstaste F9 auswerte, erhalte die tatsächlich die angegeben Matrix. Leider kann ich sie immer noch nicht in meiner Matrixtabelle nutzen.
Wo bin ich falsch abgebogen?
Gruß Ludwig

[LCohen]

Das bringt Dir nichts, denn Du versuchst nach wie vor, die Matrix in einer Zelle abzurufen, also: aus einem "Formeltext" zu konstruieren. Also wie in Deinem Eröffnungsbeitrag.

Das geht tatsächlich nur in einem "Namen", denn nur der ist zur automatischen Matrixbildung in der Lage - und kann solche Texte interpretieren.

Falls die Ausgabe der Matrix einer Regel folgen sollte ("immer 3 Zeilen hoch!"), und die Matrixtexte direkt untereinander stehen können sollen (also 1 Zeile hoch), dann klappt der von Dir gewünschte relative Matrixbezug mit

J9: =INDEX(_N7;$I9;J$8) mit
_N7: =AUSWERTEN(INDEX($N:$N;KÜRZEN(ZEILE(N21)/3)))

definiert in J9. Achtung: Dieses Stehen in J9 ist das entscheidende Wissen beim Definieren von benannten Formeln!

[LB1972]

Hallo LCohen,

danke für deine Zeit.
Ich nehme mit, dass mein "einfach so in die Zelle schreiben"-Ansatz nicht so einfach funktioniert. Deine Vorschläge helfen mir auf alle Fälle gut weiter. Den letzten habe ich noch ein bisschen umgebaut
  LB1972_Verwendung_Index_Gute_Lösung.xlsm (Größe: 10,77 KB / Downloads: 1) und er ist jetzt ganz nah an meiner ursprünglichen Grundidee.
Danke nochmals
Gruß Ludwig