Index vergleich mit ähnlicher Schreibweise?

[Jockel]

Hallo, meinst du so..?

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D	E	F
1		Minimale	bis 300 kg	bis 500 kg	bis 1000 kg	bis 1500 kg
2	Zone 1	10,22	9,14	7,14	5,14	6,14
3	Zone 2	12,55	11,12	9,44	7,48	6,87
4	Zone 3	14,96	12,45	10,55	8,89	7,84
5	*Minimale bis 100kg. Alle weiteren je 100 kg
6
7
8	PLZ	70
9	Zone:	Zone 3
10	Gewicht:	999
11	Preis	8,89 €
12	Faktor	44,45 €
13

Zelle	Format	Wert
B1	[<=100]"Minimale";Standard	100
C1	"bis" 0 "kg"	300
D1	"bis" 0 "kg"	500
E1	"bis" 0 "kg"	1000
F1	"bis" 0 "kg"	1500
B11	#.##0,00 €	8,89
B12	#.##0,00 €	44,45
C12	#.##0,00 €
B13	#.##0,00 €

Zelle	Formel
B9	="Zone "&VERWEIS(B8;{0;20;40;70;99};{1;1;2;3;1})
B11	=SVERWEIS(B9;A2:F4;VERGLEICH(KGRÖSSTE(A1:F1;ZÄHLENWENN(A1:F1;">="&B10));A1:F1;0);0)
B12	=B11*(MIN(5;OBERGRENZE(B10;100)%))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hallo,

wie ich schon bemerkte, das ist recht einfach:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J	K
1		Minimale	bis 300 kg	bis 500 kg	bis 1000 kg	bis 1500 kg
2	Zone 1	10,22	9,14	7,14	5,14	6,14
3	Zone 2	12,55	11,12	9,44	7,48	6,87				PLZ Zonen
4	Zone 3	14,96	12,45	10,55	8,89	7,84				Zone 1	10; 20; 99
5	*Minimale bis 100kg. Alle weiteren je 100 kg									Zone 2	40; 50
6										Zone 3	70;90
7
8	PLZ	10
9	Zone:	1
10	Gewicht:	489
11	Preis/100kg	7,14 €
12	Gesamt	35,70 €

Zelle	Format	Wert
B1	[=100]"Minimale";Standard	100
C1	"bis "Standard" kg"	300
D1	"bis "Standard" kg"	500
E1	"bis "Standard" kg"	1000
F1	"bis "Standard" kg"	1500
A2	"Zone "Standard	1
A3	"Zone "Standard	2
A4	"Zone "Standard	3
B11	_-* #.##0,00 €_-;-* #.##0,00 €_-;_-* "-"?? €_-;_-@_-	7,14
B12	#.##0,00 €	35,7

Zelle	Formel
B9	=VERWEIS(B8;{0;20;40;70;99};{1;1;2;3;1})
B11	=INDEX(B2:F4;VERGLEICH(B9;$A$2:$A$4;0);VERGLEICH(B10;B1:F1;1)+(ZÄHLENWENN(C1:F1;B10)=0))
B12	=B11*AUFRUNDEN(B10%;0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Allerdings passt Dein Verweis nicht zu den Einteilungen in Plz-Gebiete!

[Jockel]

Hallo Edgar, bei unter 100 kg kommt bei dir #NV... .... und bei 100 bekomme ich ein anderes Ergebnis heraus... Das mit B12 habe ich wohl missverstanden... wenn nicht bei 5 Schluss sein soll, dann 

=B11*OBERGRENZE(B10;100)% 

[Jockel]

Hallo Edgar, noch eins: Du kannst den ersten VERGLEICH() beim INDEX() doch weglassen und stattdessen B9 schreiben... ... oder?

[BoskoBiati]

Hi Jörg,

Du hast vollkommen recht.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1		Minimale	bis 300 kg	bis 500 kg	bis 1000 kg	bis 1500 kg
2	Zone 1	10,22	9,14	7,14	5,14	6,14
3	Zone 2	12,55	11,12	9,44	7,48	6,87
4	Zone 3	14,96	12,45	10,55	8,89	7,84
5	*Minimale bis 100kg. Alle weiteren je 100 kg
6
7
8	PLZ	10
9	Zone:	1
10	Gewicht:	50
11	Preis/100kg	10,22 €
12	Gesamt	10,22 €

Zelle	Formel
B9	=VERWEIS(B8;{0;20;40;70;99};{1;1;2;3;1})
B11	=INDEX(B2:F4;B9;VERGLEICH(MAX(100;B10);B1:F1;1)+(ZÄHLENWENN(B1:F1;MAX(100;B10))=0))
B12	=B11*AUFRUNDEN(B10%;0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg