Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Frachtkostenkalkulator auf Basis von 4 Tabellen
#1
Hallo liebes Forum,

dies ist mein erster Eintrag, daher bitte ich bei Formfehlern um Nachsicht.

Ich möchte für mein Team einen Frachtkostenkalkulator bauen, bei welchem man lediglich 3 Felder bedienen muss.
Es handelt sich um Sendungen zweier unterschiedlicher Lager von Deutschland in die Schweiz.

Die 3 Variablen lauten:
"Ab Lager" (entweder Remscheid oder Dortmund)
"Gewicht bis" (in kg)
"Postleitzahl" (hierbei bestimmt sich de Versandzone durch die ersten beiden Ziffern der schweizerischen PLZ)

Die Kalkulation muss auf diese 4 Tabellen zurückgreifen:
1. Frachtraten ab RS
2. Frachtraten ab DO
--> mit den Dimensionen Gewicht und Versandzone
3. Zoneneinteilung ab RS
4. Zoneneinteilung ab DO
--> mit den Dimensionen PLZ-2stellig und Versandzone

Über Chat GPT habe ich eine Anweisung erhalten, auf deren Grundlage ich die angehängte Tabelle gebaut und folgende Formel eingefügt habe, zu finden in D2:

=WENN(A2="Remscheid";INDEX(RemscheidRaten!$B$1:$J$19;VERGLEICH(B2;RemscheidRaten!$A$1:$A$19;1);SVERWEIS(LINKS(C2;2);RemscheidZonen!$A$1:$B$29;2;FALSCH));INDEX(DortmundRaten!$B$1:$K$19;VERGLEICH(B2;DortmundRaten!$A$1:$A$19;1);SVERWEIS(LINKS(C2;2);DortmundZonen!$A$1:$B$29;2;FALSCH)))

Ich erhalte den Fehler #NV.

Wenn jemand Interesse hat mir bei der Lösung zu helfen, wäre ich unendlich dankbar.

(Tabelle6 bitte vorerst ignorieren, das kann ich später hinzuaddieren)

Beste Grüße! T


Angehängte Dateien
.xlsx   Kalkulator_V2.xlsx (Größe: 19,02 KB / Downloads: 13)
Antworten Top
#2
Hola,
#NV erhältst du, weil zB dein Sverweis schon #NV ergibt. Du vergleichst hier nämlich einen TEXT mit einer ZAHL.
Gibt es nur die beiden Lager Remscheid und Dortmund?
Gruß,
steve1da
Antworten Top
#3
Okay, wie müsste die Formel dann lauten?
Ja, es gibt nur die beiden Lager.

BG T.
Antworten Top
#4
Probier mal:
Code:
=SVERWEIS(MINWENNS(INDIREKT(A2&"Raten!A2:A21");INDIREKT(A2&"Raten!A2:A21");">="&B2);INDIREKT(A2&"Raten!A2:K21");VERGLEICH(TEIL(SVERWEIS(C2;INDIREKT(A2&"Zonen!A:B");2;0);5;2)*1;INDIREKT(A2&"Raten!A1:J1");0);0)
[-] Folgende(r) 1 Nutzer sagt Danke an steve1da für diesen Beitrag:
  • Anno1987
Antworten Top
#5
Hi,

es geht besser ohne ChatGpt, allerdings mit einem veränderten Aufbau:


.xlsx   Kalkulator_V2.xlsx (Größe: 16,71 KB / Downloads: 8)

Ohne etwas an Deiner Datei zu verändern ginge es so:

Code:
=WENN(A2="Remscheid";INDEX(RemscheidRaten!$B$1:$J$19;VERGLEICH(B2;RemscheidRaten!$A$1:$A$19;1);VERGLEICH(--WECHSELN(SVERWEIS(C2;RemscheidZonen!$A$1:$B$29;2;FALSCH);"Zone ";"");RemscheidRaten!$B$1:$K$1;0));INDEX(DortmundRaten!$B$1:$K$19;VERGLEICH(B2;DortmundRaten!$A$1:$A$19;1);VERGLEICH(--WECHSELN(SVERWEIS(C2;DortmundZonen!$A$1:$B$29;2;FALSCH);"Zone ";"");DortmundRaten!$B$1:$K$1;0)))

Problem ist nur, dass der VERGLEICH bei Gewichten unter 100kg in einen Fehler läuft. Bei solchen Tabellen ist es besser mit "Gewicht ab" zu arbeiten!
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
[-] Folgende(r) 1 Nutzer sagt Danke an BoskoBiati für diesen Beitrag:
  • Anno1987
Antworten Top
#6
@steve1da

Es klappt... unfassbar.
Du bist mein Held des Tages!
1000 Dank!

@BoskoBiati: Danke auch an dich, den Entwurf habe ich mir abgespeichert!

Euer Forum kann was.
Antworten Top
#7
Hallo Anno1987,

Du solltest mehr Testen bevor Du jubelst, denn in der Formel ist noch ein Fehler drin:
- bei der PLZ 39 für Dortmund wird 'Zone 11' ermittelt, die es in der Testtabelle nicht gibt
- dieser Teil der Formel: TEIL(SVERWEIS(C3;INDIREKT(A3&"Zonen!A:B");2;0);5;2)*1 macht aus
  'Zone 11'  aber '1'
- und somit wird in der falschen Spalte gesucht!

Gruß von Luschi
aus klein-Paris
Antworten Top
#8
@Luschi: Danke für den Hinweis!
@Anno: bitte so abändern:
Zitat:.....TEIL(SVERWEIS(C3;INDIREKT(A3&"Zonen!A:B");2;0);5;5)*1 .....
Antworten Top
#9
Hi,

dann werfe ich das noch in den Ring:

Code:
=INDEX(INDIREKT(A2&"Raten!B2:l21");WENNFEHLER(VERGLEICH(B2-1%;INDIREKT(A2&"Raten!A2:A21");1)+1;1);VERGLEICH(--WECHSELN(SVERWEIS(C2;INDIREKT(A2&"Zonen!A:B");2;FALSCH);"Zone ";"");INDIREKT(A2&"Raten!B1:L1");0))
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste