ISTLEER Funktion

[blaster619]

Hallo Leute,

ich habe ein Excel Sheet bei dem es mir verschiedene Textbausteine von Zellen in einen Namen zusammenfügen soll.

Momentane Formel: 

="Org_" & B13 & "_" & D13 & "_" & F13 & "_" & H13 & "_" & J13

Es kommt z.B. folgender Name heraus: 

Org_CEO_Global Prod_Prod LU_CNC Proc_Turning

Nun gibt es das Problem, dass es auch in verschiedenen Spalten kein Wert drin steht. 

- In der Spalte B und D steht immer ein Wert.
- In den anderen Spalten steht nur manchmal ein Wert

Es kommen dann bei diesen Ausnahmen leider unschöne Namen heraus wie z.B.: ( zu viele "__")

Org_CFO___IT BLN_Apprentices


Weiß jemand eine Formel wie man das umgehen könnte?

Viele Grüße,

blaster

[Luffy]

Hallo,

probier mal:

Code:

="Org_"&B13&"_"&D13&WENN(F13<>"";"_"&F13;"")&WENN(H13<>"";"_"&H13;"")&WENN(J13<>"";"_"&J13;"")

:)

edit: Kann es auch sein dass in H etwas steht und in F nicht? das hab ich jetzt nicht berücksichtigt.

[Luffy]

Hi,

hier was das alles abdeckt :)

Code:

="Org_"&B13&"_"&D13&WENN(UND(F13<>"";H13<>"";J13<>"");"_"&F13&"_"&H13&"_"&J13;WENN(UND(F13<>"";H13<>"");"_"&F13&"_"&H13;WENN(UND(F13<>"";J13<>"";);"_"&F13&"_"&J13;WENN(UND(H13<>"";J13<>"");"_"&H13&"_"&J13;WENN(F13<>"";"_"&F13;WENN(H13<>"";"_"&H13;WENN(J13<>"";"_"&J13;"")))))))

[blaster619]

Hat super geklappt. DANKE!!!!

Aber deine erste Formel hat bei mir schon überall geklappt. Mein Fehler war, das ich dir oben leider falsch mitgeteilt habe, dass in Spalte D auch manchmal nichts steht.

Aber scheint trotz der kleine Formel zu funktionieren.

[Luffy]

Hi,

Wenn in D nichts steht bekommst du nen doppel "__"

[blaster619]

Hab sie davor so angepasst:

="Org_"&B13&WENN(D13<>"";"_"&D13;"")&WENN(F13<>"";"_"&F13;"")&WENN(H13<>"";"_"&H13;"")&WENN(J13<>"";"_"&J13;"")

Scheint alles gut zu klappen!

[Jockel]

Hallo, wie wär's mit..:


gelöscht, weil nicht zu ende gedacht...

[Luffy]

Hallo, wie wär's mit..:

Code:

=WECHSELN(GLÄTTEN(B13&" "&D13&" "&F13&" "&H13&" "&J13);" ";"_")

Sehr elegante Lösung, und deckt alle Möglichkeiten ab! ich habe meine Formel nochmal überarbeitet und die Spalte D auch noch ab zu decken, so sieht Jockel's Formel bei einem Anfänger aus: :D

Code:

="Org_"&B13&WENN(UND(D13<>"";F13<>"";H13<>"";J13<>"");"_"&D13&"_"&F13&"_"&H13&"_"&J13;WENN(UND(D13<>"";F13<>"";H13<>"");"_"&D13&"_"&F13&"_"&H13;WENN(UND(D13<>"";H13<>"";J13<>"");"_"&D13&"_"&H13&"_"&J13;WENN(UND(D13<>"";F13<>"";J13<>"");"_"&D13&"_"&F13&"_"&J13;WENN(UND(F13<>"";H13<>"";J13<>"");"_"&F13&"_"&H13&"_"&J13;WENN(UND(D13<>"";F13<>"");"_"&D13&"_"&F13;WENN(UND(D13<>"";H13<>"");"_"&D13&"_"&H13;WENN(UND(D13<>"";J13<>"");"_"&D13&"_"&J13;WENN(UND(F13<>"";H13<>"");"_"&F13&"_"&H13;WENN(UND(F13<>"";J13<>"");"_"&F13&"_"&J13;WENN(UND(H13<>"";J13<>"");"_"&H13&"_"&J13;WENN(D13<>"";"_"&D13;WENN(F13<>"";"_"&F13;WENN(H13<>"";"_"&H13;WENN(J13<>"";"_"&J13;"")))))))))))))))

[Luffy]

@ Jockel was war falsch an deiner Formel? Bei mir funktioniert sie.

[Jockel]

@ Jockel was war falsch an deiner Formel?

Hallo, wenn z.B. ein Leerzeichen innerhalb einer Zelle ist..:

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B	C	D	E	F	G	H	I	J
13		CFO						IT BLN		Apprentices
14
15	Org_CFO_IT_BLN_Apprentices			falsch
16	Org_CFO_IT BLN_Apprentices			richtig

Zelle	Formel
A15	="Org_"&WECHSELN(GLÄTTEN(B13&" "&D13&" "&F13&" "&H13&" "&J13);" ";"_")
A16	="Org_"&WECHSELN(WECHSELN(GLÄTTEN((WECHSELN(B13;" ";"#")&" "&WECHSELN(D13;" ";"#")&" "&WECHSELN(F13;" ";"#")&" "&WECHSELN(H13;" ";"#")&" "&WECHSELN(J13;" ";"#")));" ";"_");"#";" ")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg