Für verschiedene Touren-Kombinationen Preis und Maut automatisch ziehen

[CleSie]

Hallo,

ich benötige eine Formel, die für bestimmte Touren-Kombinationen automatisch den Preis und Maut zieht.
Ich habe quasi eine Tabelle als Datenbasis und muss täglich eine Liste schreiben in der die Relationen variieren.
Um Zeit zu sparen wäre es praktisch, wenn ich Preis und Maut nicht jedes Mal neu eingeben müsste, sondern die Zahlen automatisch eingefügt werden.

Im Anhang befindet sich ein Beispiel. Die orangen Zellen sollen sich automatisch füllen.

Bei den Relationen kann es vorkommen, dass das Land aus der Tabelle Absender oder Empfänger ist.
z.B. Deutschland - Spanien, Spanien - Deutschland.
Preis und Maut bleiben dennoch gleich.

Ich bin für jede Hilfe dankbar. Alle Fragen werde ich zügig beantworten.

LG

Clemens

[Elex]

Hi

Du solltest deinen Tabellenaufbau anders gestallten.

Code:

____|______A_____|_____B_____|___C__|__D__|_E|_F|______G_____|______H_____|___I__|__J__|_K|
   1|            |           |      |     |  |  |            |            |      |     |  |
   2|            |           |      |     |  |  |            |            |      |     |  |
   3|Start       |Ziel       |Preis |Maut |  |  |Tour Start  |Tour Ziel   |Preis |Maut |  |
   4|Deutschland |Frankreich |   100|   10|  |  |Deutschland |Spanien     |   200|   20|  |
   5|Deutschland |Spanien    |   200|   20|  |  |Lettland    |Deutschland |   300|   30|  |
   6|Deutschland |Lettland   |   300|   30|  |  |Schweiz     |England     |   150|   15|  |
   7|Deutschland |Schweden   |   400|   40|  |  |Deutschland |Schweden    |   400|   40|  |
   8|England     |Schweiz    |   150|   15|  |  |England     |Österreich  |   350|   35|  |
   9|England     |Spanien    |   250|   25|  |  |            |            |      |     |  |
  10|England     |Österreich |   350|   35|  |  |            |            |      |     |  |

Code:

I4  =INDEX($C$4:$D$10;WENNFEHLER(VERGLEICH($G4&$H4;$A$4:$A$10&$B$4:$B$10;0);VERGLEICH($H4&$G4;$A$4:$A$10&$B$4:$B$10;0));SPALTE(A1))

Die Formel ist mit strg+shift+enter abzuschließen. Und dann nach rechts und unten ziehen/kopieren.

Gruß Elex

[CleSie]

Die Tabellen kann ich leider nicht ändern. Es handelt sich um eine Umsatzliste, die ich täglich für die Geschäftsführung ausfüllen muss. 
Das Ablesen von Preisen kostet sehr viel Zeit. Deswegen muss das Schema exakt wie in meinem Beispiel aussehen. :(

Vielleicht hast du trotzdem eine Formel die in meine Tabelle passt?!

Danke im Voraus.

Gruß

Clemens

[Elex]

Tut mir ja Leid aber mit dem Blattaufbau wird das wohl nichts. 
Und wenn mit deinen Chefs keine Kommunikation möglich ist, habt Ihr (wahrscheinlich Du) ein Problem.

[steve1da]

Hola,

Code:

=WENN(SUMMENPRODUKT(($B$2:$F$2=LINKS(B9;FINDEN("-";B9)-2))*($B$3:$F$6=TEIL(B9;FINDEN("-";B9)+2;99));$C$3:$G$6)=0;SUMMENPRODUKT(($B$2:$F$2=TEIL(B9;FINDEN("-";B9)+2;99))*($B$3:$F$6=LINKS(B9;FINDEN("-";B9)-2));$C$3:$G$6);SUMMENPRODUKT(($B$2:$F$2=LINKS(B9;FINDEN("-";B9)-2))*($B$3:$F$6=TEIL(B9;FINDEN("-";B9)+2;99));$C$3:$G$6))

Code:

=WENN(SUMMENPRODUKT(($B$2:$F$2=LINKS(B9;FINDEN("-";B9)-2))*($B$3:$F$6=TEIL(B9;FINDEN("-";B9)+2;99));$D$3:$H$6)=0;SUMMENPRODUKT(($B$2:$F$2=TEIL(B9;FINDEN("-";B9)+2;99))*($B$3:$F$6=LINKS(B9;FINDEN("-";B9)-2));$D$3:$H$6);SUMMENPRODUKT(($B$2:$F$2=LINKS(B9;FINDEN("-";B9)-2))*($B$3:$F$6=TEIL(B9;FINDEN("-";B9)+2;99));$D$3:$H$6))

Gruß,
steve1da

[CleSie]

Das beurteilst du jetzt ein wenig vorschnell, da du die Situation nicht kennst...

Zurück zum Problem. Ich bin mir ziemlich sicher, dass es eine Formel gibt die folgendermaßen funktioniert:

Wenn z.B. das Wort "Deutschland" in z.B. "Deutschland - Spanien" vorhanden, dann Tabelle "Deutschland". 
Anschließend wenn "Spanien", dann Preis "200".

Kenne mich aber zu wenig mit den Funktionen aus, die hier notwendig sind.

Vielleicht hat jemand anderes noch eine Idee?

[Elex]

Das beurteilst du jetzt ein wenig vorschnell, da du die Situation nicht kennst...

Ich denke nur das es nicht nur zwei Tabellen sind die als Basis dienen und ob die alle auch so nebeneinander stehen?

Klar bekommt man das irgendwie in eine Formel. Ist halt der umständliche Umweg.
Für C9

Code:

=SUMMENPRODUKT((($B$2:$F$2=LINKS(B9;FINDEN("-";B9)-2))+($B$2:$F$2=TEIL(B9;FINDEN("-";B9)+2;99)))*(($B$3:$F$6=LINKS(B9;FINDEN("-";B9)-2))+($B$3:$F$6=TEIL(B9;FINDEN("-";B9)+2;99)));$C$3:$G$6)

Gruß Elex