Häufigkeit in Zeile

[Al Swearengen]

Hallo!

Ich möchte, daß Excel mir in einer Zelle anzeigt, wie häufig eine Zahl vorkommt. Wenn mehr als eine Zahl z. B. 2 oder 3 mal vorhanden ist, sollen beide Zahlen in den Zellen angezeigt werden. Wenn keine Zahl mehrfach vorkommt, dann soll eine 0 angezeigt werden.

Die Zeilen, in denen Werte stehen, haben mal nur 1 Zahl, dann aber bis zu 200 Zahlen, sodaß viele Leerzellen vorhanden sein können.

In der Beispieldatei soll das Ergebnis für die Werte in den Zellen B2:Q2 in Zelle AA2 der Wert 6, in der Zelle AB2 der Wert 4 und in der Zelle AC2 der Wert 15 angezeigt werden; entsprechend für die nächste Zeile.

Welche Formel brauche ich für die Zellen AA2, AB2 bzw. AC2?

Meine Versuche mit der Formel WENNFEHLER(MODUS.VIELF() brachte leider nur die erste Zahl, nicht aber die zweite, die 3. Zahl...

Hat jemand einen Vorschlag?

[slowboarder]

Hi
wenn es ok ist, dass die Werte nach Größe sortiert sind, dann so:
in AA2:
=AGGREGAT(15;6;$B2:$Y2/(ZÄHLENWENNS($B2:$Y2;$B2:$Y2)>1);1)
in AB2:
=AGGREGAT(15;6;$B2:$Y2/(ZÄHLENWENNS($B2:$Y2;$B2:$Y2)>1)/($B2:$Y2>AA2);1)
in AC2:
=AGGREGAT(15;6;$B2:$Y2/(ZÄHLENWENNS($B2:$Y2;$B2:$Y2)>1)/($B2:$Y2>AB2);1)
usw
die Formel in AB2 kannst du dann soweit wie benötigt nach rechts ziehen.



mit neueren Excelversionen (365) dann auch so
=LET(a;B2:Y2;EINDEUTIG((FILTER(a;ZÄHLENWENNS(a;a)>1));WAHR))

Gruß Daniel

[Andreas Killer]

In der Beispieldatei soll das Ergebnis für die Werte in den Zellen B2:Q2 in Zelle AA2 der Wert 6, in der Zelle AB2 der Wert 4 und in der Zelle AC2 der Wert 15 angezeigt werden; entsprechend für die nächste Zeile.

In Excel 2016 musst Du die Formel als Matrixformel eingeben, z.B. für max. 5 Zahlen:
AA2:AE2:  {=MTRANS(MODUS.VIELF(B2:Y2))}

Wenn es weniger als 5 Zahlen gibt siehst Du #NV in den entsprechenden Zellen:
   

Ich habe da einfach eine bedingte Formatierung für die Fehler erstellt und die Schriftfarbe grau gemacht... der Einfachheit halber.

Andreas.

[snb]

Vielleicht so ?

[Al Swearengen]

Hallo, Daniel!

Vielen Dank für deinen Vorschlag. Er hat mir sehr viel weitergeholfen.

Ich habe die Formeln ein wenig an meine Bedürfnisse angepaßt. Das Ergebnis habe ich hochgeladen, falls du es einsehen willst.

Schön' Tag noch!