Function.sum in Labelbeschriftung

[peacescorer]

Hallo liebes Forum

Ich brüte seit einer Woche über einem Problem und weiß nicht mehr weiter, da sämtliche erhofften Lösungsansätze scheitern...

In einer Userform (vbmodeless), welche als Übersicht bzw. als eine Art Dashboard dient, möchte ich verschiedene Infos einer Mappe mit 8 - 10 Sheets zusammentragen.
Da viele dieser Infos durch den User nicht verändert werden müssen, habe ich mich für Labels entschieden...

Leider macht mir die Befüllung Schwierigkeiten, sobald ich Daten einlesen will, welche auf ein anderes Sheet verweisen, als von welchem ich die UF über einen Button gestartet habe...

Code:

Private Sub UserForm_Initialize()
Me.Height = ActiveWindow.Height
Me.Controls("Label_Command_Line").Caption = "" 'Aktivitätszeile
Me.Controls("Label2").Caption = "Es gibt " & Sheets("Offerten").Cells(Rows.Count, 1).End(xlUp).Row - 8 & " offene Offerten" 'Anzahl Offerten (-8 sind die 8 obersten Zeilen)
Me.Controls("Label6").Caption = "Es gibt " & Sheets("Aufträge").Cells(Rows.Count, 1).End(xlUp).Row - 8 & " offene Aufträge"
Me.Controls("Label13").Caption = Format(Application.WorksheetFunction.Sum(Sheets("Offerten").Range(Cells(10, 25), Cells(12, 25))), "#,##0.00")
Me.Controls("Label16").Caption = Format(WorksheetFunction.Sum(Sheets("Aufträge").Range(Cells(10, 25), Cells(11, 25))), "#,##0.00")
End Sub

Je nachdem von welchem Sheet ich die UF starte, hängt entweder die Label13 (Sheets Offerten) oder Label16 (Sheets Aufträge) mit einer "Laufzeitfehler 1004"-Meldung...

Kann mir jemand helfen?

PS: Wenn eine Beispieldatei notwendig ist, schreibt mir bitte... vermutlich sieht der versierte VBA`ler aber schon auf den ersten Blick was los ist.

Danke und liebe Grüße

Christian

[Klaus-Dieter]

Hallo,

zunächst fällt mir das Me auf, dazu gucksdt du: Me

[Werner.M]

Hallo Christian,

schätze mal das häufige Refernzierungsproblem.
Um sauber auf ein Blatt zu referenzieren mußt du vor jedes Range Objekt (Range, Cells, Rows.Count...) den Blattnamen dazu schreiben.
Um diese Schreibarbeit zu spaten kann man das ganze in eine With - End With "Klammer" packen.
Innerhalb des With - End With wird auf das im With angegebene Blatt referenziert, indem man vor jedes Range Objekt einen Punkt setzt.

Code:

Private Sub UserForm_Initialize()
Me.Height = ActiveWindow.Height
Me.Controls("Label_Command_Line").Caption = "" 'Aktivitätszeile
With Sheets("Offerten")
   Me.Controls("Label2").Caption = "Es gibt " & .Cells(.Rows.Count, 1).End(xlUp).Row - 8 & " offene Offerten"
   Me.Controls("Label13").Caption = Format(Application.WorksheetFunction.Sum(.Range(.Cells(10, 25), .Cells(12, 25))), "#,##0.00")
End With
With Sheets("Aufträge")
   Me.Controls("Label6").Caption = "Es gibt " & .Cells(.Rows.Count, 1).End(xlUp).Row - 8 & " offene Aufträge"
   Me.Controls("Label16").Caption = Format(WorksheetFunction.Sum(.Range(.Cells(10, 25), .Cells(11, 25))), "#,##0.00")
End With
End Sub

Gruß Werner

[Werner.M]

Hallo Christian,

und das Controls brauchst du doch auch nicht:

Code:

Private Sub UserForm_Initialize()
Me.Height = ActiveWindow.Height
Me.Label_Command_Line.Caption = "" 'Aktivitätszeile
With Sheets("Offerten")
   Me.Label2.Caption = "Es gibt " & .Cells(.Rows.Count, 1).End(xlUp).Row - 8 & " offene Offerten"
   Me.Label13.Caption = Format(Application.WorksheetFunction.Sum(.Range(.Cells(10, 25), .Cells(12, 25))), "#,##0.00")
End With
With Sheets("Aufträge")
   Me.Label6.Caption = "Es gibt " & .Cells(.Rows.Count, 1).End(xlUp).Row - 8 & " offene Aufträge"
   Me.Label16.Caption = Format(WorksheetFunction.Sum(.Range(.Cells(10, 25), .Cells(11, 25))), "#,##0.00")
End With
End Sub

Gruß Werner

[peacescorer]

Werner!
Klaus-Dieter!

DANKE! - Funktioniert einwandfrei...

Werde mir den "Me"-Wink, vor allem aber die Referenzierungen zur Gemüte führen...

Ich habe noch ein kleines Problem, möchte aber nicht unbedingt ein neues Thema eröffnen (auch wenn es Sinn machen würde).

Meine Mappe ist mit vielen Application.speech.speak -Zeilen ausgestattet, was auf meinem Rechner einwandfrei geht.
Nun ist es so, daß mir Excel auf dem Firmenrechner eine Fehlermeldung auswirft (Methode Speak ist fehlgeschlagen) - Ich nehme an weil keine Soundkarte installiert ist...
Diese lässt sich auch nicht mit "On Error resume next" abfangen...

Wisst ihr wie ich vorab eine Prüfung starten kann ob eine Soundkarte installiert ist oder wie ich die Fehlermeldung abfangen kann?

Danke nochmals für die vorige Lösung!!!

Christian

[schauan]

Hallöchen,

zuweilen ist in Firmen auch eine Soundkarte drin und über GPO deaktiviert

Evetuell kannst DU über eine zusätzliche Function die Soundausgabe prüfen und das Ergebnis der Function auswerten. Wie äußert sich denn das Problem? Bekommst Du eine Meldung und kommst nicht weiter? Oder bricht das Sub einfach ab? Oder ...?