Fußball, direktvergleich zweier Mannschaften

[Gin Sandmann]

Hallo zusammen
 
Und zwar habe ich folgendes Problem,
ich möchte einen direktvergleich zwischen zwei Fußballmannschaften erstellen.
Und habe folgende Formeln eingegeben.

In B10 =INDEX($F$9:$F$6434;VERGLEICH(C9&D9;$J$9:$J$6434&$K$9:$K$6434;0))
In C10 =INDEX($I$9:$I$6434;VERGLEICH(C9&D9;$J$9:$J$6434&$K$9:$K$6434;0))
In D10 =INDEX($L$9:$L$6434;VERGLEICH(C9&D9;$J$9:$J$6434&$K$9:$K$6434;0))

So weit kein Problem, da er mir das erste Ergebnis ausspuckt was mit den Suchkriterien übereinstimmt.
In der nächsten Zeile habe ich dann folgende Formel eingegeben Damit mir Excel die vorigen Ergebnisse ausspuckt

Code:

B11 =INDEX($F$9:$F$6434;VERGLEICH(C9&D9&MAX(WENN($F$9:$F$6434<B10;$F$9:$F$6434));$J$9:$J$6434&$K$9:$K$6434&$F$9:$F$6434;0))
C11 =INDEX($I$9:$I$6434;VERGLEICH(C9&D9&MAX(WENN($F$9:$F$6434<B10;$F$9:$F$6434));$J$9:$J$6434&$K$9:$K$6434&$F$9:$F$6434;0))
D11 =INDEX($L$9:$L$6434;VERGLEICH(C9&D9&MAX(WENN($F$9:$F$6434<B10;$F$9:$F$6434));$J$9:$J$6434&$K$9:$K$6434&$F$9:$F$6434;0))

Das geht aber nur solange gut solange die Jahre nicht unterbrochen werden. (siehe Anhang)
Ich könnte zwar mit “wenn(istfehler(“ und “–“ bei den Jahren (Zellbezüge B) arbeiten,
aber das würde glaube ich den Rammen bei der Formeleingabe sprängen,
wenn die besagten Mannschaften das letzte mal 20 Jahre vorher aufeinander trafen und wäre außerdem sehr umständlich.
 
Wenn mir da jemand helfen könnte wäre ich sehr dankbar.

[steve1da]

Hola,

bitte eine Exceldatei hochladen.

Gruß,
steve1da

[Gin Sandmann]

Ich frage mich, warum die Formel von B11 C11 D11 hier nicht komplet angezeigt werden.

Na ja egal, hier die Datei.

[steve1da]

Hola,

schreib in eine Hilfsspalte, z.B. ab M9:

Code:

=J9&K9

Dann für die Jahre:

Code:

=WENNFEHLER(INDEX($F$9:$F$6434;AGGREGAT(15;6;ZEILE($A$9:$A$6434)-8/($M$9:$M$6434=$C$9&$D$9);ZEILE(A1)));"")

Für die andere Werte einfach den Index-Bereich ändern.

Gruß,
steve1da

[Gin Sandmann]

muchas gracias. :23: 
Du hast mir echt weiter helfen können, ich war schon am verzweifeln. ;)
Habe da aber noch ne kleine Frage, kann man das nur über die Hilfsspalte machen oder geht das auch wenn ich die Spalten direkt anspreche?

[steve1da]

Hola,

Code:

=WENNFEHLER(INDEX($F$9:$F$6434;AGGREGAT(15;6;ZEILE($A$9:$A$6434)-8/($J$9:$J$6434&$K$9:$K$6434=$C$9&$D$9);ZEILE(A1)));"")

oder:

Code:

=WENNFEHLER(INDEX($F$9:$F$6434;AGGREGAT(15;6;ZEILE($A$9:$A$6434)-8/(($J$9:$J$6434=$C$9)*($K$9:$K$6434=$D$9));ZEILE(A1)));"")

Gruß,
steve1da

[Gin Sandmann]

Super und noch mal vielen dank.

jetzt muss ich nur noch die Formel auseinanderfriemeln damit ich sie besser verstehe.
Ich hoffe das mir Youtube oder so da weiter helfen kann. ;)

Gruß, Gin

[Jockel]

Alternative gefällig...? Hallo, hier ginge auch..:

PHP-Code:

=KGRÖSSTE(INDEX($F$9:$F$2762*(($J$9:$J$2762=$C$9)*($K$9:$K$2762=$D$9)););ZEILE(A1)) 


Müssen die Leerzeichen..? Exportierst du die Daten..?

[BoskoBiati]

Hi,

bei 2016 würde ich das so machen:

Arbeitsblatt mit dem Namen 'Tabelle1 (3)'
	B	C	D
9		Köln	Leverkusen
10	2018	27	-:- (-
11	2017	16	1:1 (1:1)
12	2016	29	0:2 (0:2)
13	2015	30	1:1 (0:0)
14	2012	23	0:2 (0:1)
15	2011	32	2:0 (0:0)
16	2010	7	0:1 (0:0)

Zelle	Formel
B10	=WENNFEHLER(AGGREGAT(14;6;$F$1:$F$7000/($J$1:$J$7000=$C$9)/($K$1:$K$7000=$D$9);ZEILE(A1));"")
C10	=WENNFEHLER(AGGREGAT(14;6;$I$9:$I$7000/($J$9:$J$7000=$C$9)/($K$9:$K$7000=$D$9)/($F$9:$F$7000=$B10);1);"")
D10	=WENNFEHLER(INDEX($L:$L;AGGREGAT(14;6;ZEILE($L$9:$L$7000)/($J$9:$J$7000=$C$9)/($K$9:$K$7000=$D$9)/($F$9:$F$7000=$B10);1));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo und noch n Gedicht - ohne AGGREGAT() - und ohne CSE-Abschluss

Arbeitsblatt mit dem Namen 'Tabelle1 (3)'
	B	C	D
9		Köln	Leverkusen
10	2018	27	-:- (-:-)
11	2017	16	1:1 (1:1)
12	2016	29	0:2 (0:2)
13	2015	30	1:1 (0:0)
14	2012	23	0:2 (0:1)
15	2011	32	2:0 (0:0)
16	2010	7	0:1 (0:0)

Zelle	Formel
B10	=KGRÖSSTE(INDEX($F$9:$F$2762*(($J$9:$J$2762=$C$9)*($K$9:$K$2762=$D$9)););ZEILE(A1))
C10	=WENN(B10=0;"";INDEX($I$9:$I$2762;VERGLEICH($C$9&$D$9&B10;INDEX($J$9:$J$2762&$K$9:$K$2762&$F$9:$F$2762;);)))
D10	=WENN(B10=0;"";INDEX($L$9:$L$2762;VERGLEICH($C$9&$D$9&C10;INDEX($J$9:$J$2762&$K$9:$K$2762&$I$9:$I$2762;);)))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg