Index und Vergleichsfunktion

[dscheydschey]

Hallo zusammen,
Ich habe folgende Formel in Gebrauch, die es mir ermöglicht bei einem nicht vorhandenen Wert aus der S-Verweisfunktion den Wert "Nein" auszugeben.
=WENN($B$3="";"";WENN(SVERWEIS($B$3;Mitgliederdaten!$A$1:$AD$296;29;0)="";"Nein";SVERWEIS($B$3;Mitgliederdaten!$A$1:$AD$294;29;0)))
Klappt auch Prima.

Anstelle des S-Verweises teste ich nun die Index und Vergleichsfunktion, die ich grade so verstanden habe:
=WENNFEHLER(INDEX(Versicherungen2023!$A$1:$R$124;VERGLEICH($B$4;Versicherungen2023!$A$1:$A$124;0);2);"")

Auch diese Formel funktioniert. Hier geht es zwar um eine andere Tabelle aber auch mit nicht vorhandenen Ausgabewerten.
Frage: Wie kann ich hier vmtl. eine Wenn oder WENNNV-Abfrage einbauen, damit ich einen bestimmten Text ausgegeben bekomme, wenn es keinen Wert gibt.
Meine Laienhaften Versuche sind leider gescheitert.
Danke im Voraus für eure Unterstützung

Jakob

[steve1da]

Hola,
also das gleiche Prinzip wie bei deiner Sverweis Formel?
Gruß,
steve1da

[echo]

Frage: Wie kann ich hier vmtl. eine Wenn oder WENNNV-Abfrage einbauen, damit ich einen bestimmten Text ausgegeben bekomme, wenn es keinen Wert gibt.

Hallo
deine Formel steht WENNFEHLER() vor, diese Funktion hat doch eine weitere Option am Ende.
Aktuell wird "" (nichts) angezeigt.
Füge zwischen den "" einen beliebigen Text ein.

Gruß Holger

[dscheydschey]

Hallo Holger,
Die Wennfehlerfunktion bezieht sich in dem Fall auf das fehlende Suchkriterium. Ich brauche aber einen Ersatztext für den fehlenden Ausgabewert.

[steve1da]

Dann mach es doch einfach wie bei der ersten Formel.

[dscheydschey]

Hallo steve1da,
Ich hatte eigentlich gehofft, dass es eine kürzere Variante gibt. Ich habe es mit dem gleichen Prinzip versucht, hat aber irgendwas nicht geklappt. Gleichzeitig wird die Formel - so wie ich das sehe - unendlich lang, womit der ein Vorteil dieser Index/vergleichs-Funktion verloren geht.
Danke dennoch für eure Tipps.

Jakob

[BoskoBiati]

Hi,

Auch diese Formel funktioniert.

Sie ist aber völlig übertrieben. Da ist der SVERWEIS deutlich geschickter. Ansonsten würde das reichen:

Code:

=WENNFEHLER(INDEX(Versicherungen2023!$B$1:$B$124;VERGLEICH($B$4;Versicherungen2023!$A$1:$A$124;0));"")

Wenn Du einen Text einbauen willst, wird das Ganze komplizierter:

Code:

=WENN(ZÄHLENWENN(Versicherungen2023!$A$1:$A$124;$B$4);INDEX(Versicherungen2023!$A$1:$R$124;VERGLEICH($B$4;Versicherungen2023!$A$1:$A$124;0);2);"nicht da"))
=WENN(istzahl(VERGLEICH($B$4;Versicherungen2023!$A$1:$A$124;0));INDEX(Versicherungen2023!$A$1:$R$124;VERGLEICH($B$4;Versicherungen2023!$A$1:$A$124;0);2);"nicht da"))

Ich habe jetzt nicht getestet, ggf. ist die Klammersetzung falsch.

[dscheydschey]

Habe es nochmal versucht nach dem gleichen Prinzip wie bei der S-Verweis-Funktion. Diesmal hat es geklappt, aber wie gesagt, eine unendlich lange Formel:

=WENN(B4="";"";WENN(INDEX(Versicherungen2023!$A$1:$R$124;VERGLEICH($B$4;Versicherungen2023!$A$1:$A$124;0);13)="";"nein";INDEX(Versicherungen2023!$A$1:$R$124;VERGLEICH($B$4;Versicherungen2023!$A$1:$A$124;0);13)))

Schade drum!
Vielen Dank für eure Mühe.
LG und noch einen schönen Sonntag
Jakob

PS: Ihr habt Recht. Ich bleibe in dem Fall bei der S-Verweis-Funktion. Man muss ja nicht übertreiben.  Aber als Lernender versucht man eben so Manches, auch wenn es nicht zielführend ist. Danke.

[HKindler]

Hi,

wieso berechnest du den Vergleich zwei mal? Ich würde diese Berechnung in eine (versteckte) Hilfszelle auslagern. Das macht die ganze Sache übersichtlicher. Übrigens: INDEX/VERGLEICH ist immer dann geschickt, wenn man mehrere Werte aus derselben Zeile braucht oder wenn die Ergebnisspalte links von der Suchspalte liegt. Bei neuem Excel gibt es übrigens XVERWEIS, der unter anderem auch diesen Fall abdeckt.

Also mit der Hilfszelle z.B. X4:
X4: =VERGLEICH(B4;Versicherungen2023!$A$1:$A$124;0)
bisherige Zele: =WENN(B4="";"";WENN(INDEX(Versicherungen2023!$A$1:$R$124;X4;13)="";"nein";INDEX(Versicherungen2023!$A$1:$R$124;X4;13)))
oder besser (da INDEX im Gegensatz zu zum SVerweis auch mit einer einzelnen Spalte klar kommt
bisherige Zele: =WENN(B4="";"";WENN(INDEX(Versicherungen2023!$M$1:$M$124;X4)="";"nein";INDEX(Versicherungen2023!$M$1:$M$124;X4)))

Wenn du die Zeilennummer nicht öfters brauchst, dann kannst du auch noch INDEX mit in die Hilfszelle nehmen:
X4:
X4: =INDEX(Versicherungen2023!$M$1:$M$124;VERGLEICH(B4;Versicherungen2023!$A$1:$A$124;0))
bisherige Zele: =WENN(B4="";"";WENN(X4="";"nein";X4))

Bei neuem Excel geht das alles auch ohne Hilfszelle:
=WENN(B4="";"";LET(x;VERGLEICH(B4;Versicherungen2023!$A$1:$A$124;0);y;INDEX(Versicherungen2023!$M$1:$M$124;x);WENN(y="";"nein";y)))

[dscheydschey]

Hallo Helmut,
Vielen herzlichen Dank. Super, Ich wußte doch, dass man das Ganze irgendwie abkürzen kann. Aber wie????
Ich werde das gleich mal ausprobieren. Jetzt habe ich ja etliche Varianten ....

Danke für die LET-Funktion. Die kannte ich bisher gar nicht, aber echt cool.
LG
Jakob