Formel verlangsamt Excel

[Andyle]

Ich habe folgende Formel:

=WENN(B6<>0;"( Vom "&TEXT(INDIREKT("B8");"TT.MM.JJJJ")&" bis "&TEXT(VERWEIS(2;1/(B:B<>"");B:B);"TT.MM.JJJJ")&" )";"")

B6 = Formel   =INDIREKT("B8")

Indirekt musste ich machen, da er sonst bei Zeilen löschen den Bezug zu B8 verliert.

Nur habe ich jetzt das Problem, dass wenn die Formel oben drin ist, sich Excel sehr schwer tut und alles recht langsam geht.

neme ich die Formel raus geht es wieder.

An was könnte dass liegen??

Vielen Dank

[Isabell]

Hallo, ohne den Zusammenhang deiner Datei zu kennen, eher schwierig. Indirekt ist allerdings schon eine ordentliche Bremse. Alternativen kann man so nicht vorschlagen.

[Egon12]

Hallo,

Das liegt an Indirekt (volatile Funktion).

Gruß Uwe

[Andyle]

Er nimmt ja wenn in B8 ein Datum steht als von

Dann schaut er nach dem letzten Eintrag in Spalte B und holt da das Datum für bis.

wie kann ich aber dann die Formel umbauen, dass er ohne INDIREKT den Zellbezug nicht verliert?

[BoskoBiati]

Hi,

schmeiß das INDIREKT raus:

Code:

=WENN(B6<>0;"( Vom "&TEXT(INDEX(B:B;8);"TT.MM.JJJJ")&" bis "&TEXT(VERWEIS(2;1/(B:B<>"");B:B);"TT.MM.JJJJ")&" )";"")

[PIVPQ]

Hallo

Wenn ich merkte das die Formeln mein Excel verlangsamen gibt es für mich zwei Wege, entweder 
a) Mit ganz neuen Formeln arbeiten (Heißt für dich das neuste Excel dir anschaffen, was man ja fast geschenkt bekommt)  oder
b) Alle Formeln komplett raus schmeißen und dann mit PQ arbeiten.
Dies nur als Tipp

[oee]

Und nie komplette Spalten in Formeln benutzen wie z.B.:

Code:

....B:B<>"");B:B...

Du hast doch nicht 1 Million Zeilen benutzt - oder etwa doch ?

[BoskoBiati]

Hi oee,

Und nie komplette Spalten in Formeln benutzen

Das nie würde ich streichen, es kommt immer auf die Formel an. Es gibt mit Sicherheit welche, bei denen man da vorsichtig sein sollte, SUMMENPRODUKT z.B., aber bei SUMMEWENNS ist die Größe des Bereichs belanglos. Es gibt noch sehr viele andere Funktionen, bei der die Größe des Bereichs nebensächlich ist.

[Andyle]

@ BoskoBiati 

Also die Formel passt.
=WENN(B6<>0;"( Vom "&TEXT(INDEX(B:B;8);"TT.MM.JJJJ")&" bis "&TEXT(VERWEIS(2;1/(B:B<>"");B:B);"TT.MM.JJJJ")&" )";"")

Nur wie fange ich den Bezug-Fehler ab?

Er soll aber nichts anzeigen wenn in B8 nichts steht.

B6 steht ja =INDIREKT("B8")

wenn ich jetzt die Zeilen ohne INDIREKT ab 8 lösche, fliegt ja ohne INDIREKT in B6 der Bezug zu B8 raus.

=WENN(B8<>0;"( Vom "&TEXT(INDEX(B:B;8);"TT.MM.JJJJ")&" bis "&TEXT(VERWEIS(2;1/(B:B<>"");B:B);"TT.MM.JJJJ")&" )";"")

Zeilen löschen verliert er B8

=WENN(#BEZUG!<>0;"( Vom "&TEXT(INDEX(B:B;8);"TT.MM.JJJJ")&" bis "&TEXT(VERWEIS(2;1/(B:B<>"");B:B);"TT.MM.JJJJ")&" )";"")

[BoskoBiati]

Hi,


alle Deine Beiträge haben das gleiche Problem: Du stellst hier Formeln im luftleeren Raum vor, und wir sollen uns dann ein Bild von Deiner Tabelle machen. Das funktioniert nicht. Zeige in Zukunft ein Muster der Tabelle, dann erübrigen sich solche Nachfragen:

=WENN( INDEX(B:B;8)<>0;"( Vom "&TEXT(INDEX(B:B;8);"TT.MM.JJJJ")&" bis "&TEXT(VERWEIS(2;1/(B:B<>"");B:B);"TT.MM.JJJJ")&" )";"")

dann brauchst Du auch B6 nicht. Wieso löschst Du überhaupt die Zeilen?