Formel vereinfachen

[Hille_2510]

Hallo Leute, 

ich hoffe jemand kann mir hier weiter helfen. Ich habe eine ziemlich komplizierte wenn-Gleichung aufgestellt und bin mir ziemlich sicher, dass man diese vereinfachen kann und deutlich übersichtlicher darstellen kann. Ich weiß aber nicht wie. Ich habe schon vieles versucht aber irgendwie hat nichts bisher zum gewünschten Erfolg geführt. 

Es geht um die Formel in den gelb markierten Zellen. Die Formel berechnet mir den durchschnittlichen "Gesamtwirkungsgrad" einer Gruppe an einem Tag. Die Gruppe besteht im Moment aus 5 Mitarbeitern und jeder Mitarbeiter hat einen anderen Wirkungsgrad. Der Wirkungsgrad verändert sich auch je nachdem ob der Mitarbeiter den ganzen Tag anwesend war "A", nur den halben Tag anwesend war "HAT" oder den ganzen Tag nicht produktivwar "GAT". Bei A zählt der volle Wirkungsgrad, bei HAT nur die Hälfe und bei GAT gar nichts. 
Bei GAT wird der Mitarbeiter trotzdem mit bei der Anzahl berücksichtig. GAT bedeutet nämlich das er den ganzen Tag andere Dinge gemacht hat, und nicht produktiv an dem gearbeitet hat für das er eigentlich eingestellt wurde. Nur zur Info.

Vielen Dank schonmal im Voraus. 
Hier das Beispiel 
  Work.xlsx (Größe: 9,68 KB / Downloads: 11)

[schauan]

Hallöchen,

nimm den gleichen Ansatz wie in Zeile 9. Zähle die Abkürzungen und rechne damit.

[Hille_2510]

Danke für die Antwort. 

Ich weiß nicht ob du damit die Summenprodukt Formel meintest aber diese Habe ich jetzt auf jeden Fall verwendet. 

Nun möchte ich die Formel für die Anzahl auch noch bisschen sauberer gestalten. Ich denke das sollte auch möglich sein, weil er ja immer im selben Bereich suchen soll bloß nach anderen Texten. Also er soll zählen wenn er ein A,GAT oder HAT findet. Im Moment habe ich das ja über eine einfache Reihung gelöst aber das geht sicher auch anders.
Ich habe es schon mit ZÄHLENWENNS probiert aber irgendwie ging das nicht so wirklich wie gewünscht. 

Das jetzt meine Lösung für den durchschnittlichen Gesamtwirkungsgrad des Tages:

=(SUMMENPRODUKT((C3:C7=$J$2)*($B3:$B7)) + SUMMENPRODUKT((C3:C7=$J$3)*0,5*($B3:$B7)))/C10

[Hille_2510]

Meine Lösung für das Problem mit dem Zählen wäre jetzt erstmal:

=SUMME(ZÄHLENWENN(C2:C7;{"A";"HAT";"GAT"}))

Damit bin ich aber noch nicht so wirklich zu frieden, weil ich in den geschweiften Klammern gerne auf die Zellen verweisen würde in denen der Text zum abgleichen definiert wird.

[PIVPQ]

Hallo

Für die Zeile Anzahl ohne Formel so?

[bug99]

Damit bin ich aber noch nicht so wirklich zu frieden, weil ich in den geschweiften Klammern gerne auf die Zellen verweisen würde in denen der Text zum abgleichen definiert wird.

{=SUMME((C3:C7=$J2)+(C3:C7=$J3)+(C3:C7=$J4))}

[schauan]

Hallöchen,

Dein SUMMENPRODUKT wäre auch mit SUMMEWENN realisierbar:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
10	Anzahl		2	4	5	4	3
11	Werkungsgrad		0,45	0,63	0,61	0,53	0,62
12			0,45	0,63	0,61	0,53	0,62
13			0,45	0,63	0,61	0,53	0,62

Zelle	Formel
C10	=ZÄHLENWENN(C3:C7;$J$2)+ZÄHLENWENN(C3:C7;$J$3)+ZÄHLENWENN(C3:C7;$J$4)
C11	=(WENN(C3=$J$2;$B$3;WENN(C3=$J$3;$B$3/2))+WENN(C4=$J$2;$B$4;WENN(C4=$J$3;$B$4/2))+WENN(C5=$J$2;$B$5;WENN(C5=$J$3;$B$5/2))+WENN(C6=$J$2;$B$6;WENN(C6=$J$3;$B$6/2))+WENN(C7=$J$2;$B$7;WENN(C7=$J$3;$B$7/2)))/C10
C12	=(SUMMENPRODUKT((C3:C7=$J$2)*($B3:$B7)) + SUMMENPRODUKT((C3:C7=$J$3)*0,5*($B3:$B7)))/C10
C13	=(SUMMEWENN(C3:C7;$J2;$B3:$B7)+SUMMEWENN(C3:C7;$J3;$B3:$B7)*0,5)/C10

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hi,

andere Variante:



  Kopie von Work.xlsx (Größe: 10,05 KB / Downloads: 6)