Geburtstagsperson anzeigen

[Sputnikbaby]

Hallo zusammen.
Ich bin neu hier und daher bitte ich um Verständnis, falls ich irgendetwas falsch mache.
Ich benötige Hilfe bei der Erstellung einer Geburtstagsliste.
Die Liste selber ist recht simpel. Von A1 bis A17 steht der Name und von B1 bis B17 steht das Geburtsdatum ohne Jahr.
Jetzt möchte ich auf D1 den Namen angezeigt bekommen, welcher heute Geburtstag hat.
Ich habs mit einer Verschachtelung der WENN-Formel versucht, aber da war das Höchstmaß der Verschachtelungen irgendwo bei 7.

Kann mir irgendjemand einen Anreiz geben, wie ich auf D1 den Namen aus A angezeigt bekomme, wenn das Datum aus B Heute ist?

Ich danke schon jetzt für eure Anregungen.

Gruß
Sputnikbaby

   

[steve1da]

Hola,

Code:

=index(A1:A17;vergleich(heute();B1:B17;0))

Kann aber sein dass es nicht klappt - auf einem Bild kann man leider das Format einer Zelle nicht erkennen.

Gruß,
steve1da

[Sputnikbaby]

Danke für die schnelle Antwort.
Es funktioniert.
Wie bekomme ich jetzt noch ein --- dahin, wenn kein Geburtstag ist.

[steve1da]

Hola,

Code:

=wennfehler(index(A1:A17;vergleich(heute();B1:B17;0));"--")

Gruß,
steve1da

[Jockel]

Hallo, so z.B. ..: (da du ja oO verwendest)

Code:

=WENN(ISTNV(VERGLEICH(HEUTE();B1:B17;0));"--";INDEX(A1:A17;VERGLEICH(HEUTE();B1:B17;0)))

[Jockel]

Hola,

Code:

=wennfehler(index(A1:A17;vergleich(heute();B1:B17;0));"--")

Gruß,
steve1da

Hallo, aber nicht bei oO... ;-(

[Sputnikbaby]

Vielen Vielen Dank.
Ich mach das für die Arbeit, habe zuhause aber kein MS sondern nur oO
Ich danke euch nochmal und werde das Thema jetzt schließen.

[RPP63]

Moin!
Was passiert, wenn mehrere Leute Geburtstag haben?
Ist ja dann doch etwas komplizierter (hier für Excel):
In M1 steht: =TEXT(HEUTE();"TT. MMMM")

	A	B	C	D	E	L	M	N
1	Geburtsdatum	Geburtstag	Name	Vorname		Heute	31. Januar
2	11.01.1960	11. Januar	Name 0900	Vorname 0900		Geburtsdatum	Name	Vorname
3	16.01.1960	16. Januar	Name 0384	Vorname 0384		31.01.1960	Name 0725	Vorname 0725
4	23.01.1960	23. Januar	Name 1952	Vorname 1952		31.01.1966	Name 0035	Vorname 0035
5	26.01.1960	26. Januar	Name 0458	Vorname 0458		31.01.1967	Name 0653	Vorname 0653
6	31.01.1960	31. Januar	Name 0725	Vorname 0725		31.01.1967	Name 1621	Vorname 1621
7	01.03.1960	01. März	Name 0373	Vorname 0373		31.01.1970	Name 0620	Vorname 0620
8	15.03.1960	15. März	Name 1524	Vorname 1524		31.01.1977	Name 0952	Vorname 0952
9	25.03.1960	25. März	Name 0824	Vorname 0824		31.01.1981	Name 1039	Vorname 1039
10	08.04.1960	08. April	Name 0902	Vorname 0902		31.01.1984	Name 0439	Vorname 0439
11	14.04.1960	14. April	Name 0227	Vorname 0227		31.01.1999	Name 1369	Vorname 1369
12	15.04.1960	15. April	Name 1160	Vorname 1160

Formeln der Tabelle

Zelle Formel B3 =TEXT(A3;"TT. MMMM") L3 {=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$1:$B$2000=M$1;ZEILE($1:$2000));ZEILE($A1)));"")} M3 {=WENNFEHLER(INDEX($C:$C;KKLEINSTE(WENN($B$1:$B$2000=M$1;ZEILE($1:$2000));ZEILE($A1)));"")} N3 {=WENNFEHLER(INDEX($D:$D;KKLEINSTE(WENN($B$1:$B$2000=M$1;ZEILE($1:$2000));ZEILE($A1)));"")}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

In meiner Datei könnt ihr die Makros ruhig deaktivieren, da ging es um eine Anzeige per Msgbox (Makro RPP).

Gruß Ralf

[Jockel]

Vielen Vielen Dank.
Ich mach das für die Arbeit, habe zuhause aber kein MS sondern nur oO
...

off topic...

... dann solltest du das evtl. in der Signatur angeben. Es gibt zuweilen erhebliche Unterschiede zwischen oO und XL (und innerhalb der verschiedenen XL-Versionen, die es mittlerweile gibt auch) ...

[Jockel]

Moin!
Was passiert, wenn mehrere Leute Geburtstag haben?
Ist ja dann doch etwas komplizierter (hier für Excel):
...
Gruß Ralf

Hallo Ralf, KKLEINSTE() geht in oO auch, nur eben WENNFEHLER() nicht, wenn der TE in der Arbeit XL>2007 verwendet, würde ich eh' AGGREGAT() vorschlagen...