INDEX/VERGLEICH Funktion

[sfo]

Hallo Zusammen,

ich habe die Tabelle im Anhang vorliegen und soll mit Hilfe der INDEX/VERGLEICH Funktion den Namen des Mitarbeiters in Spalte G ausgeben.

Meine Funktion lautet wie folgt: =INDEX('Mitarbeiter Sales'!$A$2:$B$79;VERGLEICH('Bestellungen 2013'!F2;'Mitarbeiter Sales'!$A$2:$A$79;0);VERGLEICH('Bestellungen 2013'!$F$1;'Mitarbeiter Sales'!$A$1:$B$1;0))

Allerdings erhalte ich nur #NV

Kann mir jemand evtl. sagen, wo mein Fehler liegt?

Danke vorab!

[steve1da]

Hola,
hier reicht ein einfacher Sverweis. Du erhältst #NV weil der Wert in F1 und in A1 nicht identisch geschrieben ist. Außerdem würdest du dann den Namen immer noch nicht bekommen, weil dein 2. Vergleich Spalte A ergibt - die Namen stehen aber in Spalte B.

Code:

=SVERWEIS(F2;'Mitarbeiter Sales'!A:B;2;0)

Gruß,
steve1da

[sfo]

Hallo Steve1da,

Danke für deine Antwort.

grundsätzlich wäre ein sverweis natürlich möglich und einfacher, die Vorgabe ist allerdings INDEX/VERGLEICH zu verwenden.

Kannst du mir evtl. sagen, wie ich den 2. Vergleich korrigieren muss?

[steve1da]

Dann:
https://www.herber.de/excelformeln/src/call.pl?idx=24
Dort steht zwar Sverweis nach links, aber das geht genauso nach rechts.

[sfo]

Danke!!

Aber kannst du mir nicht einfach sagen, was genau daran falsch ist? :D Du scheinst es ja schon erkannt zu haben ;) Was muss ich ändern?

Vielen Dank!

[steve1da]

Mit deiner Formel sucht man den Schnittpunkt von 2 Suchkriterien. Das erste ist bei dir die Nummer, das zweite der Text aus F1. Der steht in der anderen Tabelle in A1 und nicht in B1. Das würde dir schon mal nicht den Namen ausgeben. Außerdem sind die Texte nicht gleich.

[sfo]

Das mit dem Text hab ich verstanden und bereits angepasst.

Heißt, ich müsste aus dem zweiten Vergleich einfach B1 komplett rausnehmen? Dann sähe die Formel so aus 

=INDEX('Mitarbeiter Sales'!$A$2:$B$79;VERGLEICH('Bestellungen 2013'!F2;'Mitarbeiter Sales'!$B$2:$B$79;0);VERGLEICH('Bestellungen 2013'!$F$1;'Mitarbeiter Sales'!$A$1;0))

Ich bekomme aber trotzdem #NV

[steve1da]

Nein, nicht B1 rauslassen. Nochmal: du hast 2 Suchkriterien. Nummer und Text. Die Nummer findet man in Spalte, den Text in A1:B1. Wird beides gefunden wird der Wert aus dem Schnittpunkt zurückgegeben. Dein Text aus F1 steht in A1, nicht in B1. Lässt du B1 raus, ergibt das automatisch #NV.
Dein 2. Suchkriterium muss also der Text sein, der in B1 als Überschrift steht.

[neopa]

Hallo sfo,

wenn Du INDEX() und VERGLEICH() für die Ergebnisermittlung einsetzen willst, dann würde folgende Formel:

=INDEX('Mitarbeiter Sales'!B:B;VERGLEICH(F2;'Mitarbeiter Sales'!A:A;0))

ausreichend sein. Du kannst es auch natürlich auf den vorhandenen Datenbereich beschränken, also so:

=INDEX('Mitarbeiter Sales'!B$2:B$79;VERGLEICH(F2;'Mitarbeiter Sales'!A$2:A$79;0))

Da Du aber nach Deinem Fehler fragst:
Du hast eine zweispaltige Ergebnismatrix  'Mitarbeiter Sales'!$A$2:$B$79  angegeben. Das ist noch kein Fehler (ist hier nur unnötig). Dann aber musst Du auch als Ergebnis-Spaltenwert vorgeben oder ermitteln. In dem Fall als eine 2 oder eben diese 2 mit z.B.:  =VERGLEICH("Name";'Mitarbeiter Sales'!$1:$1;0) ermitteln.

Deine Formel korrigiert müsste also richtig so:

=INDEX('Mitarbeiter Sales'!A$2:B$79;VERGLEICH(F2;'Mitarbeiter Sales'!A$2:A$79;0);VERGLEICH("Name";'Mitarbeiter Sales'!$1:$1;0))

aber bereits wie geschrieben. Einfacher ist die eingangs angeführte oder eben auch die SVERWEIS()-Formel.

Noch eins: In F5 hast Du einen Textwert zu stehen. Da würdest Du auch ein #NV erhalten. Aber duchr den kleinen "Trick" den Suchwert mit 1 zu multiplizieren oder alternativ einfach nur eine 0 zu addieren wird aus diesem textwert wieder ein echter Zahlenwert und Du erhälst auch dafür ein korrektes Ergebnis.

Also in der Formel G2 z.B. so: ... VERGLEICH(F2*1;...

weil natürlich echte Zahelnwerte durch die Multiplikation mit oder durch +0 sich ja nicht ändern.

[sfo]

Vielen Lieben Dank, Werner!! Mit deiner einfachen Formel hat es einwandfrei funktioniert :) Da war ich wohl zu kompliziert unterwegs.

Wie gesagt, S-Verweis würde natürlich gehen. Hier ist aber explitzit INDEX/VERGLEICH gefordert gewesen.

Nochmal vielen Dank und einen schönen Restsonntag!!

LG
Sfo