Formel wirft Zahl in Zelle aus, obwohl kein Bezug
#1
Hallo zusammen,

ich habe folgendes Problem. Und zwar habe ich eine Formel die mir das Ergebniss 1,03 ausgibt, obwohl in den Bezugzellen nichts drin steht.
Wie könnte ich dir Formel anpassen, dass er mir anstelle 1,03 erstmal 0 anzeigt.

=((TAG(MIN(C20;MONATSENDE(B20;0)))-TAG(B20)+1)/TAG(MONATSENDE(B20;0))+WENN(MONAT(B20)<>MONAT(C20);TAG(C20)/TAG(MONATSENDE(C20;0))+MAX(0;DATEDIF(MONATSENDE(B20;0);C20-TAG(C20)+1;"M"));0))


In diesem Fall wäre das Feld C20 und B20 noch leer.

Besten Dank und viele Grüße
Antworten Top
#2
Hola,
Monat() und Monatsende() bezogen auf leere Zellen ergeben immer 1 bzw. 31, also niemals 0.
Du musst also jedes dieser Elemente so abfragen:
WENN(B20="";"";MONATSENDE(B20;0))
WENN(B20="";"";MONAT(B20))
Gruß,
steve1da
Antworten Top
#3
Ok. Aber kann ich irgendwo einstellen, dass wenn in der Zelle 1,03 kommt, dass diese an z.B. leer ist oder halt eine 0 stehen soll?
Antworten Top
#4
Hallo,

auf B20/C20="" prüfen:

Code:
=WENN(B20*C20;((TAG(MIN(C20;MONATSENDE(B20;0)))-TAG(B20)+1)/TAG(MONATSENDE(B20;0))+WENN(MONAT(B20)<>MONAT(C20);TAG(C20)/TAG(MONATSENDE(C20;0))+MAX(0;DATEDIF(MONATSENDE(B20;0);C20-TAG(C20)+1;"M"));0));0)

Geht auch so:
Code:
=WENN(B20*C20;((TAG(MIN(C20;MONATSENDE(B20;0)))-TAG(B20)+1)/TAG(MONATSENDE(B20;0))+(MONAT(B20)<>MONAT(C20))*TAG(C20)/TAG(MONATSENDE(C20;0))+MAX(0;MONAT(C20)-MONAT(B20)-1));0)
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#5
Zitat:=WENN(B20*C20;
Danke für's Augen öffnen :)
Antworten Top
#6
(16.05.2024, 16:24)BoskoBiati schrieb: Hallo,

auf B20/C20="" prüfen:

Code:
=WENN(B20*C20;((TAG(MIN(C20;MONATSENDE(B20;0)))-TAG(B20)+1)/TAG(MONATSENDE(B20;0))+WENN(MONAT(B20)<>MONAT(C20);TAG(C20)/TAG(MONATSENDE(C20;0))+MAX(0;DATEDIF(MONATSENDE(B20;0);C20-TAG(C20)+1;"M"));0));0)

Geht auch so:
Code:
=WENN(B20*C20;((TAG(MIN(C20;MONATSENDE(B20;0)))-TAG(B20)+1)/TAG(MONATSENDE(B20;0))+(MONAT(B20)<>MONAT(C20))*TAG(C20)/TAG(MONATSENDE(C20;0))+MAX(0;MONAT(C20)-MONAT(B20)-1));0)

Das funktioniert super. Besten Dank.
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste