Formel indirekt mit dynamischem Bezug

[Florana]

Hallo,

ich verwende folgende Formel:
=@INDIREKT(WENN("Kunden!h6">0;"Kunden!h6";" ")).

Was muss ich machen, damit die Formel dynamisch weitergeführt wird?

Vielen Dank im Voraus.

Gruß

[derHoepp]

Moin,

irgendwie ergibt die Formel so keinen Sinn. Die wenn Abfrage gibt immer den Wahr- Zweig wieder. Zudem ist die Verwendung von indirekt in der gleichen Mappe eher ungewöhnlich. Wozu glaubst du, Indirekt zu benötigen?

Viele Grüße
derHöpp

[Florana]

Hallo,

ich habe Indirekt verwendet und zwar aus folgendem Grund:
Wenn die Zeile 6 in der Tabelle Kunden! gelöscht wird, erscheint ein #Bezug!-Fehler.

Das passiert bei indirekt nicht.

Wenn ich bei Indirekt die Formel nach unten ziehe, wird der Bezug nicht fortgeführt. Das heißt, ich muss alles manuell abändern.

Was gäbe es für eine Lösung?

Gruß F.

[LCohen]

=MAX(INDEX(Kunden!H:H;6);) und die 0 über benDefFmt ausblenden

=MAX(INDEX(Kunden!H:H;ZEILE(A6));) wäre die Herunterkopier-Variante (falls Du das mit dynamisch meinst)

[slowboarder]

Hi
nun, das sinnvollste wäre, die Zellen nicht zu löschen, sondern nur zu leeren.
aber gut, Fehler passieren und es gut, wenn man sie absichern kann.

ein dynamischen Indirekt kannst du erzeugen, wenn du die Z1S1-Bezugsart verwendest.

also nicht: =Indirekt("Kunden!H6")
sondern =Indirekt("Kunden!Z(0)S(0)";FALSCH)

dabei steht Z für "Zeile" und "S" für Spalte
danach folgt dann entweder die Zeilen- bzw Spaltennummer, wenn es ein absoluter Zellbezug sein soll, oder bei einem dynamischen Zellbezug (wandert mit) der Versatzwert in Klammern, dh das (0) im Bespiel steht für "gleiche Zeile, gleiche Spalte wie die Zelle, in der sich die Formel befindet. ein positiver Wert bedeutet einen Versatz nach unten oder rechts, ein negativer Wert einen Versatz nach links oder oben.
dh man muss hier immer die Zeilen- und Spaltendifferenz von Zielzelle und Zelle mit der Formel angeben.
im Fall von (0) kann man das auch weglassen, dh wenn deine Formel schon in H6 steht, reicht auch (0=FALSCH)  =Indirekt("Kunden!ZS";0)

wenn du dich mit Z1S1 nicht anfreunden kannst, oder die Datei auch von anderssprachigen Exceln verwendet werden soll, dann ggf so:

=INDIREKT(ADRESSE(ZEILE(H6);SPALTE(H6);4;1;"Kunden"))

wenn die Formel nur nach unten gezogen wird und die Spalte fix ist ist, dann gehts auch einfacher:

=INDIREKT("Kunden!H"&Zeile(H6))

Gruß Daniel

[Florana]

Hallo zusammen,

funktionieren alle super. Das erspart mir sehr viel Tipparbeit.
Danke an alle!

Gruß
Florana